PATTERN RIALZISTA E RIBASSISTA

Si, certo.

Molti di questi pattern (forse anche tutti, devi verificarlo) puoi trovarli già codificati qui https://www.prorealcode.com/prorealtime-indicators/candlesticks-patterns-indicator/.

Ad esempio la Shooting Star è alle righe 274-278. Una volta preso il codice e messo nella tua strategia puoi fargli fare quello che vuoi, anche mediante aggiunta di filtri per verificarne la corrispondenza con il trend in corso.

Se ce n’è qualcuna che non è codificata dammi la definizione corretta del pattern (come devono essere i corpi, le direzioni, le ombre e le relazioni tra le varie candele).

Ok, dammi un pò di tempo però.

Ti ho fatto questo per l’ENGULFING, sia rialzista (Bullish) che ribassista (Bearish).

Ho messo due filtri:

• che avvenga in corrispondenza di probabili punti d’inversione (i periodi li decidi tu, maggiorisono più è affidabile il segnale, ma hai meno segnali)
• che il corpo sia almeno il 70% del range totale, per evitare che vengano segnalati anche engulfing dojis.

DEFPARAM CumulateOrders = False
Bullish          = close > open
Bearish          = close < open
Body             = abs(close - open)
//UpperShadow    = high - max(open,close)
//LowerShadow    = min(open,close) - low
//TotalShadows   = range - Body
// Engulfing come dfinito a https://www.ig.com/it/gli-engulfing (solo il corpo è interessato, non le ombre)
ONCE BodySize    = 0.70                        //il corpo deve essere almeno il 70% del range della candela
BullishEngulfing = Bullish AND Bearish[1] AND Body > Body[1] AND close >= open[1] AND open <= close[1] AND Body >= (range * BodySize)
BearishEngulfing = Bullish[1] AND Bearish AND Body > Body[1] AND close <= open[1] AND open >= close[1] AND Body >= (range * BodySize)
// filtro per verificare che il pattern si verifichi in posizione di possibile inversione (swing)
ONCE Periodi     = 100
HH               = highest[Periodi](high)
LL               = lowest[Periodi](low)
InversioneLong   = 0
InversioneShort  = 0
IF BearishEngulfing THEN
   IF max(high,high[1]) = HH THEN
      InversioneShort = 1
   ENDIF
ELSIF BullishEngulfing THEN
   IF min(low,low[1]) = LL THEN
      InversioneLong  = 1
   ENDIF
ENDIF
// entrata LONG
IF BullishEngulfing AND InversioneLong AND Not OnMarket THEN
   BUY 1 CONTRACT AT MARKET
ENDIF
// entrata SHORT
IF BearishEngulfing AND InversioneShort AND Not OnMarket THEN
   SELLSHORT 1 CONTRACT AT MARKET
ENDIF
//
SET TARGET pPROFIT 100
SET STOP   pLOSS   20

Le righe 5, 6 e 7 le ho commentate perché non servono in questo TS, ma le ho messe per farti vedere la definizione completa delle varie parti di una candela.