DEFPARAM CUMULATEORDERS = FALSE
DEFPARAM NoCashUpdate = FALSE
DEFPARAM MinOrder = 1
//DEFPARAM FlatBefore = 100000
//DEFPARAM FlatAfter = 180000
MinSize = 10 //CAC40 0.5 //Forex 1
AmplitudeMax = 50
AmplitudeMin = 20
/*==============================================================================================================================*/
// Ecran 1 : définir la tendance de long terme
TIMEFRAME(Weekly, updateonclose)
MACDhistogram = MACD[12,26,9](close)
WeeklyC1 = MACDhistogram < 0 AND MACDhistogram[1] < 0
WeeklyC2 = MACDhistogram > 0 AND MACDhistogram[1] > 0
WeeklyC3 = MACDhistogram > MACDhistogram[1]
WeeklyC4 = MACDhistogram < MACDhistogram[1]
/*==============================================================================================================================*/
// Ecran 2 : Définir si la tendance intérmédiaire est dans le sens opposé de la tendance LT
TIMEFRAME(Daily, updateonclose)
DailyRSI = RSI[14](close)
DailySAR = SAR[0.02,0.02,0.2]
Haut = high[1]
Bas = low[1]
DailyAmplitude = abs(haut - bas)
// Calculer la taille de la position
DailyC1 = DailyRSI < 30
DailyC2 = DailyRSI > 70
DailyC3 = DailyAmplitude > AmplitudeMin AND DailyAmplitude < AmplitudeMax
/*==============================================================================================================================*/
// Ecran 3 : Placer les ordres d'achat et de vente
TIMEFRAME(1 hour, updateonclose)
// Conditions pour ouvrir une position à l'achat et pour fermer une position d'achat
OneHourC1 = Close CROSSES OVER Haut
OneHourC2 = Close CROSSES UNDER DailySAR
// Ouverture position acheteuse
IF NOT ONMARKET AND (WeeklyC1 OR WeeklyC2) AND WeeklyC3 AND DailyC1 AND DailyC3 AND Close CROSSES OVER Haut THEN
BUY MinSize CONTRACTS AT MARKET
ENDIF
// Clôture position acheteuse
IF LongOnMarket AND OneHourC2 THEN
SELL AT MARKET
ENDIF
// Conditions pour ouvrir une position à la vente et pour fermer une position à la vente
OneHourC3 = Close CROSSES UNDER Bas
OneHourC4 = Close CROSSES OVER DailySAR
// Ouverture position vendeuse
IF NOT OnMarket AND (WeeklyC1 OR WeeklyC2) AND WeeklyC4 AND DailyC2 AND DailyC3 AND OneHourC3 THEN
SELLSHORT MinSize CONTRACTS AT MARKET
ENDIF
// Clôture position vendeuse
IF ShortOnMarket AND OneHourC4 THEN
EXITSHORT AT MARKET
ENDIF
// STOP LOSS GARANTIE
SET STOP LOSS DailyAmplitude
IF STRATEGYPROFIT < -200 THEN
QUIT
ENDIF
.
