Traduzione codice TV Setup 9.1 by Larry Williams

Viewing 5 posts - 1 through 5 (of 5 total)

Author

Posts
09/29/2022 at 6:22 AM #201617 quote

Msport71
Participant

Senior

Nicolas,

buongiorno.

Vorrei tuo cortese supporto per tradurre questo codice trovato nella libreria di tradingt View, per poterlo importare i PRT.

Ti ringrazio.

Carlo

—————————————————————————————–

study(“Larry Williams 9.1″, overlay=true)

ema9=ema(close,9)

ema9up= ema9>ema9[1]
colorup=(ema9up? #1cff78:na)

ema9down=ema9<ema9[1]
colordown = (ema9down ? #FF0000:na)

ema9n=not ema9up and not ema9down
colorn=(ema9n ? #ffeb3b: na)

plot(ema9, title=”EMA 9 UP”,linewidth=2,color=colorup,transp=0)
plot(ema9, title=”EMA 9 DOWN”,linewidth=2,color=colordown,transp=0)
plot(ema9, title=”EMA 9 N”,linewidth=2,color=colorn,transp=0)

// text signal

textbuy= high>high[1] and ema9[1]>ema9[2] and ema9[2]<ema9[3]

textsell= low< low[1]and ema9[1]<ema9[2] and ema9[2]>ema9[3]

plotshape(textbuy, title=”9.1 BUY”, style=shape.arrowup, location=location.belowbar, size=size.auto, text=”BUY 9.1″, color=#1cff78, transp=0, offset=0)
plotshape(textsell,title=”9.1 BUY”, style=shape.arrowdown, location=location.abovebar, size=size.auto, text=”SELL 9.1″, color=red, transp=0, offset=0)

//barcolor signal

buybarsignal= close>open and textbuy
sellbarsignal = close<open and textsell

barcolor(buybarsignal? #1cff78:na,title=”BuyBar 9.1″)
barcolor(sellbarsignal? #FF0000:na,title=”SellBar 9.1″)

09/29/2022 at 6:23 AM #201618 quote

Msport71
Participant

Senior

,

Screenshot-2022-09-29-at-07-19-42-Larrywiliams-—-Indicators-and-Signals-—-TradingView.png

09/29/2022 at 3:07 PM #201649 quote
Nicolas
Keymaster

Legend
Di seguito trovi il codice ” Larry Williams 9.1″ tradotto in ProRealTime:
```
//Larry Williams 9.1

ema9=average[9,1]

r=66
g=135
b=245
ema9up= ema9>ema9[1]
if ema9up then 
r=50
g=168
b=82
endif
ema9down=ema9<ema9[1]
if ema9down then 
r=252
g=186
b=3
endif

// text signal
textbuy= high>high[1] and ema9[1]>ema9[2] and ema9[2]<ema9[3]
textsell= low< low[1]and ema9[1]<ema9[2] and ema9[2]>ema9[3]
if textbuy then 
drawarrowup(barindex,low-averagetruerange[100]/2) coloured(66, 135, 245)
endif
if textsell then 
drawarrowdown(barindex,high+averagetruerange[100]/2) coloured("red")
endif

//barcolor signal
buybarsignal= close>open and textbuy
sellbarsignal = close<open and textsell

if buybarsignal then 
drawcandle(open,high,low,close) coloured(66, 135, 245)
endif
if sellbarsignal then 
drawcandle(open,high,low,close) coloured(252,186,3)
endif


return ema9 coloured(r,g,b) style(line,2)
```
Larry-Williams-9.1.png
09/29/2022 at 4:18 PM #201666 quote

Msport71
Participant

Senior

Ti ringrazio tantissimo per il tuo prezioso aiuto.

Buon pomeriggio.

09/29/2022 at 4:39 PM #201668 quote

Msport71
Participant

Senior

Ti ringrazio tantissimo per il tuo preziosissimo aiuto e la cortese tempestività.

Buon pomeriggio.
Author

Posts