Non inserire documenti/file/immnagini all’interno del post, ma allegali usando il pulsante “Select File“.
Grazie 🙂

Appena ho un pò di tempo te lo farò.

Eccolo (provato sul DAX, Giornaliero):

DEFPARAM CumulateOrders = False
ONCE p  = 40                   //40  periodi per verificare il trend
Bullish = close > open
Bearish = close < open
HH          = highest[p](high)
LL          = lowest[p](low)
UP      = 0
DN      = 0
FOR i = 0 TO (p - 1)
IF high[i] = HH THEN
UP = 1
BREAK
ENDIF
IF low[i] = LL THEN
DN = 1
BREAK
ENDIF
NEXT
GapDN = open < low[1]  AND Bullish AND DN
GapUP = open > high[1] AND Bearish AND UP
IF GapDN THEN
GapUP   = 0
Entrata = low[1] + 1*PipSize
SL      = low - 1*PipSize
TP      = Entrata + (Entrata - SL) * 10
ELSIF GapUP THEN
GapDN   = 0
Entrata = high[1] - 1*PipSize
SL      = high + 1*PipSize
TP      = Entrata - (SL - Entrata) * 10
ENDIF
IF (GapUP + GapDN) = 0 THEN
GapUP = GapUP[1]
GapDN = GapDN[1]
ENDIF
IF OnMarket THEN
GapUP = 0
GapDN = 0
ENDIF
IF GapDN THEN
IF close > Entrata THEN
BUY 1 CONTRACT AT Entrata LIMIT
ELSIF close < Entrata THEN
BUY 1 CONTRACT AT Entrata STOP
ELSE
BUY 1 CONTRACT AT Market
ENDIF
SET STOP   PRICE SL
SET TARGET PRICE TP
ELSIF GapUP THEN
IF close < Entrata THEN
SELLSHORT 1 CONTRACT AT Entrata LIMIT
ELSIF close > Entrata THEN
SELLSHORT 1 CONTRACT AT Entrata STOP
ELSE
SELLSHORT 1 CONTRACT AT Market
ENDIF
SET STOP   PRICE SL
SET TARGET PRICE TP
ENDIF
//graphonprice SL      coloured("Red")  AS "SL"
//graphonprice TP      coloured("Blue")
//graphonprice Entrata