Price distance can be set at 2 points with SP500 with a clear conscience.

Is there a reason why you define TP and SL outside of the if block? Is this better from the encoding or just a coding style?

itfs

here’s the code for mine, so you can see the changes

//30.03.2022  200000k
//US500 M5 Spread 0.6
//UK Time

defparam preloadbars = 10000
defparam CUMULATEORDERS = false


possize = 5

//Tradetime
//UK time
h1 = 143000
h2 = 220000

//Euro time
//h1 = 153000
//h2 = 230000



//adjustment for American Daylight Savings time
ADLS =1
if ADLS then
DLS =(Date >= 20100314 and date <=20100328) or (Date >= 20101031 and date <=20101107) or (Date >= 20110313 and date <=20110327) or (Date >= 20111030 and date <=20111106) or (Date >= 20120311 and date <=20120325) or (Date >= 20121028 and date <=20121104) or (Date >= 20130310 and date <=20130331) or (Date >= 20131027 and date <=20131103) or (Date >= 20140309 and date <=20140330) or (Date >= 20141026 and date <=20141102) or (Date >= 20150308 and date <=20150329) or (Date >= 20151025 and date <=20151101) or (Date >= 20160313 and date <=20160327) or (Date >= 20161030 and date <=20161106) or (Date >= 20170312 and date <=20170326) or (Date >= 20171030 and date <=20171105) or (Date >= 20180311 and date <=20180325) or (Date >= 20181028 and date <=20181104) or (Date >= 20190310 and date <=20190331) or (Date >= 20191027 and date <=20191103) or (Date >= 20200308 and date <=20200329) or (Date >= 20201025 and date <=20201101) or (Date >= 20210314 and date <=20210328) or (Date >= 20211031 and date <=20211107) or (Date >= 20220313 and date <=20220327) or (Date >= 20221030 and date <=20221106) or (Date >= 20230312 and date <=20230326) or (Date >= 20231029 and date <=20231105) or (Date >= 20240310 and date <=20240331) or (Date >= 20241027 and date <=20241103)
If DLS then
Tradetime = time >=h1-10000 and time <h2-10000
elsif not DLS then
Tradetime = time >=h1 and time <h2
endif
endif

if not ADLS then
Tradetime = time >=h1 and time <h2
endif

timeframe(8 hour)
ma = average[a1,t1](typicalprice)
cb1 = ma > ma[1]
mb = average[a2,t2](typicalprice)
cs1 =  mb < mb[1]


timeframe(15 minutes)
MA1 = average[x1,t3](typicalprice)
MA2 = average[x2,t3](typicalprice)

MA4 = average[x5,t5](typicalprice)
MA5 = average[x6,t5](typicalprice)

cb2  = MA1 > MA2 //and MA2 > MA3 //and MA2 > MA2[1]
cs2 = MA4 < MA5 //and MA5 < MA5[1]




timeframe(default)//M5
MAL1 = average[a7,t7](typicalprice)
MAL2 = average[a8,t7](typicalprice) //15
cb3  = MAL1 crosses over MAL2
cs3 = MAL1 crosses under MAL2


long   =   cb1 and cb2 and cb3     //and RangelongD20
short  =   cs1 and cs2 and cs3  //and RangeshortD20



 
// position management
IF Tradetime THEN
If long then                           //not onmarket and
BUY possize CONTRACT AT market
SET STOP %LOSS hl
SET TARGET %PROFIT gl
EndIf

If short then
sellshort possize CONTRACT AT market
SET STOP %LOSS hs
SET TARGET %PROFIT gs
EndIf
endif


If longonmarket and cs1 then
sell at market
endif

If shortonmarket and cb1 then
exitshort at market
endif
 


////////////////////////////////////////

phoentzs wrote:

the Roberto Trail is that it uses points instead of percent

this version has a % option:

//RGTS2
ONCE RGTS2 = 1
if RGTS2 then

