TMMS oscillator (Trading Made More Simpler)

The TMMS oscillator (aka “Trading Made More Simpler”) is an indicator made of conditions based on both 2 separated Stochastic and 1 RSI.

Bullish zone is green and bearish one is red. When the histogram is grey, no signals is available at that time.

The indicator has an option to show the current trend of an Hull moving average (ascending or descending curve). When the trend is up, green dots are plotted on the zero line. When the trend is down, the dots are coloured in orange.

Indicator converted from an MT4 version by a request in the indicators forum.

//PRC_smTMMS-Oscillator_v3.0 | indicator
//13.09.2019
//Nicolas @ www.prorealcode.com
//Sharing ProRealTime knowledge
//translated from mt4 version

// --- settings
RSIPeriod=14
Stochastic1PeriodK  = 8
Stochastic1PeriodD  = 3
Stochastic2PeriodK  = 14
Stochastic2PeriodD  = 3
DrawHullTrend = 1 //(1=true ; 0=false)
HullPeriod     =12
HullDivisor    =2
// --- end of settings

once threshold=50
once ilimit=0

bufRSI=rsi[RSIPeriod]
bufStoch1=stochastic[Stochastic1PeriodK,Stochastic1PeriodD]
bufStoch2=stochastic[Stochastic2PeriodK,Stochastic2PeriodD]
bufRSI=bufRSI-threshold
bufStoch1=bufStoch1-threshold
bufStoch2=bufStoch2-threshold

bufHistUP=0
bufHistDN=0
bufHistNO=0
if(bufRSI>ilimit and bufStoch1>ilimit and bufStoch2>ilimit) then
 bufHistUP=bufStoch2
else
 if(bufRSI<ilimit and bufStoch1<ilimit and bufStoch2<ilimit) then
  bufHistDN=bufStoch2
 else
  bufHistNO=bufStoch2
 endif
endif

if (DrawHullTrend) then
 inner = 2*weightedaverage[ round( HullPeriod/HullDivisor ) ](close)-weightedaverage[HullPeriod](close)
 MMHULL=weightedaverage[ round( sqrt(HullPeriod) ) ]( inner )
 r=255
 g=155
 if MMHULL>MMHULL[1] then
  r=0
  g=255
 endif
 drawtext("●",barindex,0,dialog,bold,16) coloured(r,g,0)
endif

return bufHistUP coloured(0,128,0) style(histogram) as "Up", bufHistDN coloured(255,0,0) style(histogram) as "Dn", bufHistNO coloured(169,169,169) style(histogram) as "No",0 coloured(168,168,168) style(point,1) as "level0", 20  coloured(168,168,168) style(dottedline,1) as "level20", -20  coloured(168,168,168) style(dottedline,1) as "level-20"