Here we go, something a lot of people are awaiting for : draw some arrows to show signals of trading conditions.

At least, a simple stochastic crossing can be drawn visually into our charts :

sto = Stochastic[10,3](close)
signal = average[5](sto)
rge = averagetruerange[10](close)

if sto[1]>80 and sto crosses under signal then
  DRAWARROWDOWN(barindex[1],high[1]+rge/2)coloured(255,10,10)
elsif sto[1]<20 and sto crosses over signal then
  DRAWARROWUP(barindex[1],low[1]-rge/2)coloured(10,255,10)
endif

RETURN

It’s easy to make gradient colour to show greater or less value. Here is an example to show the spread between 2 moving average with a dynamic scaling :

mm1 = average[10](close)
mm2 = exponentialaverage[30](close)

maxi = 200/50
color = ABS(mm1-mm2)*maxi

if mm1>mm2 then
  backgroundcolor(0,color,0)
else
  backgroundcolor(color,0,0)
endif

RETURN

In this example, 50 points of spread is the maximum value of the color, set to 200.

Another nice feature for coders, it is now the possibility of coding different things in the same time does not affect the interface development, as you can add as many coding windows as you like :

Drawing text on chart is now possible. You can even use ASCII character for drawing symbol-like on chart with the instruction http://www.prorealcode.com/documentation/drawtext/

DRAWTEXT("│", barindex, y2[1], Dialog, Bold, 12) COLOURED(10,255,10,255)

In order to use ASCII character you just have to use the ALT keyboard button + the ASCII number of the character you’d like to use, “179” in my case :

Hello Chupacabra, glad to see you here. You are right, with all these new graphical features, our imagination is the limit 🙂

Draw text on chart and horizontal line with extension with the new instructions : DRAWTEXT and DRAWLINE

Here is an intraday Fibonacci pivot points indicator made of these 2 new probuilder instructions :

defparam drawonlastbaronly = true

//yesterday's value
dh = DHigh(1)
dl = DLow(1)

//fibonacci pivot points
P = (dh + dl + DClose(1))/3
S1 = P - .382 * (dh-dl)
S2 = P - .618 * (dh-dl)
S3 = P -  1 * (dh-dl)
R1 = P +  .382 * (dh-dl)
RR2 = P +  .618 * (dh-dl)
R3 = P + 1 * (dh-dl)

//vertical offset to draw text correctly over horizontal lines
Voffset = 5*pipsize

//draw pivot points text
DRAWTEXT("Pivot",barindex-2,p+Voffset,SansSerif,Bold,16)coloured(153,153,0)
DRAWTEXT("R1",barindex-2,R1+Voffset,SansSerif,Bold,16)coloured(0,153,0)
DRAWTEXT("R2",barindex-2,RR2+Voffset,SansSerif,Bold,16)coloured(0,153,0)
DRAWTEXT("R3",barindex-2,R3+Voffset,SansSerif,Bold,16)coloured(0,153,0)
DRAWTEXT("S1",barindex-2,S1+Voffset,SansSerif,Bold,16)coloured(153,0,0)
DRAWTEXT("S2",barindex-2,S2+Voffset,SansSerif,Bold,16)coloured(153,0,0)
DRAWTEXT("S3",barindex-2,S3+Voffset,SansSerif,Bold,16)coloured(153,0,0)

//draw pivot points lines with extension 
DRAWLINE(barindex-1,p,barindex,p) coloured(153,153,0)
DRAWLINE(barindex-1,R1,barindex,R1) coloured(0,153,0)
DRAWLINE(barindex-1,RR2,barindex,RR2) coloured(0,153,0)
DRAWLINE(barindex-1,R3,barindex,R3) coloured(0,153,0)
DRAWLINE(barindex-1,S1,barindex,S1) coloured(153,0,0)
DRAWLINE(barindex-1,S2,barindex,S2) coloured(153,0,0)
DRAWLINE(barindex-1,S3,barindex,S3) coloured(153,0,0)

RETURN

Since these functions are only dealing with x and y coordinates from “barindex” and “price”, ProScreener would be able to find the same thing. Or I misunderstand your question?