New Money Management, increases position size by 1 for each 1000 profit, margin is constant at ~13% of funds.

Insane result, not for the faint hearted…

DJ-5m-Mother.of_.Dragons-v3.5.jpg DJ-5m-Mother.of_.Dragons-v3.5.itf

New improved recipe, now with added vitamins.

Long and short in one code or separated. Robustness tests for v3.5L and 3.5S are roughly similar as v3.3 – the long is a bit worse, the short is a bit better. WF is fine but I’ve only got 100k to work with so it could still be the mother of all curve-fits.

Most grateful if someone could run it on 200k to see if it doesn’t completely crash and burn.

// Definition of code parameters
DEFPARAM CumulateOrders = false // Cumulating positions deactivated
DEFPARAM preloadbars = 5000
//Money Management
MM = 0
if MM = 0 then //MM = 0 for optimization
positionsize=1
ENDIF
if MM = 1 then
ONCE startpositionsize = .4
ONCE factor = 10 // factor of 15 means margin increases/decreases @ 6.6% of strategy profit; 10 = 10% 20 = 5% etc — optimize for best result, profit vs drawdown
ONCE margin = (close*.005) // margin value of 1 contract in instrument currency
ONCE maxpositionsize = 55 // DOW €1 IG first tier margin limit
ONCE minpositionsize = .2 // enter minimum position allowed
IF Not OnMarket THEN
positionsize = startpositionsize + Strategyprofit/(factor*margin)
ENDIF
IF Not OnMarket THEN
if startpositionsize + Strategyprofit/(factor*margin) < minpositionsize THEN
positionsize = minpositionsize// keeps positionsize from going below allowed minimum
ENDIF
IF startpositionsize + Strategyprofit/(factor*margin) > maxpositionsize then
positionsize = maxpositionsize// keeps positionsize from going above IG first tier margin limit
ENDIF
ENDIF
ENDIF

TIMEFRAME(2 hours,updateonclose)
Period= 490
inner = 2*weightedaverage[round( Period/2)](typicalprice)-weightedaverage[Period](typicalprice)
HULL = weightedaverage[round(sqrt(Period))](inner)
c1 = HULL > HULL[1]
c2 = HULL < HULL[1]

indicator1 = SuperTrend[5,22]
c3 = (close > indicator1)
c4 = (close < indicator1)

indicator4 = CALL "Moving Average Slope"[52,1](close)
c11 = (indicator4 > 0)
c12 = (indicator4 < 0)

//PRC_Stochastic RSI | indicator
lengthRSI = 12 //RSI period
lengthStoch = 9 //Stochastic period
smoothK = 11 //Smooth signal of stochastic RSI
smoothD = 4 //Smooth signal of smoothed stochastic RSI
 
myRSI = RSI[lengthRSI](close)
MinRSI = lowest[lengthStoch](myrsi)
MaxRSI = highest[lengthStoch](myrsi)
 
StochRSI = (myRSI-MinRSI) / (MaxRSI-MinRSI)
 
K = average[smoothK](stochrsi)*100
D = average[smoothD](K)
 
c13 = K>D
c14 = K<D

TIMEFRAME(15 minutes,updateonclose)
indicator2 = Average[5](typicalPrice)
indicator3 = Average[7](typicalPrice)
c7 = (indicator2 > indicator3)
c8 = (indicator2 < indicator3)

Period2= 19
inner2 = 2*weightedaverage[round( Period2/2)](typicalprice)-weightedaverage[Period2](typicalprice)
HULL2 = weightedaverage[round(sqrt(Period2))](inner2)
c9 = HULL2 > HULL2[1]
c10 = HULL2 < HULL2[1]

TIMEFRAME(5 minutes)

Period3= 15
inner3 = 2*weightedaverage[round( Period3/2)](typicalprice)-weightedaverage[Period3](typicalprice)
HULL3 = weightedaverage[round(sqrt(Period3))](inner3)
c5 = HULL3 > HULL3[1]and HULL3[1]<HULL3[2]
c6 = HULL3 < HULL3[1]and HULL3[1]>HULL3[2]

// Conditions to enter long positions
IF c1 AND C3 AND C5 and c7 and c9 and c11 and c13 THEN
BUY positionsize CONTRACT AT MARKET
ENDIF
 
// Conditions to enter short positions
IF c2 AND C4 AND C6 and c8 and c10 and c12 and c14 THEN
SELLSHORT positionsize CONTRACT AT MARKET
ENDIF

SET STOP %LOSS 2.3
SET TARGET %PROFIT 1.7
//================== maximise les gains ==========
if longonmarket and C6 and c8 and close>positionprice then
sell at market
endif

If shortonmarket and C5 and c7 and close<positionprice then
exitshort at market
endif
//==============limite les pertes

if longonmarket AND  c2 and c6 and close<positionprice then
sell at market
endif
If shortonmarket and c1 and c5 and close>positionprice then
exitshort at market
endif
//trailing stop function
trailingstart = 35 //trailing will start @trailinstart points profit
trailingstep = 3 //trailing step to move the "stoploss"
 
//reset the stoploss value
IF NOT ONMARKET THEN
newSL=0
ENDIF
 
//manage long positions
IF LONGONMARKET THEN
//first move (breakeven)
IF newSL=0 AND close-tradeprice(1)>=trailingstart*pipsize THEN
newSL = tradeprice(1)+trailingstep*pipsize
ENDIF
//next moves
IF newSL>0 AND close-newSL>=trailingstep*pipsize THEN
newSL = newSL+trailingstep*pipsize
ENDIF
ENDIF
 
//manage short positions
IF SHORTONMARKET THEN
//first move (breakeven)
IF newSL=0 AND tradeprice(1)-close>=trailingstart*pipsize THEN
newSL = tradeprice(1)-trailingstep*pipsize
ENDIF
//next moves
IF newSL>0 AND newSL-close>=trailingstep*pipsize THEN
newSL = newSL-trailingstep*pipsize
ENDIF
ENDIF
 
//stop order to exit the positions
IF newSL>0 THEN
SELL AT newSL STOP
EXITSHORT AT newSL STOP
ENDIF
//************************************************************************

DOW-5m-Mother.of_.Dragons-v3.3.jpg DOW-5m-Mother.of_.Dragons-v3.3-vrt.jpg DOW-5m-Mother.of_.Dragons-v3.5L.jpg DOW-5m-Mother.of_.Dragons-v3.5S.itf DOW-5m-Mother.of_.Dragons-v3.3.itf DOW-5m-Mother.of_.Dragons-v3.5L.itf DOW-5m-Mother.of_.Dragons-v3.5S.jpg