Really impressive, thanks for sharing! 🙂

One thing you might want to look at is the section starting at line 73 above. In a 10 year backtest no trades have gone to 1600 bars so those values are doing nothing. This is also the case for the Breakout code you posted.

This is the snippet I use for that function, closes very long-running positions whether they’re winning or losing. You have to optimise for b1 and b2 (b3, b4 for short).

//EXIT ZOMBIE TRADE
EZT = 1
if EZT then
IF longonmarket and (barindex-tradeindex(1)>= b1 and positionperf>0) or (barindex-tradeindex(1)>= b2 and positionperf<0) then
sell at market
endif
IF shortonmarket and (barindex-tradeindex(1)>= b3 and positionperf>0) or (barindex-tradeindex(1)>= b4 and positionperf<0) then
exitshort at market
endif
endif

b1 if it’s winning, b2 if it’s losing.

but I should add that this isn’t always advantageous, you should also try switching it off, with some algos it’s better to just let them run.

nonetheless wrote:

but I should add that this isn’t always advantageous, you should also try switching it off, with some algos it’s better to just let them run.

Without this remark I already wanted to add :

I have attempted so many means of exiting because of too long “useless” trades. They always and always net lose. Otherwise this will be highly subject to curve fitting, IMO.

BUT

Only last week I applied a “strange” means for this : let shrink the SL per bar (or once in the so many, also OK). This seems counterproductive, but the contrary appears true. This starts with allowing for a higher SL (avoid peaks at entry) which is psychologically good. Next the losses because or running into the SL in practice are not that high at all. But moreover, this works out. For me it does …
Warning : I am almost sure that we should not change the StopLoss per bar because the broker may not like that. Eh, *if* possible at all. So it needs to be your own exit (like the example code in the earlier post) and NOT changing the StopLoss each time.

I played a bit with the strategy, on DAX 1€, 200K units, 5 min-TF (mtf), changing just TP & SL and slightly the Trailing Stop to use PointsToKeep as sort of a trailing step. Performance is nice and WF is around 25%. I also commented out exiting on RSI:

//================================================
//https://www.prorealcode.com/topic/nasdaq-mean-reversion/
//
//   Code:    TEST KD3 Mean Reverting v1.3
//   Source:  https://www.youtube.com/watch?v=D_P_XqB5nHs
//            Entry Strategy #3 Mean REverting
//   Author:  Kevin Davey
//   Version  1
//   Index:   DAX    (ex NASDAQ)
//   TF:      15 min
//   TZ:      Europe
//   Notes:   v1.1 Long Olny
//   Notes:   v1.2 Entry Filter (optimised to 150 MA)
//   Notes:   v1.3 Day of week - do not trade Friday's
//
//   Pending  Test Short side
//            Reduce Drawdown (Long Entry Filter)
//================================================

DEFPARAM CUMULATEORDERS = FALSE
Timeframe(2h,UpdateOnClose)                                        //1h
//Risk Management
nLots=1

//=== Entry Filter ===
//Filter 1
indicator1 = average[150,7]                //150,7
F1 = close>indicator1
F2 = close<indicator1

//Range Parameters
Nbars = 15                                 //15
Pbars = 10                                 //10

//Entry Criteria
indicator1 = Volume
c1 = (indicator1 < indicator1[Nbars])

// Conditions to enter long positions
If close > lowest[Pbars](low) and c1 and opendayofweek <> 5 and F1 and Not OnMarket then
Buy nLots CONTRACTS AT MARKET
ENDIF

// Conditions to enter short positions
If close < highest[Pbars](high) and c1 and opendayofweek <> 5 and F2 and Not OnMarket then
//SELLSHORT nLots CONTRACTS AT MARKET
ENDIF

// Stops and targets
SET STOP   pLOSS   50                      //50
SET TARGET pPROFIT 70                      //75

once openStrongLong  = 0
once openStrongShort = 0
if (time <= 090000 or time >= 210000) then   //090000 - 210000
openStrongLong  = 0
openStrongShort = 0
endif

//detect strong direction for market open
once rangeOK  = 30
once tradeMin = 2500
IF (time >= 090500) AND (time <= 090500 + tradeMin) AND ABS(close - open) > rangeOK THEN
IF close > open and close > open[1] THEN
openStrongLong  = 1
openStrongShort = 0
ENDIF
IF close < open and close < open[1] THEN
openStrongLong  = 0
openStrongShort = 1
ENDIF
ENDIF