ONCE UseCLOSE = 0                        //1=use CLOSE,  0=use High/Low
srcH = close                                      //defaults to CLOSE
srcL = close                                      //defaults to CLOSE
IF UseCLOSE = 0 THEN
srcH = high
srcL = low
ENDIF
ONCE UsePerCentage = 1                            //0=use Pips  (default), 1=use Percentages
ONCE UseEquity     = 0                            //0=use price (default), 1=use current Equity (initial Capital + StrategyProfit, as defined by variable MyEquity)
MyEquity = 0
DirectionSwitch = (LongOnMarket AND ShortOnMarket[1]) OR (LongOnMarket[1] AND ShortOnMarket)  //True when there's been a change in the direction (likely to be due to a Stop & Reverse)
//
IF Not OnMarket OR DirectionSwitch THEN
//
// when NOT OnMarket or thare's been a change in direction, reset values to their default settings
//
StartPerCent  = pc //0.25  = 0.25%  to start triggering Trailing Stop       (when UsePerCentage=1)
StartPerCentShort  = pcs
StepPerCent   = spc //50  = 50%    (of the 0.25% above) as a Trailing Step (when UsePerCentage=1) (set to 100 to make StepSize=TrailStart, set to 200 to make it twice TrailStart)
//
TrailStart    = 30          //30     Start trailing profits from this point  (when UsePerCentage=0)
MinStart      = 10          //10     Minimum value for TrailStart            (when UseEquity=1, to prevent TrailStart from dropping below ZERO when Equity turns negative)
IF UsePerCentage THEN
TrailStart = (close / PipSize) * StartPerCent / 100    //use current price (CLOSE) for calculations
TrailStartShort = (close / PipSize) * StartPerCentShort / 100
IF UseEquity THEN                                             //alternative calculations using EQUITY
TrailStart = Max(MinStart,(MyEquity / PipValue) * StartPerCent / 100)  //MyEquity is the variable (feel free to use a different name) retaining your current equity
ENDIF
ENDIF
//
BasePerCent   = bpc //0.08 - 0.2  Profit percentage to keep when setting BerakEven
//
StepSize      = ss //5 - 15     Pip chunks to increase Percentage
IF UsePerCentage THEN
StepSize   = TrailStart * StepPerCent / 100
ENDIF
//
PerCentInc    = pci //0.06 - 0.14  PerCent increment after each StepSize chunk
RoundTO       = rnd        //-0.5   rounds always to Lower integer,   +0.4 rounds always to Higher integer,     0 defaults PRT behaviour
PriceDistance = IG * pipsize //IG minimum distance from current price
y1            = 0           //reset to 0
y2            = 0           //reset to 0
ProfitPerCent = BasePerCent //reset to desired default value
//PositionCount = 0
SellPrice     = 0
SellPriceX    = 0
ExitPrice     = 9999999
ExitPriceX    = 9999999
ELSE
//------------------------------------------------------
// --- Update Stop Loss after accumulating new positions
//------------------------------------------------------
//PositionCount = max(PositionCount,abs(CountOfPosition))
//
// update Stop Loss only when PositionPrice has changed (actually when increased, we don't move it if there's been some positions exited)
//
//IF PositionCount <> PositionCount[1] AND (ExitPrice + SellPrice)<>9999999 THEN //go on only if Trailing Stop had already started trailing
IF PositionPrice <> PositionPrice[1] AND (ExitPrice + SellPrice) <> 9999999 THEN //go on only if Trailing Stop had already started trailing
IF LongOnMarket THEN
q1         = PositionPrice + ((srcH - PositionPrice) * ProfitPerCent)      //calculate new SL
SellPriceX = max(max(SellPriceX,SellPrice),q1)
SellPrice  = max(max(SellPriceX,SellPrice),PositionPrice + (y1 * pipsize)) //set exit price to whatever grants greater profits, comopared to the previous one
ELSIF ShortOnMarket THEN
r1         = PositionPrice - ((PositionPrice - srcL) * ProfitPerCent)      //calculate new SL
ExitPriceX = min(min(ExitPriceX,ExitPrice),r1)
ExitPrice  = min(min(ExitPriceX,ExitPrice),PositionPrice - (y2 * pipsize)) //set exit price to whatever grants greater profits, comopared to the previous one
ENDIF
ENDIF
// --- Update END
ENDIF
//
IF LongOnMarket AND srcH > (PositionPrice + (y1 * pipsize)) THEN                              //LONG positions
//
// compute the value of the Percentage of profits, if any, to lock in for LONG trades
//
x1 = (srcH - PositionPrice) / pipsize                                     //convert price to pips
IF x1 >= TrailStart THEN                                                //    go ahead only if N+ pips
Diff1         = abs(TrailStart - x1)                                 //difference from current profit and TrailStart
Chunks1       = max(0,round((Diff1 / StepSize) + RoundTO))           //number of STEPSIZE chunks
ProfitPerCent = BasePerCent + (BasePerCent * (Chunks1 * PerCentInc)) //compute new size of ProfitPerCent
ProfitPerCent = max(ProfitPerCent[1],min(100,ProfitPerCent))         //make sure ProfitPerCent doess not exceed 100%
y1 = max(x1 * ProfitPerCent, y1)                                     //y1 = % of max profit
ENDIF
ELSIF ShortOnMarket AND srcL < (PositionPrice - (y2 * pipsize)) THEN                             //SHORT positions
//
// compute the value of the Percentage of profits, if any, to lock in for SHORT trades
//
x2 = (PositionPrice - srcL) / pipsize                                     //convert price to pips
IF x2 >= TrailStartShort THEN                                                //      go ahead only if N+ pips
Diff2         = abs(TrailStartShort - x2)                                 //difference from current profit and TrailStart
Chunks2       = max(0,round((Diff2 / StepSize) + RoundTO))           //number of STEPSIZE chunks
ProfitPerCent = BasePerCent + (BasePerCent * (Chunks2 * PerCentInc)) //compute new size of ProfitPerCent
ProfitPerCent = max(ProfitPerCent[1],min(100,ProfitPerCent))         //make sure ProfitPerCent doess not exceed 100%
y2 = max(x2 * ProfitPerCent, y2)                                     //y2 = % of max profit
ENDIF
ENDIF
//------------------------------------------------------------------------------
//                    manage actual Exit, if needed
//------------------------------------------------------------------------------
IF y1 THEN                                                                 //Place pending STOP order when y1 > 0   (LONG positions)
SellPrice = max(SellPrice,PositionPrice + (y1 * pipsize))                  //convert pips to price
//
// check the minimun distance between ExitPrice and current price
//
IF abs(close - SellPrice) > PriceDistance THEN
//
// place either a LIMIT or STOP pending order according to current price positioning
//
IF close >= SellPrice THEN
SELL AT SellPrice STOP
ELSE
SELL AT SellPrice LIMIT
ENDIF
ELSE
//
//sell AT MARKET when EXITPRICE does not meet the broker's minimun distance from current price
//
SELL AT Market
ENDIF
ENDIF
IF y2 THEN                                                                 //Place pending STOP order when y2 > 0   (SHORT positions)
ExitPrice = min(ExitPrice,PositionPrice - (y2 * pipsize))                  //convert pips to price
//
// check the minimun distance between ExitPrice and current price
//
IF abs(close - ExitPrice) > PriceDistance THEN
//
// place either a LIMIT or STOP pending order according to current price positioning
//
IF close <= ExitPrice THEN
EXITSHORT AT ExitPrice STOP
ELSE
EXITSHORT AT ExitPrice LIMIT
ENDIF
ELSE
//
//ExitShort AT MARKET when EXITPRICE does not meet the broker's minimun distance from current price
//
EXITSHORT AT Market
ENDIF
ENDIF
ENDIF

I mostly use this one (above) – has a few more options and usually gives better results. I added a separate TrailStartShort as it often helps to have different values there.