Breakout Strategy for the Dax and Dow Open – Trader Tom

Viewing 15 posts - 1 through 15 (of 54 total)

1 2 3 4 →

Author

Posts
11/09/2021 at 6:51 AM #181276 quote
murre87
Participant

Senior
https://tradertom.com/breakout-strategy-for-the-dax-and-dow-open/

The world’s simplest strategy but which is proven to make money in the long run.

Breakout of the DAX index
- Observe DAX pre-market from 7am until 07.59am.
- Mark the high and the low of those 59 minutes of trading.
- Place a BUY order at the high of the 59 minutes observation period.
- Place a SELL SHORT order at the low of the 59 minutes observation period.
- This obviously needs to be done in the minute before the market opens.You need to be quick.
- You risk 9 points.
- Your target is to make 6 points.If one order is filled, I cancel the other. Some do not. I do.
Breakout of Dow Open
- Observe Dow pre-market from 13:30 until 14:29.
- Mark the high and the low of those 59 minutes of trading.
- Place a BUY order at the high of the 59 minutes observation period.
- Place a SELL SHORT order at the low of the 59 minutes observation period.
- This obviously needs to be done in the minute before the market opens. You need to be quick.
- You risk 9 points.
- Your target is to make 6 points, but I always go for more.
Would this be possible to code?
11/09/2021 at 10:31 AM #181292 quote

monkeys nuts
Blocked

New

Yes

11/09/2021 at 12:12 PM #181297 quote

TempusFugit
Participant

Veteran

Murre,

DAX 30 – Morning range breakout with order size increase

This is a good system with the same idea, you can change the parameters as you please… for instance you can set the range from 7 to 7.59, the target profit and so on…

Good Luck

11/09/2021 at 1:00 PM #181305 quote
MauroPro
Participant

Veteran
Try this:
```
DEFPARAM cumulateOrders = false
//-----------------------------------------
timeframe (1 minute)
OTD = Barindex - TradeIndex(1) > IntradayBarIndex //one trade X day
startHour = 080000
cTime = time >= startHour
//------------------------------------------------------
if openTime = 070000 then
myHighest = high
myLowest = low
endif
if openTime >= 070000 and openTime <=075900 then
myHighest = max (myHighest,high)
myLowest = min (myLowest,low)
endif
//--------------------------------------------------------------
if not onMarket and cTime and OTD then
buy 1 contract at myHighest + (1*pointSize) stop
sellShort 1 contract at myLowest - (1*pointSize) stop
endif
//-----------------------------------------------------------------
set stop pLoss 9
set target pProfit 6
```
murre87 thanked this post
11/09/2021 at 1:53 PM #181307 quote

Eric
Participant

Master

Beware of slippage

Had 13.5 points once[attachment file=”181308″]

Slippage.png

11/09/2021 at 2:30 PM #181310 quote

smp
Participant

Average

<span class=”bbp-author-name”>@murre87</span>

Hi, I tested the strategy as written on the DAX and it does not seem to work! I moved the hour to the open and it wins 100% of the time with a tweak using a 5 mon bar for direction backtested 100,000 units. See attached.

I will try a premarket tweak and see what tI can do!

DAX-BO.png

11/09/2021 at 3:00 PM #181313 quote

murre87
Participant

Senior

Great.

Share ur code 🙂

11/09/2021 at 6:45 PM #181327 quote

smp
Participant

Average

Hi, murre87 I thought I would write you a tweaked BOT, modified around stop and entry to improve with a little 5 min direction to help!

Anyone feel free to use or improve, I am going to post this to the library

murre87 thanked this post

DAX-Early-Bird.png Early-Bird-DAX-V1.0.itf

11/09/2021 at 7:25 PM #181331 quote
murre87
Participant

Senior
Thanks SMP.

