LNEAS DE TENDENCIA CON BREAKOUTS EN RSI

holà
aqui esta el codigo utilizado para cualquier discrepancia en obv rsi macd

//    by Jose Callao
//    twitter @jose7674
//
//N      = 40                      //N is the number of bars to look back for a divergence.
//                                   Normal values are 20-40. Must be the same in both indicators
//
MiRSI  = RSI[14](close)
Offset = MiRSI * 0.1
IF (BarIndex > 10+1+N) THEN
///divergencia bajista
IF (miRSI[1]>miRSI AND miRSI[1]>miRSI[2]) THEN
extremum2=miRSI[1]
extremum1=highest[N](miRSI)
preciomax2=close[1]
preciomax=Highest[N](close)
IF(extremum2<extremum1 AND preciomax2>preciomax[1]) THEN
for i=1 to N
if miRSI[i]=extremum1 then
zz=i
drawsegment (barindex[1], miRSI[1]+Offset, barindex[zz], miRSI[zz]+Offset) coloured("RED")STYLE(line,4)
endif
next
endif
endif
///divergencia alcista
IF (miRSI[1]<miRSI AND miRSI[1]<miRSI[2]) THEN
extremum22=miRSI[1]
extremum11=lowest[N](miRSI)
preciomin2=close[1]
preciomin=lowest[N](close)
IF(extremum22>extremum11 AND preciomin2<preciomin[1]) THEN
for i2=1 to N
if miRSI[i2]=extremum11[1] then
zz2=i2
drawsegment(barindex[1], miRSI[1]-Offset, barindex[zz2], miRSI[zz2]-Offset) coloured("DARKGREEN")STYLE(line,4)
endif
next
ENDIF
ENDIF
endif
return miRSI as "RSI", 50 as "50"

Buenas tardes
Aquí tienes el indicador mostrando los breakouts del RSI.

defparam DRAWONLASTBARONLY=false
////inputs/////////////////
BarsAfter = 8
BarsBefore = 8
BarLookBack  = BarsAfter + 1
////RSI
myrsi = rsi[14](close)
/////pivots low
IF myrsi[BarsAfter] < lowest[BarsBefore](myrsi)[BarLookBack] THEN
IF myrsi[BarsAfter] = lowest[BarLookBack](myrsi) THEN
$ply[z]  = myrsi[BarsAfter]
$plx[z] = barindex-BarsAfter
z=z+1
ENDIF
ENDIF
/////pivots low line
//(x-x1)/(x2-x1) = (y-y1)/(y2-y1)
y2 = $ply[max(z-1,1)]
x2 = $plx[max(z-1,1)]
y1 = $ply[max(z-2,1)]
x1 = $plx[max(z-2,1)]
xl = barindex
yl = y1+(xl-x1)*(y2-y1)/(x2-x1)
//draw line only when rsi is over the line
if y2 > y1 then
drawsegment(x1,y1,x2,y2)coloured("red")
//look for the cross under
if myrsi crosses under yl then
drawarrowdown(xl,yl+5)coloured("red")
drawsegment(x2,y2,xl,yl)style(dottedline,2)coloured("red")
endif
endif
/////pivots high
if myrsi[Barsafter] > highest[BarsBefore](myrsi)[BarLookBack] THEN
IF myrsi[BarsAfter] = highest[BarLookBack](myrsi) THEN
$phy[n]  = myrsi[BarsAfter]
$phx[n] = barindex-BarsAfter
n=n+1
ENDIF
ENDIF
/////pivots high line
////(x-x1)/(x2-x1) = (y-y1)/(y2-y1)
y22 = $phy[max(n-1,1)]
x22 = $phx[max(n-1,1)]
y11 = $phy[max(n-2,1)]
x11 = $phx[max(n-2,1)]
xh = barindex
yh = y11+(xh-x11)*(y22-y11)/(x22-x11)
//draw line only when rsi is under the line
if y22 < y11 then
drawsegment(x11,y11,x22,y22)coloured("green")
//look for the cross over
if myrsi crosses over yh then
drawarrowup(xh,yh-5)coloured("green")
drawsegment(x22,y22,xh,yh)style(dottedline,2)coloured("green")
endif
endif
/////////////////////////////

return myrsi as "RSI" coloured(250,250,250)style(line,2)

Agregué dos opciones del código original (repintar y rsiDiff) y simplifiqué el anidamiento de condiciones.

defparam DRAWONLASTBARONLY=false
////inputs/////////////////
BarLookBack = 8
repaint = 0
RSIdiff = 2
////RSI
myrsi = rsi[14](close)
/////pivots low
IF myrsi[repaint*BarLookBack+1] = lowest[repaint*BarLookBack+BarLookBack+1](myrsi) THEN
$ply[z] = myrsi[repaint*BarLookBack+1]
$plx[z] = barindex-(repaint*BarLookBack+1)
z=z+1
ENDIF

/////pivots low line
//(x-x1)/(x2-x1) = (y-y1)/(y2-y1)
y2 = $ply[max(z-1,1)]
x2 = $plx[max(z-1,1)]
y1 = $ply[max(z-2,1)]
x1 = $plx[max(z-2,1)]
xl = barindex
yl = y1+(xl-x1)*(y2-y1)/(x2-x1)
//draw line only when rsi is over the line
if y2 > y1 then
drawsegment(x1,y1,x2,y2)coloured("red")
//look for the cross under
if myrsi crosses under yl-RSIdiff then
drawarrowdown(xl,yl+5)coloured("red")
drawsegment(x2,y2,xl,yl)style(dottedline,2)coloured("red")
endif
endif
/////pivots high
IF myrsi[repaint*BarLookBack+1] = highest[repaint*BarLookBack+BarLookBack+1](myrsi) THEN
$phy[n] = myrsi[repaint*BarLookBack+1]
$phx[n] = barindex-(repaint*BarLookBack+1)
n=n+1
ENDIF

/////pivots high line
////(x-x1)/(x2-x1) = (y-y1)/(y2-y1)
y22 = $phy[max(n-1,1)]
x22 = $phx[max(n-1,1)]
y11 = $phy[max(n-2,1)]
x11 = $phx[max(n-2,1)]
xh = barindex
yh = y11+(xh-x11)*(y22-y11)/(x22-x11)
//draw line only when rsi is under the line
if y22 < y11 then
drawsegment(x11,y11,x22,y22)coloured("green")
//look for the cross over
if myrsi crosses over yh+RSIdiff then
drawarrowup(xh,yh-5)coloured("green")
drawsegment(x22,y22,xh,yh)style(dottedline,2)coloured("green")
endif
endif
/////////////////////////////

return myrsi as "RSI" coloured("black",255 )style(line,2)