I’ve imported the code but it does not seem to work. I do not understand why! Can someone help me?

Screenshot-2017-08-05-13.24.37.png

Good Morning,
I have been using the V2 version of the Navigator System in the demo account since March and the results do not correspond exactly with the backtest ones. Anyway, the drowndown of V2 is still very high.
I have modified some code parameters to reduce the drowndown and, although it only performs half of operations. I leave the code.
Is someone running it on a real account?
Best regards.

// Navigator DAX 4H V2 (5K)
// Navigator Trading System based on ProRealTime 10.3
// The algo based on the statistical advantage of the TDOM (trading day of the month) idea around the turn of the month
// Version 2
// Instrument: DAX mini 1 EUR, 4H, 9-17 CET, 1 point spread, account size 10.000 Euro

// ProOrder code parameter
DEFPARAM CUMULATEORDERS = true // cumulate orders

// define TDOM days
ONCE tradingDaySell = 20
ONCE tradingDayBuy = 8

// define intraday trading window
ONCE timeSell = 090000
ONCE timeBuy = 170000

// define position and money management parameter
ONCE positionSize = 1
ONCE maxPositionSizeLong = 4
ONCE maxPositionSizeShort = 4

ONCE minSizeLong = 1
ONCE midSizeLong = 2
ONCE maxSizeLong = 4
ONCE maxSizeShort = -10

ONCE stopLossLong = 8 // in %
ONCE takeProfitLong = 3 // in %
ONCE stopLossShort = 2 // in %
ONCE takeProfitShort = 1.25 // in %

ONCE maxCandlesLongWithProfit = 40
ONCE maxCandlesShortWithProfit = 6
ONCE maxCandlesLongWithoutProfit = 41
ONCE maxCandlesShortWithoutProfit = 13

// define position multiplier for each month (>0 - long / <0 - short / 0 - no trade)
ONCE longJanuary = 0
ONCE shortJanuary = maxSizeShort
ONCE longFebruary = 0
ONCE shortFebruary = maxSizeShort
ONCE longMarch = maxSizeLong
ONCE shortMarch = 0
ONCE longApril = minSizeLong
ONCE shortApril = 0
ONCE longMay = minSizeLong
ONCE shortMay = maxSizeShort
ONCE longJune = minSizeLong
ONCE shortJune = 0
ONCE longJuly = midSizeLong
ONCE shortJuly = maxSizeShort
ONCE longAugust = 0
ONCE shortAugust = maxSizeShort
ONCE longSeptember = 0
ONCE shortSeptember = maxSizeShort
ONCE longOctober = midSizeLong
ONCE shortOctober = maxSizeShort
ONCE longNovember = midSizeLong
ONCE shortNovember = maxSizeShort
ONCE longDecember = midSizeLong
ONCE shortDecember = maxSizeShort

// calculate TDOM
IF Month <> Month[1] THEN
tradingDay = 0
ENDIF
IF Time = 90000 THEN
IF CurrentDayOfWeek > 0 AND CurrentDayOfWeek < 6 THEN
tradingDay = tradingDay + 1
ENDIF
ENDIF

// set montly multiplier
IF CurrentMonth = 1 THEN
monthlyMultiplierLong = longJanuary
monthlyMultiplierShort = shortJanuary
ELSIF CurrentMonth = 2 THEN
monthlyMultiplierLong = longFebruary
monthlyMultiplierShort = shortFebruary
ELSIF CurrentMonth = 3 THEN
monthlyMultiplierLong = longMarch
monthlyMultiplierShort = shortMarch
ELSIF CurrentMonth = 4 THEN
monthlyMultiplierLong = longApril
monthlyMultiplierShort = shortApril
ELSIF CurrentMonth = 5 THEN
monthlyMultiplierLong = longMay
monthlyMultiplierShort = shortMay
ELSIF CurrentMonth = 6 THEN
monthlyMultiplierLong = longJune
monthlyMultiplierShort = shortJune
ELSIF CurrentMonth = 7 THEN
monthlyMultiplierLong = longJuly
monthlyMultiplierShort = shortJuly
ELSIF CurrentMonth = 8 THEN
monthlyMultiplierLong = longAugust
monthlyMultiplierShort = shortAugust
ELSIF CurrentMonth = 9 THEN
monthlyMultiplierLong = longSeptember
monthlyMultiplierShort = shortSeptember
ELSIF CurrentMonth = 10 THEN
monthlyMultiplierLong = longOctober
monthlyMultiplierShort = shortOctober
ELSIF CurrentMonth = 11 THEN
monthlyMultiplierLong = longNovember
monthlyMultiplierShort = shortNovember
ELSIF CurrentMonth = 12 THEN
monthlyMultiplierLong = longDecember
monthlyMultiplierShort = shortDecember
ENDIF

// all in if first day of month is Monday or Thuesday
IF tradingDay = tradingDayBuy AND ( CurrentDayOfWeek = 1 OR CurrentDayOfWeek = 2 ) THEN
monthlyMultiplierLong = maxSizeLong
ENDIF

// caculate current position profit
posProfit = (((close - positionprice) * pointvalue) * countofposition) / pipsize

// open long position with order cumulation
l1 = tradingDay = tradingDayBuy
l2 = tradingDay > tradingDayBuy AND posProfit < 0

IF ( (l1 OR l2) AND Time = timeBuy) THEN
// check monthly setup and max position size
IF monthlyMultiplierLong > 0 THEN
IF (COUNTOFPOSITION + (positionSize * monthlyMultiplierLong)) <= maxPositionSizeLong THEN
BUY positionSize * monthlyMultiplierLong CONTRACT AT MARKET
ENDIF
ELSIF monthlyMultiplierLong <> 0 THEN
IF (COUNTOFPOSITION + positionSize) <= maxPositionSizeLong THEN
BUY positionSize CONTRACT AT MARKET
ENDIF
ENDIF

stopLoss = stopLossLong
takeProfit = takeProfitLong
ENDIF

// sell short if valid month or close position only
s1 = tradingDay = tradingDaySell

IF ( s1 AND Time = timeSell ) THEN
// check monthly setup and max position size
IF monthlyMultiplierShort < 0 THEN
IF (COUNTOFPOSITION + (positionSize * ABS(monthlyMultiplierShort))) <= maxPositionSizeShort THEN
SELLSHORT positionSize * ABS(monthlyMultiplierShort) CONTRACT AT MARKET
ENDIF
ELSIF monthlyMultiplierShort <> 0 THEN
IF (COUNTOFPOSITION + positionSize) <= maxPositionSizeShort THEN
SELLSHORT positionSize CONTRACT AT MARKET
ENDIF
ELSIF monthlyMultiplierShort = 0 THEN
SELL AT MARKET
ENDIF

stopLoss = stopLossShort
takeProfit = takeProfitShort
ENDIF

// stop and profit management
numberCandles = (BarIndex - TradeIndex)

m1 = posProfit > 0 AND numberCandles >= maxCandlesLongWithProfit
m2 = posProfit > 0 AND numberCandles >= maxCandlesShortWithProfit
m3 = posProfit < 0 AND numberCandles >= maxCandlesLongWithoutProfit
m4 = posProfit < 0 AND numberCandles >= maxCandlesShortWithoutProfit

// take profit after max candles
IF LONGONMARKET AND (m1 OR m3) THEN
SELL AT MARKET
ENDIF
IF SHORTONMARKET AND (m2 OR m4) THEN
EXITSHORT AT MARKET
ENDIF

SET STOP %LOSS stopLoss
SET TARGET %PROFIT takeProfit

Navigator-5K.png Navigator-demo-vs-real.png