Thanks for the feedback, guys.  I reviewed and adjusted the code to include a 1.2 spread (Thanks, VinzentVega for the reminder), so don’t add more spread when testing!

I have reduced the losses, improved the risk management.

Again tested on V10.3 using 100,000 units

Test pic of tick by tick on and off

//Early Bird Breakout Strategy v1.0, updated with active risk code v1.2
//November 10th 2021
//www.harkoltd.com

//==========================================================
// Definition of code parameters
DEFPARAM CumulateOrders = False // Cumulating positions deactivated
// Cancel all pending orders and close all positions at the "FLATAFTER" time
DEFPARAM FLATAFTER = 120000
// Prevents the system from placing new orders to enter the market or increase position size after the specified time
noEntryAfterTime = 110000
timeEnterAfter = time < noEntryAfterTime
//==========================================================
// Prevents the system from placing new orders on specified days of the week
daysForbiddenEntry = OpenDayOfWeek = 6 OR OpenDayOfWeek = 0
//==========================================================
//Stake limited to 1.0% bank risk and topping at 1.7% return using active risk management code. Bank Risk Stop =1% and Target >2% (based on £10k account)
Stake=16
Spread=1.2
maxstop=6
Takeprofit=15
//==========================================================
//Limit to one trade
Trade = Barindex - TradeIndex(1) > IntradayBarIndex
//==========================================================
//Trading spread, entry of half spread
If Spread = 1.2 THEN
SpreadEntry = 0.6
ELSE
SpreadEntry = Spread
ENDIF
//==========================================================
//Active Risk management rules (To help the longs, shorts when wrong go straigh stop)
BreakevenAt =6
takeprofit =12
startBreakeven = takeprofit *(BreakevenAt/80)
PointsToKeep =4
IF NOT ONMARKET THEN
breakevenLevel=0
ENDIF
IF ONMARKET AND close-tradeprice(1)>=startBreakeven THEN
breakevenLevel = tradeprice(1)+PointsToKeep*pipsize
ENDIF
IF breakevenLevel>0.5 THEN
SELL AT breakevenLevel STOP
ENDIF
//==========================================================
//Leading breakout direction
Timeframe (5 MINUTE)
EMA1 = ExponentialAverage[22](close)
EMA2 = ExponentialAverage[3](close)
IF EMA1 > EMA2 AND EMA1 > EMA1[1] AND EMA2 > EMA2[1] THEN
LongNotShort = 1
ENDIF
IF EMA1 < EMA2 AND EMA1 < EMA1[1] AND EMA2 < EMA2[1] THEN
LongNotShort = 0
ENDIF
IF abs(EMA1 - EMA2) < 1 THEN
LongNotShort = 0.5
ENDIF
//==========================================================
//Entry timeframe
Timeframe (1 minute)
OpenUK = 080000
Start = time >=OpenUK
if openTime = 070000 then
myHighest = high
myLowest = low
endif
if openTime >= 070000 and openTime <=075955 then
myHighest = max (myHighest,high)
myLowest = min (myLowest,low)
endif
//==========================================================
If Start and Trade and timeEnterAfter and not daysForbiddenEntry then

// Conditions to enter long positions (0.5pt break)
IF LongNotShort = 1 THEN
BuyPrice = myHighest + SpreadEntry + 0.6
BUY stake PERPOINT AT BuyPrice stop
ENDIF
// Conditions to enter short positions
IF LongNotShort = 0 THEN
SellPrice = myLowest - SpreadEntry - 0.6
SELLSHORT stake PERPOINT AT SellPrice stop
ENDIF

SET STOP LOSS Maxstop
SET TARGET pPROFIT TakeProfit
endif

DAX-EB-open.png DAX-EB-tick-by-tick.png Early-Bird-DAX-V1.2.itf

It also looks good in 2m

Unbenannt-1.png