trovare trend ribassista

Questo indicatore stampa una freccia, Verde o Rossa, quando rileva un trend rialzista o ribassista.

Per rilevarlo osserva le candele degli ultimi PERIODI e quelle dei PERIODI precedenti. Il trend è considerato rialzista quanto vi sono sia MASSIMI che MINIMI crescenti, mentre è ribassista nel caso opposto (entrambi decrescenti):

ONCE Periodi = 30
Distanza     = average[Periodi,0](range)
U1 = highest[Periodi](high)
U2 = highest[Periodi](high[Periodi])
L1 = lowest[Periodi](low)
L2 = lowest[Periodi](low[Periodi])
U  = (U1 > U2) AND (L1 > L2)
L  = (U1 < U2) AND (L1 < L2)
IF (U <> U[1]) OR (L <> L[1]) THEN
   IF U THEN
      DrawArrowUP(BarIndex,high + Distanza)  coloured(0,128,0,155)  //Verde
   ELSIF L THEN
      DrawArrowDOWN(BarIndex,low - Distanza) coloured(255,0,0,255)  //Rossa
   ENDIF
ENDIF
RETURN

e questo è il relativo screener:

ONCE Periodi = 30
U1 = highest[Periodi](high)
U2 = highest[Periodi](high[Periodi])
L1 = lowest[Periodi](low)
L2 = lowest[Periodi](low[Periodi])
U  = (U1 > U2) AND (L1 > L2)
L  = (U1 < U2) AND (L1 < L2)
x  = 0
IF (U <> U[1]) OR (L <> L[1]) THEN
   IF U THEN
      x = 1
   ELSIF L THEN
      x = 2
   ENDIF
ENDIF
SCREENER[x](x AS "1=↑,2=↓")

Qui puoi trovare la documentazione ufficiale online https://www.prorealcode.com/prorealtime-documentation/.

Puoi cercare anche sul MarketPlace parole come “Training” o “Coding Training” o simili https://market.prorealcode.com/?prcmaf=9f7907cc&from=home.