List of all examples available in this topic:

• Example #1: support and resistance example, based on fractals points
• Example #2: probability cone
• Example #3: separate buy/sell volumes on the same candle
• Example #4: previous days pivot point
• Example #5: tag exact time and price of an event (2 MA cross over) in real time, during the same bar
• Example #6: Flat base triangle aka double top/bottom
• Example #7: calculate the Average Daily Range (ADR)

Example #1: support and resistance example, based on fractals points

This example calculate dynamically support and resistance zones based on 2 fractals found within a defined distance in percentage of price.

Each time a new fractal is found, the code stores the value and the barindex in 2 separate arrays (2 variables for tops and 2 other variables for bottoms).

On the last bar of the price chart, the code makes a loop through each index of the array, it selects the first index to compare it with all the other ones and if the distance in percentage is within the allowed threshold, then a new support or resistance zone is created. Then it moves to the next index and repeat and continue the loop. Note that I used nested loops in order to make the comparison.

The code embed these new instructions:

LastSet : Returns the last index of the array defined by the code. If no index was previously defined, the function returns -1.

Example: LASTSET($Array)

IsSet : Returns 1 if the index of the array has already been set in the code, otherwise returns 0.

Example: ISSET($MyArray[Index])

DrawPoint:Draws a point on the chart.

Example: DRAWPOINT (x,y,size) COLOURED (R,V,B,a) BORDERCOLOR  (R,V,B,a)

You can also notice that it is now possible to plot in the future of the chart (at the right of the curent price) by using BARINDEX+x (or with DateToBarIndex )

// https://www.prorealcode.com/topic/array-variables-availability-in-prorealtime/
// (please do not remove the link above for future reference)
// Example #1: support and resistance example, based on fractals points
defparam drawonlastbaronly=true

// --- settings 
fractalP = 10
percent = 0.5
barlimit = 500
// --- end of settings 

//fractals
cp=fractalP
 if high[cp] >= highest[(cp)*2+1](high) then //new fractal high found
  $TOPy[lastset($TOPy)+1] = high[cp] //store fractal value 
  $TOPx[lastset($TOPx)+1] = barindex[cp] //store fractal barindex
endif

if low[cp] <= lowest[(cp)*2+1](low)  then //new fractal low found
  $BOTy[lastset($BOTy)+1] = low[cp] //store fractal value 
  $BOTx[lastset($BOTx)+1] = barindex[cp] //stire fractal barindex
endif

if(islastbarupdate and isset($topy[0]) and isset($boty[0])) then
 //check points in a range of X percent
 for i = 0 to lastset($TOPy) do //loop through the tops
  for y = 0 to lastset($TOPy) do //check first top with other tops
   change=abs(($topy[y]-$topy[i])/$topy[i]) //percent range between the 2 tops
   if change<=percent/100 and barindex-$TOPx[y]<barlimit and $topx[i]<>$topx[y] then
    if close>min($topy[y],$topy[i]) then //define the color
     r=0
     g=255
    else
     r=255
     g=0
    endif
    //plot points at each tops
    DRAWPOINT($topx[i],$topy[i],2) COLOURED (r,g,0) BORDERCOLOR (r,g,0)
    DRAWPOINT($topx[y],$topy[y],2) COLOURED (r,g,0) BORDERCOLOR (r,g,0)
    midlevel=($topy[i]+$topy[y])/2
    //display the mid level price
    DRAWTEXT("#midlevel#", barindex+8, midlevel, monospaced, standard, 14)
    //plot the zone
    drawrectangle(min($topx[y],$topx[i]),$topy[y],barindex,$topy[i]) coloured(r,g,50,50) bordercolor(r,g,0)
   endif
  next
 next
 for i = 0 to lastset($BOTy) do //loop through the bottoms
  for y = 0 to lastset($BOTy) do //check first bottom with other bottoms
   change=abs(($boty[y]-$boty[i])/$boty[i]) //percent range between the 2 bottoms
   if change<=percent/100 and barindex-$BOTx[y]<barlimit and $BOTx[i]<>$BOTx[y] then
    if close<max($boty[y],$boty[i]) then //define the color
     r=255
     g=0
    else
     r=0
     g=255
    endif
    DRAWPOINT($botx[i],$boty[i],2) COLOURED (r,g,0) BORDERCOLOR (r,g,0)
    DRAWPOINT($botx[y],$boty[y],2) COLOURED (r,g,0) BORDERCOLOR (r,g,0)
    midlevel=($boty[i]+$boty[y])/2
    DRAWTEXT("#midlevel#", barindex+8, midlevel, monospaced, standard, 14)
    drawrectangle(min($botx[y],$botx[i]),$boty[y],barindex,$boty[i]) coloured(r,g,50,50) bordercolor(r,g,0)
   endif
  next
 next
