RSI Divergences Screener, Classic and Hidden (or Inverse)

Hi ProRealCoders,

following my previous post about RSI Divergences Indicator, here is the Screener.

As described in my last post, you can adjust the screener by change ist parameters values.

While “RSI Divergences Indicator” has explicit parameters, in this case parameters must be set inside the code.

Ciao!

//RSI Divergences Screener By Frank (Francesco)

//Variables:
//number of bars to calculare RSI value
RsiPeriod = 10

//Oversold Level
RsiOverSold = 30

//OverBought Level
RsiOverBought = 70

//Minimum distance from two consecutive RSI Highs or RSI Lows
MinBarRange = 3

MyRSI = rsi[RsiPeriod](Close)

RsiMax = MyRSI < MyRSI[1] and MyRSI[1] > MyRSI[2] and MyRSI[1] > RsiOverBought
RsiMin = MyRSI > MyRSI[1] and MyRSI[1] < MyRSI[2] and MyRSI[1] < RsiOverSold

if RsiMax then
 RSIMax1 = MyRSI[1]
 High1 = High[1]

 for I = MinBarRange to  80
  if RsiMax[I] then
   RSIMax2 = MyRSI[I + 1]
   High2 = High[I + 1]
   break
  endif
 next
endif

CondRibassista = RsiMax and ((High1 > High2 and RSIMax1 < RSIMax2) or (High1 < High2 and RSIMax1 > RSIMax2))

if RsiMin then
 RSIMin1 = MyRSI[1]
 Low1 = Low[1]
 for I = MinBarRange to  80
  if RSIMin[I] then
   RSIMin2 = MyRSI[I + 1]
   Low2 = Low[I + 1]
   break
  endif
 next
endif

CondRialzista = RsiMin and ((Low1 < Low2 and RSIMin1 > RSIMin2) or (Low1 > Low2 and RSIMin1 < RSIMin2))

if CondRibassista then
 Result = -1
endif

if CondRialzista then
 Result = 1
endif

SCREENER[CondRibassista or CondRialzista] (Result as "Go")