Buongiorno a tutti.
Mi aiutereste a creare questo indicatore?
La candela deve essere una Pinbar (indifferente sia una shooting o un hammer. Nei parametri qui sotto intendo la chiusura).
Mi servirebbero anche le direzioni ma credo sia complicato inserirle…le metto lo stesso fra parentesi.
Grazie in anticipo. Fausto
| EMA21 > SMA200 |
| Pin > EMA21 |
| 80 < Boll%B (10;2) < 95 (↘) |
| 70 < Stocastico (10;6;3) < 90 (↗) |
| 25 < ADX (10) < 40 (↗) |
Pin > EMA21 significa che la chiusura deve essere maggiore della media, oppure deve esserlo il minimo o il massimo?
Ciao Roberto. La chiusura intendo.
Grazie
Eccolo:
//Bullish = close > open
//Bearish = close < open
Body = abs(close- open)
UpperWick = high - max(open,close)
LowerWick = min(open,close) - low
cBody = Body <= (range * 0.1) //corpo non superiore al 10% del range
cUpperW = UpperWick >= (range * 0.7) //ombra (o spike) superiore >= 70% del range
cLowerW = LowerWick >= (range * 0.7) //ombra (o spike) inferiore >= 70% del range
PinBAR = cBody AND (cUpperW OR cLowerW)
Ema21 = average[21,1](close)
Sma200 = average[200,0](close)
BBval = 20 //20 BB periods
BBdev = 2.0 //2.0 BB deviation
BBavg = average[BBval,0](close) //BB mean (SMA middle line)
BollUP = BBavg + ((std[BBval](close)) * BBdev) //BB Upper Band
BollDN = BBavg - ((std[BBval](close)) * BBdev) //BB Lower Band
BB = (close - BollDN)/ (BollUP - BollDN) * 100 //BB%
StochK = Stochastic[10,6](close) //stocastico 10,6,3 - linea K
//StochD = Average[3](StochK) //stocastico 10,6,3 - linea D (segnale)
myADX = ADX[10] //ADX 10
//
// condizioni
//
c1 = Ema21 > Sma200
c2 = close > Ema21
c3 = BB < 95
c4 = StochK < 90
c5 = myADX < 40
//
Cond = PinBAR AND c1 AND c2 AND c3 AND c4 AND c5
RETURN Cond AS "Condizioni PinBAR"
Grazie mille Roberto.
Purtroppo l’indicatore esce ma spesso non nei parametri indicati.
Ho forse scordato di darti qualche parametro?
Sicuramente che quei parametri dovevano restituire una fattispecie solo LONG…
Per quanto riguarda le frecce di direzione che hai messo tra parentesi, non so cosa indichino.
In ogni caso ci sono le condizioni C1, C2, C3, C4 e C5, si sono verificate correttamente?
Eventualmente indicami strumento, timeframe, data ed oradi un segnale mancato o errato.
Buongiorno Roberto,
in allegato qualche esempio richiesto, dove i parametri non mi tornano.
Come ho scritto nel secondo messaggio (e colpevolmente non nel primo) questa è una configurazione solo LONG.
Nelle parentesi ho indicato (se può servire) la direzione dell’indicatore.
Grazie, ciao
Ho verificato solo NOK/JPY, i parametri andavano tutti bene. La differenza era solo nella direzione, che non avevo indicato perché non avevo ben capito cosa intendessi.
Ho anche aggiunto una verifica sulle candele vuote (cioè che hanno RANGE = 0) in modo da evitarle:
//Bullish = close > open
//Bearish = close < open
Body = abs(close- open)
UpperWick = high - max(open,close)
LowerWick = min(open,close) - low
cBody = Body <= (range * 0.1) //corpo non superiore al 10% del range
cUpperW = UpperWick >= (range * 0.7) //ombra (o spike) superiore >= 70% del range
cLowerW = LowerWick >= (range * 0.7) //ombra (o spike) inferiore >= 70% del range
PinBAR = cBody AND (cUpperW OR cLowerW) AND (Range > 0)
Ema21 = average[21,1](close)
Sma200 = average[200,0](close)
BBval = 20 //20 BB periods
BBdev = 2.0 //2.0 BB deviation
BBavg = average[BBval,0](close) //BB mean (SMA middle line)
BollUP = BBavg + ((std[BBval](close)) * BBdev) //BB Upper Band
BollDN = BBavg - ((std[BBval](close)) * BBdev) //BB Lower Band
BB = (close - BollDN)/ (BollUP - BollDN) * 100 //BB%
StochK = Stochastic[10,6](close) //stocastico 10,6,3 - linea K
//StochD = Average[3](StochK) //stocastico 10,6,3 - linea D (segnale)
myADX = ADX[10] //ADX 10
//
// condizioni
//
c1 = Ema21 > Sma200
c2 = close > Ema21
c3 = (BB < 95) AND (BB < BB[1])
c4 = StochK < 90 AND (StochK > StochK[1])
c5 = myADX < 40 AND (myADX > myADX[1])
//
Cond = PinBAR AND c1 AND c2 AND c3 AND c4 AND c5
RETURN Cond AS "Condizioni PinBAR"
Il codice non fa verifiche su operazioni Long o Short, semplicemente verifica le condizioni che hai chiesto e ti restituisce un segnale, che tu interpreterai come preferisci.