endif

return

Feel free to fork the above code for your own needs (and please share it! 😉 ). The code is also attached below as an ITF file for convenience.

Very nice fork of this code, by stefou102 can also be found here: Support and resistance zones with variables arrays

Example #3: separate buy/sell volumes on the same candle

With variable array, it is now possible to store values and to re-use it inside the same bar. Previously, it was not possible to refer to the last value because variables were reset on each new tick received from the market.

IMPORTANT: arrays are not historized, they are decorrelated from the BARINDEX, it means that the arrays value from X bars ago is not saved in memory. It is not a drawback since you can save up to 1 million index which is the maximum of data history allowed now with version 11. Also, you can save your index into a normal variable and refer to it with its barindex offset (see example below, the ‘delta’ variable is used to store the difference of the 2 arrays, so that we can use it to compute an average over the last X periods!).

In this example, we use only 1 index / value for each variable array, to benefit from their “memories” on the current bar, in order to “separate” the bullish from the bearish volumes. By making the difference between the 2 arrays, we can make a sort of accurate cumulative delta and usable in any timeframe from ticks to daily and beyond.

// https://www.prorealcode.com/topic/array-variables-availability-in-prorealtime/
// (please do not remove the link above for future reference)
// Example #3: separate buy/sell volumes on the same candle 

if not isset($upvol[0]) then 
 $upvol[0] = 0
 $dnvol[0] = 0
endif

if islastbarupdate then
 if close>$lastclose[0]then 
  $upvol[0]=$upvol[0]+volume
 elsif close<$lastclose[0] then
  $dnvol[0]=$dnvol[0]+volume
 endif
 $lastclose[0]=close
 delta=($upvol[0]-$dnvol[0])
endif
avg=average[10](delta)

return $upvol[0] coloured(0,255,255) style(histogram) as "up volumes", -$dnvol[0] coloured(255,0,0) style(histogram) as "down volumes", delta style(line,3), avg

Example #4: previous days pivot point

In this simple example, the code is storing the daily pivot points values into an array. Each new day, the current pivot points is put into a new index of the table. That way, we can get at any time and without making new calculation, the X previous day(s) pivot points value (with DaysBack setting). It is as if we are creating our own constants that we can reuse at any time later in our code, therefore the possibilities are numerous!

// https://www.prorealcode.com/topic/array-variables-availability-in-prorealtime/
// (please do not remove the link above for future reference)
// Example #4: previous days pivot point

// --- settings 
DaysBack = 3
// --- end of settings 

if dclose(1)<>lastclose then //new day begin 
 index = lastset($pp)+1 //increment the index to save the current day pivot point 
 $pp[index] = (dhigh(1)+dlow(1)+dclose(1))/3 //save the pivot point of the day in new index of the array
 lastclose = dclose(1) //save the current Dclose(1) value to future check of new day
endif 

//get the pivot point for the Y previous day before now
mypivot = $pp[max(0,index-DaysBack)] //added MAX keyword to verify the result of the subscract is not inferior to 0

RETURN mypivot style(line,3)

In the attached picture, the “mypivot” line (thick white line) is plotting the pivot point from 2 days ago (DaysBack = 2).