Questo codice è complicato perché non abbiamo gli stessi strumenti in ProRealTime.
Quello che le passo è un modo per affrontarlo e calcolare i pivot a 15 minuti, 30 minuti e 1 ora.
Può regolare i timeframe a sua convenienza.

DEFPARAM DrawOnLastBarOnly = true
// Parámetros de usuario
leftBars = 7
rightBars = 7
src1 = low
src2 = high
// ======================
// Pivotes en 1h
// ======================
TIMEFRAME(1 hour, updateonclose)
if src2 < src2[rightbars] and highest[rightbars](src2)<=src2[rightbars] and src2[rightbars]>highest[leftbars](src2)[rightbars+1] then
   checkHigh1H=1
   ph60=src2[rightBars]
   phIdx60=barindex[rightBars]
endif
if src1 > src1[rightbars] and lowest[rightbars](src1) >= src1[rightbars] and src1[rightbars] < lowest[leftbars](src1)[rightbars+1] then
   pl60=src1[rightBars]
   plIdx60=barindex[rightBars]
endif
// ======================
// Pivotes en 30m
// ======================
TIMEFRAME(30 minutes, updateonclose)
if src2 < src2[rightbars] and highest[rightbars](src2)<=src2[rightbars] and src2[rightbars]>highest[leftbars](src2)[rightbars+1] then
   ph30=src2[rightBars]
   phIdx30=barindex[rightBars]
endif
if src1 > src1[rightbars] and lowest[rightbars](src1) >= src1[rightbars] and src1[rightbars] < lowest[leftbars](src1)[rightbars+1] then
   pl30=src1[rightBars]
   plIdx30=barindex[rightBars]
endif
// ======================
// Pivotes en 15m
// ======================
TIMEFRAME(15 minutes)
atr=averagetruerange[14](close)
if src2 < src2[rightbars] and highest[rightbars](src2)<=src2[rightbars] and src2[rightbars]>highest[leftbars](src2)[rightbars+1] then
   ph15=src2[rightBars]
   phIdx15=barindex[rightBars]
   $phigh15[r+1]=ph15
   $phighIdx15[r+1]=phIdx15
   $phighIdxRight15[r+1]=barindex
   r=r+1
endif

if src1 > src1[rightbars] and lowest[rightbars](src1) >= src1[rightbars] and src1[rightbars] < lowest[leftbars](src1)[rightbars+1] then
   pl15=src1[rightBars]
   plIdx15=barindex[rightBars]
   $plow15[t+1]=pl15
   $plowIdx15[t+1]=plIdx15
   $plowIdxRight15[t+1]=barindex
   t=t+1
endif

if ph30<>ph30[1] then
   $phigh30[m+1]=ph30
   $phighIdx30[m+1]=barindex[rightBars*2]
   $phighIdxRight30[m+1]=barindex
   m=m+1
endif

if pl30<>pl30[1] then
   $plow30[q+1]=pl30
   $plowIdx30[q+1]=barindex[rightBars*2]
   $plowIdxRight30[q+1]=barindex
   q=q+1
endif

if ph60<>ph60[1] then
   $phigh60[n+1]=ph60
   $phighIdx60[n+1]=barindex[rightBars*4]
   $phighIdxRight60[n+1]=barindex
   n=n+1
endif

if pl60<>pl60[1] then
   $plow60[z+1]=pl60
   $plowIdx60[z+1]=barindex[rightBars*4]
   $plowIdxRight60[z+1]=barindex
   z=z+1
endif

// ======================
// Dibujo de pivotes
// ======================
timeframe(default)
if islastbarupdate then
   
   for i=1 to t do
      drawpoint($plowIdx15[i],$plow15[i],1)coloured("blue")
      drawrectangle($plowIdx15[i]-3,$plow15[i]+0.5*atr,$plowIdxRight15[i],$plow15[i]-0.5*atr)coloured("blue")fillcolor("blue",150)
   next
   for i=1 to r do
      drawpoint($phighIdx15[i],$phigh15[i],1)coloured("red")
      drawrectangle($phighIdx15[i]-3,$phigh15[i]+0.5*atr,$phighIdxRight15[i],$phigh15[i]-0.5*atr)coloured("red")fillcolor("red",150)
   next
   
   for i=1 to q do
      drawrectangle($plowIdx30[i],$plow30[i]+0.75*atr,$plowIdxRight30[i],$plow30[i]-0.75*atr)coloured("blue")fillcolor("blue",90)
   next
   
   for i=1 to m do
      drawrectangle($phighIdx30[i],$phigh30[i]+0.75*atr,$phighIdxRight30[i],$phigh30[i]-0.75*atr)coloured("red")fillcolor("red",90)
   next
   
   for i=1 to z do
      drawrectangle($plowIdx60[i],$plow60[i]+atr,$plowIdxRight60[i],$plow60[i]-atr)coloured("blue")fillcolor("blue",45)
   next
   
   for i=1 to n do
      drawrectangle($phighIdx60[i],$phigh60[i]+atr,$phighIdxRight60[i],$phigh60[i]-atr)coloured("red")fillcolor("red",45)
   next
   
endif
RETURN