Hi skippy… here’s something I knocked up based on what I think your after.
The time setting are just to test multiple sessions on 15sec to see what happens.
All calculations are done within the ‘in session’ block. Count keeps track of valid bars. Inside the block:
if(1) and if(2) accumulate values for a 12 and 26 sma.
if(3) calculates the sma’s and these become the default ema values. and the first macd line can now be calculated as well.
if(4) calculates the future 12/26 ema,s after the default one’s, also The macd line values.
if(5) accumulate values for a 9sma of the macd line.
if(6) calculates the macd signal default value and 1st histogram value
if(7) calculates future macd signal values, and histogram values.
I think this is closer to what you want. It creates the standard MACD but only in a valid session. Out of session the MACD freezes till the next session, and then continues. Though it looks back at the bar before the next session starts, the values are the same as the last time they were calculated at the end of the previous session. This because the values are not re-calculated out of a session.
The count ensure that if the beginning setup is over 2 sessions, only session bars count. Watch out for midnight!
It appears to be doing what I expect , but not got time to do detailed testing. Check it against 24h and stock macd.
regards
defparam drawonlastbaronly = true
once count = 0
once ema26 = undefined
once ema12 = undefined
StartTime = 000000 // set times for 1st session test
EndTime = 030000
if opentime > endtime then
StartTime = 030700 // set times for 2nd session test
EndTime = 032000
endif
if opentime > endtime then
StartTime = 040000 // set times for 3rd session test
EndTime = 043000
endif
// period and constants for ema's
period1 = 26
k1 = 0.074074 // = 2/(26+1) est @ 6 d.p.
period2 = 12
k2 = 0.153846 // = 2/(12+1) est @ 6 d.p.
//k2 = 2/(period2+1)
period3 = 9
k3 = 0.200000 // = 2/(9+1) est @ 6 d.p.
// in session block
If (opentime >= StartTime and opentime <= EndTime) then // valid session bar
backgroundcolor(120,120,60,120)
count = count + 1 // keep count of valid bars
//(1)
if count <= 26 then // accumulate 26 values for a sma 1-26
sma26 = sma26 + close
endif
//(2)
if count >14 and count <= 26 then // accumulate 12 values for a sma 15-26
sma12 = sma12 + close
endif
//(3)
if count = 26 then // calculate default ema's (1st)
ema26 = sma26/period1 // calculate the sma as first (previous) 26 ema
ema12 = sma12/period2 // calculate the sma as first (previous) 12 ema
mdLine = ema12 - ema26 // calculate macd with valid ema's
endif
//(4)
if count > 26 then // calculate ema's (2nd,...)
ema26 = (close - ema26[1]) * k1 + ema26[1] // calculate ema's 2nd and onwards
ema12 = (close - ema12[1]) * k2 + ema12[1] // calculate ema's 2nd and onwards
mdLine = ema12 - ema26 // calculate macd with every new valid ema's
endif
//(5)
if count >=26 and count = 34 then //accumulate 9 values for signal line
sma9 = sma9 + mdline
endif
//(6)
if count = 34 then // default macd signal
mdSignal = sma9/period3
mdHistogram = mdLine - mdSignal
endif
//(7)
if count > 34 then
mdSignal = (mdLine - mdSignal[1]) * k3 + mdSignal[1] // calculate ema's 2nd and onwards
mdHistogram = mdLine - mdSignal
endif
drawHline(0)coloured(0,0,255,150) // zero line
drawtext("Valid bar Count #count#",0,10)anchor(bottom) coloured("pink") // valid bar count
endif
// histogram color change
r=255
g=113
b=113
if mdHistogram >= 0 then
r=68
g=198
b=68
endif
return mdline as"macdLine" coloured(0,0,255,155), mdsignal as"macdSig" coloured(255,0,0,155), mdHistogram as"macdHisto" coloured(r,g,b,210)style(histogram,1)
//return close as"close", ema26 as"ema26", ema12 as"ema12"
/*
//timeline
// valid bar count
1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,32,33,34,...
// 26 ema
1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,...
// 12 ema
#,#,#,#,#,#,#,#,#,##,##,##,##,##,#1,#2,#3,#4,#5,#6,#7,#8,#9,10,11,12,...
//macd Line
#,#,#,#,#,#,#,#,#,##,##,##,##,##,##,##,##,##,##,##,##,##,##,##,##,#1,#2,#3,#4,#5,#6,#7,#8,#9,...
// macd signal
#,#,#,#,#,#,#,#,#,##,##,##,##,##,##,##,##,##,##,##,##,##,##,##,##,#1,#2,#3,#4,#5,#6,#7,#8,#9,...
// macd histogram
#,#,#,#,#,#,#,#,#,##,##,##,##,##,##,##,##,##,##,##,##,##,##,##,##,##,##,##,##,##,##,##,##,#1,...
*/
