Maz

Thank you for the code. I really feel like I learnt something from going through it which is what I love about this site. In particular many thanks for the time you spent adding the notes and making it user friendly.

Just a small FYI / beginners question: in the code for the coeff version the lines for mcThreshold and rcThreshold have a “//” to cancel them out however later on in the buy conditions you have:

bc1 = bc1 and (mc >= mcThreshold)
bc1 = bc1 and (rc >= rcThreshold)

I see that you have optimised for mcThreshold and rcThreshold. Should the “//” be still in the code?  I don’t think it matters as when I take the “//” out it gives the same result.

Thanks

Hi Maz, may have a detailed explanation of the concept, and what variations are possible to look for different market or time frame? 

// ====================================== \\
// :: Optimizations --
// -------------------------------------- //

// Static Optimization for DOW E1 Contract 1 hour
// Jan 2013 - April 2017
// Spread 3 points
wintarget = 45       // Clip target to maximum of x points
minTradeTime = 16     // stay in trade for at least x bars
mcThreshold = 0.1    // Momentum coef or dif threshold
rcThreshold = 0.1    // Range coef or dif threshold
// try also 27
mcShortPeriod = 4     // Short period momentum
rcShortPeriod = 2     // Short period average range
mcLongPeriod  = 100   // Long period momentum
rcLongPeriod  = 70    // Long period average range

mcThreshold = 0.1 // 0.5   // Momentum coefficient threshold
rcThreshold = 0.55 // 1     // Range coefficient threshold

maShortPeriod = 5    // Short term moving average
maLongPeriod  = 20    // Long term moving average

// ====================================== \\
// :: Indicators --
// -------------------------------------- //

// Momentum Coefficient and Range Coefficient ============= \\
if barIndex >= max(mcLongPeriod, rcLongPeriod) then

mShort = momentum[mcShortPeriod]
mLong  = momentum[mcLongPeriod]
mc = max(0, (abs(mShort) / abs(mLong)) -1)

r = abs(range)
arLong  = average[max(1, rcLongPeriod)](r)
arShort = average[max(1, rcShortPeriod)](r)
rc = max(0, (arShort / arLong) -1)
//rc = max(0, arShort - arLong)

endif
// ----------------------------------- //

// General Indicators ================= \\
upBar = close > open
maShort = exponentialAverage[maShortPeriod](Close)
maLong  = exponentialAverage[maLongPeriod](Close)
// ----------------------------------- //

// ====================================== \\
// :: Entry Logic
// -------------------------------------- //

// long entry rules (buy condition)
bc1 = not longOnMarket
bc1 = bc1 and (mc >= mcThreshold)
bc1 = bc1 and (rc >= rcThreshold)
bc1 = bc1 and upBar
bc1 = bc1 and maShort > maShort[1]

// long exit rules (exit long conditions)
le1 = longOnMarket
le1 = le1 and ( barIndex >= barIndexAtBuy + minTradeTime)
le1 = le1 and (maLong < maLong[4])

// ====================================== \\
// :: Execution Handlers
// -------------------------------------- //
if bc1 then
buy 1 shares at market
set target pprofit wintarget
barIndexAtBuy = barIndex
endif

if le1 and longOnMarket then
sell at market
endif

SET STOP pLOSS 70

//trailing stop
trailingstop = 30

//resetting variables when no trades are on market
if not onmarket then
MAXPRICE = 0
priceexit = 0
endif

//case LONG order
if longonmarket then
MAXPRICE = MAX(MAXPRICE,close) //saving the MFE of the current trade
if MAXPRICE-tradeprice(1)>=trailingstop*pointsize then //if the MFE is higher than the trailingstop then
priceexit = MAXPRICE-trailingstop*pointsize //set the exit price at the MFE - trailing stop price level
endif
endif

//exit on trailing stop price levels
if onmarket and priceexit>0 then
SELL AT priceexit STOP
endif