Here is my version, with a different angle (WF).

Improvments and suggestions are welcome!

// ROBOT VECTORIAL DAX V.3
// M5
// SPREAD 1.5
// by BALMORA 74 - FEBRUARY 2019 /// winnie version 10/04/12019
 
DEFPARAM CumulateOrders = false
DEFPARAM Preloadbars = 50000
 
 
//VARIABLES
CtimeA = time >= 080000 and time <= 180000
CtimeB = time >= 080000 and time <= 180000

ONCE BarLong = 950   //EXIT ZOMBIE TRADE LONG
ONCE BarShort = 650  //EXIT ZOMBIE TRADE SHORT

 
 
MoneyManagement = 2
//MoneyManagement =  Set to 0 for level stakes. Set to 1 for increasing stake size as profits increase and decreasing stake size as profits decrease. Set to 2 for increasing stake size as profits increase with stake size never being decreased.

RiskManagement = 1
//RiskManagement =      0 = risk management off and 1 = risk management on. I do not recommend using this it can blow up your account very easily!

Capital = 10000

MinBetSize = 1
//MinBetSize =                 The minimum bet size allowed for the instrument.

RiskLevel = 10
//RiskLevel =A factor that changes how fast position size increases as profit increases. Only relevant if Risk Management is turned on.


 
Equity = Capital + StrategyProfit
 
IF MoneyManagement = 1 THEN
PositionSize = Max(MinBetSize, Equity * (MinBetSize/Capital))
ENDIF
 
IF MoneyManagement = 2 THEN
PositionSize = Max(LastSize, Equity * (MinBetSize/Capital))
LastSize = PositionSize
ENDIF
 
IF MoneyManagement <> 1 and MoneyManagement <> 2 THEN
PositionSize = MinBetSize
ENDIF
 
IF RiskManagement THEN
IF Equity > Capital THEN
RiskMultiple = ((Equity/Capital) / RiskLevel)
PositionSize = PositionSize * (1 + RiskMultiple)
ENDIF
ENDIF
 
PositionSize = Round(PositionSize)
 
 
// TAILLE DES POSITIONS
PositionSizeLong = 1 * positionsize
PositionSizeShort = 1 * positionsize
 
 
//STRATEGIE
 
//VECTEUR = CALCUL DE L'ANGLE
ONCE PeriodeA = 10
ONCE nbChandelierA= 15
MMA = Exponentialaverage[PeriodeA](close)
ADJASUROPPO = (MMA-MMA[nbchandelierA]*pipsize) / nbChandelierA
ANGLE = (ATAN(ADJASUROPPO)) //FONCTION ARC TANGENTE
CondBuy1 = ANGLE >= 20
CondSell1 = ANGLE <= - 24
 
 
//VECTEUR = CALCUL DE LA PENTE ET SA MOYENNE MOBILE
ONCE PeriodeB = 20
ONCE nbChandelierB= 35
lag = 1.5
MMB = Exponentialaverage[PeriodeB](close)
pente = (MMB-MMB[nbchandelierB]*pipsize) / nbchandelierB
trigger = Exponentialaverage[PeriodeB+lag](pente)
CondBuy2 = (pente > trigger) AND (pente < 0)
CondSell2 = (pente CROSSES UNDER trigger) AND (pente > -1)
 
 
 
//ENTREES EN POSITION
CONDBUY = CondBuy1 and CondBuy2 and CTimeA
CONDSELL = CondSell1 and CondSell2 and CtimeB
 
 
//POSITION LONGUE
IF CONDBUY THEN
buy PositionSizeLong contract at market
SET STOP %LOSS 2
ENDIF
 
//POSITION COURTE
IF CONDSELL THEN
Sellshort PositionSizeShort contract at market
SET STOP %LOSS 2
ENDIF
 
//VARIABLES STOP SUIVEUR
ONCE trailingStopType     = 1    // Trailing Stop - 0 OFF, 1 ON
ONCE trailingstoplong     = 4    // Trailing Stop Atr Relative Distance
ONCE trailingstopshort    = 4    // Trailing Stop Atr Relative Distance
 
ONCE atrtrailingperiod    = 14  // Atr parameter Value
ONCE minstop              = 0    // Minimum Trailing Stop Distance
 
 
// TRAILINGSTOP
//----------------------------------------------
atrtrail = AverageTrueRange[atrtrailingperiod]((close/10)*pipsize)/1000
trailingstartl = round(atrtrail*trailingstoplong)
trailingstartS = round(atrtrail*trailingstopshort)
if trailingStopType = 1 THEN
TGL =trailingstartl
TGS=trailingstarts
if not onmarket then
 
MAXPRICE = 0
MINPRICE = close
PREZZOUSCITA = 0
ENDIF
if longonmarket then
MAXPRICE = MAX(MAXPRICE,close)
if MAXPRICE-tradeprice(1)>=TGL*pointsize then
if MAXPRICE-tradeprice(1)>=MINSTOP then
PREZZOUSCITA = MAXPRICE-TGL*pointsize
ELSE
PREZZOUSCITA = MAXPRICE - MINSTOP*pointsize
ENDIF
ENDIF
ENDIF
if shortonmarket then
MINPRICE = MIN(MINPRICE,close)
if tradeprice(1)-MINPRICE>=TGS*pointsize then
if tradeprice(1)-MINPRICE>=MINSTOP then
PREZZOUSCITA = MINPRICE+TGS*pointsize
ELSE
PREZZOUSCITA = MINPRICE + MINSTOP*pointsize
ENDIF
ENDIF
ENDIF
if onmarket and PREZZOUSCITA>0 then
EXITSHORT AT PREZZOUSCITA STOP
SELL AT PREZZOUSCITA STOP
ENDIF
ENDIF

//EXIT ZOMBIE TRADE
IF POSITIONPERF<0 THEN
IF shortOnMarket AND BARINDEX-TRADEINDEX(1)>= barshort THEN
EXITSHORT AT MARKET
ENDIF
ENDIF
 
IF POSITIONPERF<0 THEN
IF LongOnMarket AND BARINDEX-TRADEINDEX(1)>= barlong THEN
SELL AT MARKET
ENDIF
ENDIF

Vectorial-DAX-M5-v3_Paul.itf Capture-d’écran-2019-04-10-à-11.57.01.png Capture-d’écran-2019-04-10-à-11.58.55.png Capture-d’écran-2019-04-10-à-11.59.09.png

Is there redundant code in this strategy or can anybody offer a reason for the following please?

When I optimise the angles, it seems that almost any value gives the same figure for Gain … see attached.

Attached is related to the code version immediately above this post.

vectorial.jpg