Hi Vonasi ! I recently worked on a new version of the code based on the various suggestions of this thread (Paul and Jebus89 in particular). I also did a Walk Forward on the variable “lag”. I also took into account your recommendations on the size of the positions and I added your code on money management. Here is the code and below the results. I would be happy to have your feedback and opinion. Thank you.

// ROBOT VECTORIAL DAX
// M5
// SPREAD 1.5
// by BALMORA 74 - FEBRUARY 2019

DEFPARAM CumulateOrders = false
DEFPARAM Preloadbars = 50000


//VARIABLES
CtimeA = time >= 080000 and time <= 180000
CtimeB = time >= 080000 and time <= 180000


MoneyManagement = 2
RiskManagement = 0
Capital = 10000
MinBetSize = 1
RiskLevel = 20
 
Equity = Capital + StrategyProfit
 
IF MoneyManagement = 1 THEN
PositionSize = Max(MinBetSize, Equity * (MinBetSize/Capital))
ENDIF
 
IF MoneyManagement = 2 THEN
PositionSize = Max(LastSize, Equity * (MinBetSize/Capital))
LastSize = PositionSize
ENDIF
 
IF MoneyManagement <> 1 and MoneyManagement <> 2 THEN
PositionSize = MinBetSize
ENDIF
 
IF RiskManagement THEN
IF Equity > Capital THEN
RiskMultiple = ((Equity/Capital) / RiskLevel)
PositionSize = PositionSize * (1 + RiskMultiple)
ENDIF
ENDIF
 
PositionSize = Round(PositionSize)

 
// TAILLE DES POSITIONS
PositionSizeLong = 1 * positionsize
PositionSizeShort = 1 * positionsize
 

//STRATEGIE

//VECTEUR = CALCUL DE L'ANGLE
ONCE PeriodeA = 10
ONCE nbChandelierA= 15
MMA = Exponentialaverage[PeriodeA](close)
ADJASUROPPO = (MMA-MMA[nbchandelierA]*pipsize) / nbChandelierA
ANGLE = (ATAN(ADJASUROPPO)) //FONCTION ARC TANGENTE
CondBuy1 = ANGLE >= 35
CondSell1 = ANGLE <= - 40


//VECTEUR = CALCUL DE LA PENTE ET SA MOYENNE MOBILE
ONCE PeriodeB = 20
ONCE nbChandelierB= 35
lag = 1.5
MMB = Exponentialaverage[PeriodeB](close)
pente = (MMB-MMB[nbchandelierB]*pipsize) / nbchandelierB
trigger = Exponentialaverage[PeriodeB+lag](pente)
CondBuy2 = (pente > trigger) AND (pente < 0)
CondSell2 = (pente CROSSES UNDER trigger) AND (pente > -1)



//ENTREES EN POSITION
CONDBUY = CondBuy1 and CondBuy2 and CTimeA
CONDSELL = CondSell1 and CondSell2 and CtimeB


//POSITION LONGUE
IF CONDBUY THEN
buy PositionSizeLong contract at market
SET STOP %LOSS 2
ENDIF

//POSITION COURTE
IF CONDSELL THEN
Sellshort PositionSizeShort contract at market
SET STOP %LOSS 2
ENDIF

//VARIABLES STOP SUIVEUR
ONCE trailingStopType     = 1    // Trailing Stop - 0 OFF, 1 ON
ONCE trailingstoplong     = 4    // Trailing Stop Atr Relative Distance
ONCE trailingstopshort    = 4    // Trailing Stop Atr Relative Distance

ONCE atrtrailingperiod    = 14  // Atr parameter Value
ONCE minstop              = 0    // Minimum Trailing Stop Distance


// TRAILINGSTOP
//----------------------------------------------
atrtrail = AverageTrueRange[atrtrailingperiod]((close/10)*pipsize)/1000
trailingstartl = round(atrtrail*trailingstoplong)
trailingstartS = round(atrtrail*trailingstopshort)
if trailingStopType = 1 THEN
TGL =trailingstartl
TGS=trailingstarts
if not onmarket then

MAXPRICE = 0
MINPRICE = close
PREZZOUSCITA = 0
ENDIF
if longonmarket then
MAXPRICE = MAX(MAXPRICE,close)
if MAXPRICE-tradeprice(1)>=TGL*pointsize then
if MAXPRICE-tradeprice(1)>=MINSTOP then
PREZZOUSCITA = MAXPRICE-TGL*pointsize
ELSE
PREZZOUSCITA = MAXPRICE - MINSTOP*pointsize
ENDIF
ENDIF
ENDIF
if shortonmarket then
MINPRICE = MIN(MINPRICE,close)
if tradeprice(1)-MINPRICE>=TGS*pointsize then
if tradeprice(1)-MINPRICE>=MINSTOP then
PREZZOUSCITA = MINPRICE+TGS*pointsize
ELSE
PREZZOUSCITA = MINPRICE + MINSTOP*pointsize
ENDIF
ENDIF
ENDIF
if onmarket and PREZZOUSCITA>0 then
EXITSHORT AT PREZZOUSCITA STOP
SELL AT PREZZOUSCITA STOP
ENDIF
ENDIF

Capture-décran-2019-03-20-21.31.38.png Capture-décran-2019-03-20-21.31.57.png Capture-décran-2019-03-20-21.32.05.png Capture-décran-2019-03-20-21.32.18.png

Ok so i put on value = 0 the variables “MoneyManagement” and “trailingStopType”. These a the results :

Capture-décran-2019-03-20-22.21.26.png Capture-décran-2019-03-20-22.21.41.png Capture-décran-2019-03-20-22.21.51.png