Le code ci-dessous trace une ligne horizontale dés que les plats Kijun et SSB sont identiques. Si tu souhaites utiliser une instruction et comprendre comment elle fonctionne, tu peux utiliser la documentation: https://www.prorealcode.com/prorealtime-documentation/

kijun = (highest[26](high)+lowest[26](low))/2
SSB = (highest[52](high[26])+lowest[52](low[26]))/2
 
kijunp = summation[9](Kijun=Kijun[1])=9
ssbp = summation[9](SSB=SSB[1])=9
 
if kijunp then
kijunPrice = kijun
endif
if ssbp then
ssbPrice = SSB
endif

if kijunprice=ssbprice then 
drawhline(kijunprice)
endif

return //kijunPrice as "Plat KIjun", ssbPrice as "Plat SSB"

support-et-resistance-ichimoku.png

Ton code identifie et enregistre le dernier support ou résistance. Donc tu ne pourras utiliser que ce dernier dans ta stratégie, si tu souhaites utiliser ceux précédemment trouvés, alors soit :

• en v10.3, il faut faire des boucles dans le passé de l’historique pour identifier l’un des supports et résistances le plus proche
• en v11, utiliser un tableau pour enregistrer les anciens niveaux et faire une boucle dans ce tableau

Par ailleurs, je ne comprends pas ce que tu cherches à faire avec ta condition de proximité dans le cas d’une vente ? Peux-tu le détailler stp ?

Pour apprendre le fonctionnement d’une boucle, l’une des bases de la programmation, je te suggère de consulter la formation sur la programmation avancée : https://www.prorealcode.com/courses/prorealtime-programmation-avancee/

Donc tu voudrais un code compatible prorealtime 10.3 j’imagine ?

Très bien, j’ai créé une stratégie toute simple qui prendra ses ordres si “allowtrading” est égal à 1 (égal à 0 si trop proche d’un SR).

Dans la boucle on teste une proximité de “distance” avec un support/resistance détecté dans les “lookback” derniers chandeliers.

defparam cumulateorders=false

// --- settings 
distance = 15 //no orders if there is a SR within X points
lookback = 1000 //lookback in bars to check recent SR
tp = 30 //takeprofit in points 
sl = 10 //stoploss in points 

// ----------------------------------

// --- icihmoku support and resistance 
kijun = (highest[26](high)+lowest[26](low))/2
SSB = (highest[52](high[26])+lowest[52](low[26]))/2
 
kijunp = summation[9](Kijun=Kijun[1])=9
ssbp = summation[9](SSB=SSB[1])=9
 
if kijunp then
 kijunPrice = kijun
endif
if ssbp then
 ssbPrice = SSB
endif
if kijunprice=ssbprice then
 SRlevel = kijunprice
endif
 
// ----------------------------------

// --- dummy strategy 
buycondition = rsi[14] crosses over 50
sellcondition = rsi[14] crosses under 50

if buycondition or sellcondition then 
 //check if the current price is distant from at least "distance" from recent support or resistance
 allowtrading=1
 for i = 0 to lookback-1 do 
  dist = abs(close-srlevel[i])<distance*pointsize 
  if dist then 
   allowtrading=0 //no trading is allowed we are near a SR!
   break //break the loop, no need to continue, trading is not allowed anymore!
  endif
 next

 //trigger orders or not
 if allowtrading then 
  if buycondition then 
   buy 1 contract at market 
  endif 
  if sellcondition then 
   sellshort 1 contract at market 
  endif 
 endif
 set target pprofit tp
 set stop ploss sl
endif 
// ----------------------------------
graph allowtrading as "0=near a SR , don't trade!" 

ichimoku-straetgy-with-support-and-resistance.png

Merci pour le retour. N’hésite pas à partager tes futures recherches, histoire que le cercle vertueux puisse continuer, et aussi à demander de l’aide si nécessaire ! 😉

Il faut en effet à minima un preloadbars de “lookback”.

Plus ce dernier est important, plus les boucles seront consommatrices de ressources.