As promised this is the ProOrder robot for Delphic-TP Combo1.0 indicator. Please before download it, read and download the itf files of the Delphic-TP Combo1.0 indicator.

You can find it in the indicator section.

//*************************************************************************************
//*                                                                                   *
//*  Trading System: DelphicTrade3.0                Author: Alessandro Furlani        *
//*  Filename : DelphicTrade1.0                                                       *
//*                                                                                   *
//*  Note:  The TS works with the indicator Delphic-TP Combbo1.0                      *
//*         To understand strategy go to the Delphic1.0 indicator label               *
//*         Standard setup for 1D timeframe is SMAFast=18, SMASlow=40.                *
//*         For different TM the lenght of the SMA has to be tuned.                   *
//*         Orders are opened based on the indicator.                                 *
//*         TP and SL are available in % but the standard version work with Trailing  *
//*         Stop. All the thresholds have to be tuned based on TM and your preferences*
//*         Trailing Stop can be automated immediately under or above the SMA40       *
//*         accordingly with the postion open (Long/Short)or tuned manually at %      *
//*         A grid management is available if needed.                                 *
//* 10-05-2025 - Time run added                                                       *
//* 11-05-2023 - Witdrawal simulation added                                           *
//*                                                                                   *
//*                                                                                   *
//*************************************************************************************
DEFPARAM cumulateOrders = True
once ActualEquity=EquityStart
once EquityStartMulti=2
once TotalWithDraw=0


//Equity calculation to make the size automatic and dynamic
if OnMarket then
ActualEquity=(EquityStart+StrategyProfit)-TotalWithDraw
if CurrentDayOfWeek=5 and ActualEquity>(EquityStart*EquityStartMulti) then
WithDrawEquity=(ActualEquity-(EquityStart*EquityStartMulti))*WithDrawSize
TotalWithDraw=TotalWithDraw+WithDrawEquity
EquityStartMulti=EquityStartMulti+1
//graph WithDrawEquity as "WithDraw Gain" coloured ("green")
endif
endif
//To use only in Backtest. disable on live
//graph WithDrawEquity as "WithDraw Gain" coloured ("green")
//graph ActualEquity as "StrategyProfitYTD" coloured ("red")
//graph TotalWithDraw as "Total WithDraw YTD" coloured ("Yellow")

//Get the indicator signals
PriceSMASlow=average[PeriodSMASlow](TotalPrice)
PriceSMAFast=average[PeriodSMAFast](TotalPrice)
signal, dumb = call "Delphic-TP Combo1.0"[PeriodSMAFast, PeriodSMASlow,0]

//Force Exit Strategy to increase efficency
if ExitStrategy=1 then
if LongOnMarket and PriceSMAFast crosses under PriceSMASlow then
Sell at market
elsif ShortOnMarket and PriceSMAFast crosses over PriceSMASlow then
ExitShort at market
endif
endif

//Lotto Setup
if CurrentTime>=TimeStart and CurrentTime<=TimeStop then
if Autosize>0 then
lotto=Round((((ActualEquity*Leva)*AutoSize)/TotalPrice),0)
MaxLot=Round((ActualEquity*Leva)/TotalPrice)
if MaxLot>MaxMaxLot then
MaxLot=MaxMaxLot
endif
if Lotto>MaxLot then
Lotto=MaxLot
endif
if lotto<MinLot then
lotto=MinLot
endif
else
lotto=MinLot
MaxLot=MaxMaxLot
endif

// Condition to enter long
IF NOT LongOnMarket AND signal=1 THEN
BUY lotto Lot AT MARKET
if Trail=0 then
trailpoint=TotalPrice-PriceSMASlow
elsif Trail>0 then
trailpoint=Trail
endif
//set stop $trailing trailpoint
set stop %loss SL
set target %profit TP
LastOrderBar=BarIndex
OrderBar=BarIndex
LottoGrid=lotto
OrderGridNum=0
ENDIF

// Condition to enter short
IF NOT ShortOnMarket AND signal=-1 THEN
SELLSHORT lotto lot AT MARKET
if Trail=0 then
trailpoint=PriceSMASlow-TotalPrice
elsif Trail>0 then
trailpoint=Trail
endif
//set stop $trailing trailpoint
set stop %loss SL
set target %profit TP
LastOrderBar=BarIndex
OrderBar=BarIndex
LottoGrid=lotto
OrderGridNum=0
ENDIF
endif

//Grid management
if Grid=1 then
if LongOnMarket and CountOfLongShares<MaxLot and BarIndex>=OrderBar+1 then
if (BarIndex>LastOrderBar and PositionPerf[0]<GridStep and OrderGridNum<MaxGridOrder ) then
LottoGrid=LottoGrid*GridMulti
if LottoGrid>MaxLot-CountOfLongShares then
LottoGrid=MaxLot-CountOfLongShares
endif
BUY LottoGrid LOT AT MARKET
OrderGridNum=OrderGridNum+1
LastOrderBar=BarIndex
endif
elsif ShortOnMarket and CountOfShortShares<MaxLot and BarIndex>=OrderBar+1 then
if (BarIndex>LastOrderBar and PositionPerf[0]<GridStep and OrderGridNum<MaxGridOrder ) then
LottoGrid=LottoGrid*GridMulti
if LottoGrid>MaxLot-CountOfShortShares then
LottoGrid=MaxLot-CountOfShortShares
endif
SELLSHORT LottoGrid LOT at market
OrderGridNum=OrderGridNum+1
LastOrderBar=BarIndex
endif
endif
endif

The tested parameters are for Gold. You can find it attached in a jpg image.