once bollperiod = 20
once bollMAType = 1
once s          = 2

bollMA = average[bollperiod, bollMAType](close)
STDDEV = STD[bollperiod]
bollUP = bollMA + s * STDDEV
bollDOWN = bollMA - s * STDDEV
IF bollUP = bollDOWN THEN
bollPercent = 50
ELSE
bollPercent = 100 * (close - bollDOWN) / (bollUP - bollDOWN)
ENDIF

once trendPeriod       = 80
once trendPeriodResume = 10
once trendGap          = 4
once trendResumeGap    = 4
if not onmarket then
fullySupported      = 0
fullyResisteded     = 0
endif
//Market supported in the wrong direction
IF shortonmarket AND fullySupported = 0 AND summation[trendPeriod](bollPercent > 50) >= trendPeriod - trendGap THEN
fullySupported      = 1
ENDIF

//Market pull back but continue to be supported
IF shortonmarket AND fullySupported = 1 AND bollPercent[trendPeriodResume + 1] < 0 AND summation[trendPeriodResume](bollPercent > 50) >= trendPeriodResume - trendResumeGap THEN
exitshort at market
ENDIF

//Market resisted in wrong direction
IF longonmarket AND fullyResisteded = 0 AND summation[trendPeriod](bollPercent < 50) >= trendPeriod - trendGap THEN
fullyResisteded     = 1
ENDIF

//Market pull back but continue to be resisted
IF longonmarket AND fullyResisteded = 1 AND bollPercent[trendPeriodResume + 1] > 100 AND summation[trendPeriodResume](bollPercent < 50) >= trendPeriodResume - trendResumeGap THEN
sell at market
ENDIF

//Started real wrong direction
once strongTrend    = 60         //60
once strongPeriod   = 4          //4
once strongTrendGap = 2          //2
IF shortonmarket and openStrongLong and barindex - tradeindex < 12 and summation[strongPeriod](bollPercent > strongTrend) = strongPeriod - strongTrendGap then
exitshort at market
ENDIF

IF longonmarket and openStrongShort and barindex - tradeindex < 12 and summation[strongPeriod](bollPercent < 100 - strongTrend) = strongPeriod - strongTrendGap then
sell at market
ENDIF

//SET STOP $LOSS stoploss
Timeframe(default)                                                 //5 min
//                  Breakeven & Trailing Stop
startBreakeven = 25                   //25
PointsToKeep   = 5                    //5
Distance       = 6                    //6
//
IF NOT ONMARKET THEN
breakevenLevel=0
ENDIF
//
// --- BUY SIDE ---
//test if the price have moved favourably of "startBreakeven" points already
IF LONGONMARKET AND close-tradeprice(1)>=(startBreakeven*pipsize+PointsToKeep*pipsize) and breakevenlevel = 0 THEN
//calculate the breakevenLevel
breakevenLevel = tradeprice(1)+PointsToKeep*pipsize
ENDIF
IF LONGONMARKET AND close-breakevenlevel>=(startBreakeven*pipsize) and breakevenlevel > 0 THEN
breakevenLevel = breakevenlevel+PointsToKeep*pipsize
ENDIF
 
//place the new stop orders on market at breakevenLevel
IF breakevenLevel>0 THEN
IF close > (breakevenlevel + Distance) THEN
SELL AT breakevenLevel STOP
IF close < (breakevenlevel - Distance) THEN
SELL AT breakevenLevel LIMIT
ELSE
SELL AT Market
ENDIF
ENDIF
ENDIF
//************************************************************************
ONCE MaxBars = 305           //305
//
IF longonmarket and barindex-tradeindex>MaxBars then//and close<positionprice then
sell at market
endif
IF shortonmarket and barindex-tradeindex>MaxBars then//and close>positionprice then
exitshort at market
endif

//===================================
myrsiM5=rsi[14](close)
//
if myrsiM5<30 and barindex-tradeindex>1 and longonmarket and close>positionprice then
//sell at market
endif
if myrsiM5>70 and barindex-tradeindex>1 and shortonmarket and close<positionprice then
//exitshort at market
endif
//===================================