Multiple consecutive candlesticks strategy

Principle of multi-candle trading strategy:
The automated trading strategy expects X consecutive candles having the same direction to open a position.

Example: the chart has just formed 6 consecutive bulbs, and I want that at the opening of the 7th candle, the system automatically opens a trade short (with stop loss and take profit).

Parameters and Options:

• Size of the position: in number of lots.
• Stop loss: to determine how many pips / points of the entry price will be positioned the stop loss of an opened position.
• Take Profit: To determine how many pips / points of the entry price will be positioned the take profit of an open position.
• Number of candles to wait: to determine the number of consecutive candles having the same meaning to wait.
• Trade inverse: true / false, this option allows you to choose whether the opening of the trade will be in the same direction or the reverse of the X consecutive candles.

Example: If the option is set to “False”, the system opens a purchase after X candles bullish. Conversely, if the option is set to “True”, the system then opens a sale after X candles bullish. In other words: on False, the system opens positions in the direction of the movement during formation. On True, the system opens positions against the trend of the movement being formed.

• Trading accumulation: true / false, this option is used to fix whether the system should (or should not) open a new position if the spark plug X + 1 is also in the same direction as the previous X candles. Example: If the option is set to “False”, the system waits at least X candles after opening a new position. If the option is set to “True”, the system can then cumulate new positions directly to each subsequent candlestick.

Example 1 of the multi-candle system:
1/10 2/30 3/60 4/7 5 / True 6 / False This setting causes the system to wait 7 consecutive bullish or bearish candles to open a counter-meaning trade to the 8th candle. If this 8th candle also closes in the same direction as the previous 7 candles, the system does not open a new position at the opening of the 9th candle. * * Having already opened a position, the system waits again 7 consecutive candles From the 8th candle to possibly open a new position (if these candles from 8 to 14 are all in the same direction)

Example 2 of the multi-candle system:
1/10 2/30 3/60 4/3 5 / False 6 / True This setting means that the system expects 3 consecutive bullish or bearish candles to open a trade in the same direction to the 4th candle. If this 4th candle also closes in the same direction as the previous 3 candles, the system opens a new position directly at the opening of the 5th candle.

This trading strategy has been coded by a request on the French forum. Please consider that there is no typical settings and it is not dedicated to any instrument or timeframe at all. This strategy is almost like a “sandbox” for studying purpose and to define suitable parameters for your preferred instruments.

//PRC_TS multiple candlesticks | indicator
//01.03.2017
//Nicolas @ www.prorealcode.com
//Sharing ProRealTime knowledge

// --- parameters
Size = 1 //position size
StopLoss = 20 //stoploss in points
TakeProfit = 10 //takeprofit in points
Xcandlesticks = 6 //consecutive bullish or bearish candlesticks to open a new position
InverseTrading = 0 //(0=false ; 1=true) trade in the same direction of the candlesticks pattern or not
CumulateOrder = 0 //(0=false ; 1=true) cumulate or not a new trade if the current candlestick is in the same trend as the pattern
// ------------

//detecting patterns
bearpattern = summation[Xcandlesticks](close<open)=Xcandlesticks
bullishpattern = summation[Xcandlesticks](close>open)=Xcandlesticks

//first order
if not onmarket then
 if bearpattern then
  if InverseTrading then
   BUY Size CONTRACTS AT MARKET
  else
   SELLSHORT Size CONTRACT AT MARKET
  endif
  lastbar = barindex
  lastpattern = -1
 endif
 if bullishpattern then
  if InverseTrading then
   SELLSHORT Size CONTRACT AT MARKET
  else
   BUY Size CONTRACTS AT MARKET
  endif
  lastbar = barindex
  lastpattern = 1
 endif
endif

//cumulate order when a new pattern occurred
if onmarket and not CumulateOrder and barindex-lastbar>=Xcandlesticks then
 if bearpattern then
  if InverseTrading then
   BUY Size CONTRACTS AT MARKET
  else
   SELLSHORT Size CONTRACT AT MARKET
  endif
  lastbar = barindex
 endif
 if bullishpattern then
  if InverseTrading then
   SELLSHORT Size CONTRACT AT MARKET
  else
   BUY Size CONTRACTS AT MARKET
  endif
  lastbar = barindex
 endif
endif

//cumulate order when a new consecutive candletick happen right after the pattern occurred
if onmarket and CumulateOrder and barindex-lastbar=1 then
 if longonmarket then
  if (close>open and lastpattern=1) or (close<open and lastpattern=-1) then
   BUY Size CONTRACTS AT MARKET
   lastbar = barindex
  endif
 endif
 if shortonmarket then
  if (close>open and lastpattern=1) or (close<open and lastpattern=-1) then
   SELLSHORT Size CONTRACT AT MARKET
   lastbar = barindex
  endif
 endif
endif

SET STOP PLOSS StopLoss
SET TARGET PPROFIT TakeProfit