Ur code in text. Im not getting same result as u. See last week..
```
//Early Bird Breakout Stratgy v1.0
//November 9th 2021
//www.harkoltd.com

//==========================================================
// Definition of code parameters
//UTC+1
DEFPARAM CumulateOrders = False // Cumulating positions deactivated
// Cancel all pending orders and close all positions at the "FLATAFTER" time
DEFPARAM FLATAFTER = 130000
// Prevents the system from placing new orders to enter the market or increase position size after the specified time
noEntryAfterTime = 110000
timeEnterAfter = time < noEntryAfterTime
//==========================================================
// Prevents the system from placing new orders on specified days of the week
daysForbiddenEntry = OpenDayOfWeek = 6 OR OpenDayOfWeek = 0
//==========================================================
//Stake limited to 1.5% aiming at 2.6% return, stop and profit
Stake=11.5
Spread=1
maxstop=13//9
Takeprofit=23//6
//==========================================================
//Limit to one trade
Trade = Barindex - TradeIndex(1) > IntradayBarIndex
//==========================================================
//Trading spread, entry of half spread
If Spread = 1 THEN
SpreadEntry = 0.5
ELSE
SpreadEntry = Spread
ENDIF
//==========================================================
//Leading breakout direction
Timeframe (5 MINUTE)
EMA1 = ExponentialAverage[10](close)
EMA2 = ExponentialAverage[12](close)
IF EMA1 > EMA2 AND EMA1 > EMA1[1] AND EMA2 > EMA2[1] THEN
LongNotShort = 1
ENDIF
IF EMA1 < EMA2 AND EMA1 < EMA1[1] AND EMA2 < EMA2[1] THEN
LongNotShort = 0
ENDIF
IF abs(EMA1 - EMA2) < 1 THEN
LongNotShort = 0.5
ENDIF
//==========================================================
//Entry timeframe
Timeframe (1 minute)
Opening = 090000
Start = time >=Opening
if openTime = 080000 then
myHighest = high
myLowest = low
endif
if openTime >= 080000 and openTime <=085900 then
myHighest = max (myHighest,high)
myLowest = min (myLowest,low)
endif
//==========================================================
If Start and Trade and timeEnterAfter and not daysForbiddenEntry then

// Conditions to enter long positions (0.5pt break)
IF LongNotShort = 1 THEN
BuyPrice = myHighest + SpreadEntry + 0.5
BUY stake PERPOINT AT BuyPrice stop
ENDIF
// Conditions to enter short positions
IF LongNotShort = 0 THEN
SellPrice = myLowest - SpreadEntry - 0.5
SELLSHORT stake PERPOINT AT SellPrice stop
ENDIF

SET STOP LOSS Maxstop
SET TARGET pPROFIT TakeProfit
endif
```
Earlybird.jpg
11/09/2021 at 9:27 PM #181337 quote

murre87
Participant

Senior

Some small changes

Earlybird1.1.jpg Early-Bird-DAX-V1.1.itf

11/09/2021 at 11:32 PM #181345 quote

phoentzs
Participant

Master

Can that work or is the DAX slippage tearing a hole in the account?

11/10/2021 at 6:41 AM #181350 quote
murre87
Participant

Senior
Values like this is not allowed by IG?
```
SET STOP pLOSS 0
SET STOP PTRAILING 1
SET TARGET pPROFIT 55
```
11/10/2021 at 8:54 AM #181352 quote

murre87
Participant

Senior

Does ptrailing and ploss be minimum 5?

Screenshot_20211110-085234_2Accounts-scaled.jpg

11/10/2021 at 9:09 AM #181355 quote

robertogozzi
Moderator

Master

The 3 lines are allowed, but the first one is immediately overridden by the second line, as only one STOP can be used and it’s always the last one executed.

Lines are read and executed sequentially.

11/10/2021 at 9:15 AM #181356 quote

phoentzs
Participant

Master

ptrailing does not work in Live and the minimum stop on the Dax is at least 5 points.
Author

Posts