A based on 2RSI weekly strategy working on indexes.

It is just one version of the 2RSI strategy originated by Connors. It is tested and optimized by me to work on the weekly timeframe. It gives good results on major indexes without changing any parameter.

This weekly strategy can be used both for automatic trading and advisor for manual entry during the weekdays while the strategy gives an entry signal (I use also an indicator replying the strategy).

Any suggestion or improvement is welcome.

// PRT-RSI-10/6e90/94-week
// Author: Superfalcio
//Applicable assets:
//China A50
//EU Stoxx
//Fra40
//FTSE100
//Ger40
//Ita40
//Japan
//US500
//US Tech
//WS
//Time Frame: Weekly

Defparam cumulateorders = true

//Size plan LONG
L1=1
L2=1

// Size plan SHORT
S1=1
S2=1

// INDICATORS
indicator0 = average[50](close)
indicator1 = RSI[2](close)

ONCE posA = 0
ONCE posV = 0

// LONG PLAN 1
CL1 = close >indicator0
CL2 = indicator1<=10

IF posA = 0 and CL1 and CL2 THEN
buy L1 shares at market
tradeprice1 = close
barencours = barindex
posA = 1
ENDIF

// LONG PLAN 2
IF posA = 1 and barindex - barencours>= 1 THEN
IF indicator1<=6 THEN
buy L2 shares at market
tradeprice2 = close
barencours = barindex
posA = 2
ENDIF
ENDIF

// EXIT LONG
IF posA>0 and indicator1>70 THEN
Sell at market
posA = 0
ENDIF

// SHORT PLAN 1
CS1 = close <indicator0
CS2 = indicator1>=90

IF posV = 0 and CS1 and CS2 THEN
sellshort S1 shares at market
tradeprice1 = close
barencours = barindex
posV = -1
ENDIF

// SHORT PLAN 2
IF posV = -1 and barindex - barencours>= 1 THEN
IF indicator1>=94 THEN
sellshort S2 shares at market
tradeprice2 = close
barencours = barindex
posV = -2
ENDIF
ENDIF

// EXIT SHORT
IF posV<0 and indicator1<30 THEN
exitshort at market
posV = 0
ENDIF