Per la validità del segnale basta che vari il numero alla riga 9, indicando dopo quante candele il segnale deve essere annullato, io ho messo un valore altissimo, per rendere il segnale sempre valido, se tu lo imposti a2 dopo due candele il segnale sarà considerato nullo.
Ho aggiunto solo una riga dopo il BUY ed una dopo il SELLSHORT per azzerare il segnale che era stato attivato dopo l’incrocio, viso che siamo entrati.
Ho anche tolto ONCE sul reset delle variabili (dove c’è IF IntraDayBarIndex = 0…..), perché questo poteva creare errori.
Per il resto mi sembra vada tutto bene, ti allego una schermata di EurUsd h1 per farti vedere la candela delle ore 14 del 7 Settembre dove si è verificato l’incrocio, per evidenziare il minimo ed il massimo ho tracciato due linee orizzontali colore viola e tratteggiate; ti ho evidenziato in arancio le due candele, di entrata LONG al superamento del massimo e di uscita SHORT (in Stop Loss) al superamento del minimo.
Se vuoi cambiare qualcosa nella strategia dimmi, ma, pur non avendola testata molto, mi sembra si comporti correttamente. Semmai se c’è qualche anomalia cerca di allegare un’immagine con la schermata del grafico dove si è verificato.
Chiaramente, avendo scelto di operare alla chiusura delle candele, anziché con gli ordini pendenti, può capitare che un prezzo superi il massimo/minimo e poi ritracci prima della chiusura. In tal caso il segnale di entrata/uscita verrebbe perso. Però questo non si può ovviare al momento, dovremo attendere la prossima versione che, a quanto riportato non ufficialmente, avrà un ProOrder multitimeframe, cioè sganciato dalla gabbia temporale del timeframe, quindi, per chi opera anche su timeframe lunghi i segnali potranno essere attivati anche a candela in corso.
Allego la nuova versione con l’aggiunta delle variazioni di cui sopra.
DEFPARAM CumulateOrders = false
DEFPARAM PreLoadBars = 2000
ONCE nLots = 1 //Numero di lotti da acquistare/vendere
ONCE BarID = 0 //Numero della barra dove avviene l'incrocio
ONCE Minimo = 0 //Minimo della candela dove è avvenuto l'incrocio
ONCE Massimo = 0 //Massimo della candela dove è avvenuto l'incrocio
ONCE MaxPips = 0 //Numero di Pips oltre Minimo/Massimo per entrare in rottura
ONCE MaxBars = 9999 //9999 =numero barre max. da attendere dopo l'incrocio
////************************************************************************
//
IF IntraDayBarIndex = 0 OR ((BarIndex - BarID) > MaxBars) THEN //Ad inizio nuovo giorno...
BarID = 0
Minimo = 0 //... o dopo MaxBars occorre
Massimo = 0 //... resettare le variabili
ENDIF
St = SuperTrend[10,24] //10, 24
IF (close CROSSES OVER St) OR (close CROSSES UNDER St) THEN
BarID = BarIndex //Salvare i valori necessari in caso d'incrocio
Minimo = low
Massimo = high
ENDIF
IF LongOnMarket THEN //Chiudere l'operazione LONG se il prezzo rompe il minimo
IF close <= Minimo THEN
SELL AT MARKET
ENDIF
ENDIF
IF ShortOnMarket THEN //Chiudere l'operazione SHORT se il prezzo rompe il massimo
IF close >= Massimo THEN
EXITSHORT AT MARKET
ENDIF
ENDIF
IF BarID AND (NOT OnMarket) THEN
IF close > (Massimo + (MaxPips * pipsize)) THEN //Entrare LONG a mercato
BUY nLots CONTRACT AT MARKET
BarID = 0
ENDIF
IF close < (Minimo - (MaxPips * pipsize)) THEN //Entrare SHORT a mercato
SELLSHORT nLots CONTRACT AT MARKET
BarID = 0
ENDIF
//BUY nLots CONTRACTS AT Massimo + (MaxPips * pipsize) LIMIT //Comprate n Pips oltre il Massimo
//SELLSHORT nLots CONTRACTS AT Minimo - (MaxPips * pipsize) LIMIT //Vendere n Pips sotto il Minimo
ENDIF
