Max min con estensioni

Viewing 15 posts - 1 through 15 (of 28 total)
1 2
  • Author
    Posts
  • 05/02/2019 at 5:00 PM #97557 quote
    Marcotrading
    Participant
    Junior

    Salve Vorrei un aiuto per creare un indicatore che ogni giorno mi tracci sul grafico delle linee orizzontali che mi traccino max e minimo del giorno precedenti calcolato su time frame m15 delle candele che vanno dalle ore 08:00 alle ore 22:00. oltre ai max e minimi, l’indicatore deve tracciarmi anche estensione al 10% sopra il max e 10% sopra il minimo, sempre con linee orizzontali che riguradano il max e minimo giorno precedente calcolato sempre dalle ore 08:00 alle ore 14:00.

    Grazie a chi sapra aiutarmi

    05/02/2019 at 5:58 PM #97565 quote
    robertogozzi
    Moderator
    Master

    Ecco il codice, io messo un + o – 1 per mille (0.001), altrimenti con il 10%  o anche l’1% (0.1 o 0.01) va fuori scala, ma puoi cambiarlo come preferisci:

    DEFPARAM CalculateOnLastBars = 1000
DEFPARAM DrawOnLastBarOnly   = true
IF BarIndex = 0 THEN
   Inizio = 0
   Fine14 = 0
   Fine22 = 0
ENDIF
IF OpenTime = 080000 THEN
   Minimo  = low
   Massimo = high
   Inizio  = BarIndex
   Fine14  = BarIndex
   Fine22  = BarIndex
ENDIF
IF OpenTime <= 220000 THEN
   Massimo = max(Massimo, high)
   Minimo  = min(Minimo, low)
   Fine22  = BarIndex
ENDIF
IF OpenTime >= 080000 AND OpenTime <= 140000 THEN
   Sopra10 = Massimo * 1.001
   Sotto10 = Minimo  * 0.999
   Fine14  = BarIndex
ENDIF
DRAWSEGMENT(Inizio,Massimo,Fine22,Massimo)coloured(0,201,87,255)   //Verde
DRAWSEGMENT(Inizio,Minimo,Fine22,Minimo)  coloured(0,201,87,255)   //verde
DRAWSEGMENT(Inizio,Sopra10,Fine14,Sopra10)coloured(218,165,32,255) //Giallo-oro
DRAWSEGMENT(Inizio,Sotto10,Fine14,Sotto10)coloured(218,165,32,255) //Giallo-oro
RETURN

    Nella foto allegata puoi vedere le linee 22 (ore 8 – 22) e le linee giallo-oro (ore 8 – 14, con l’estensione).

    x-1.jpg x-1.jpg
    05/02/2019 at 6:35 PM #97567 quote
    Marcotrading
    Participant
    Junior

    Ciao Roberto buonasera. L’indicatore funziona perfettamente, ma mi traccia il max e minimo della giornata in corso e non di quella precedente. Io avrei necessita che mi tracciasse il max min con estension della giornata precedente calcolata dalle ore 8 alle ore 22

    Grazie mille

    05/02/2019 at 6:39 PM #97568 quote
    Marcotrading
    Participant
    Junior

    Inoltre noto che le estensioni non sono corrette Roberto.

    05/02/2019 at 6:43 PM #97569 quote
    robertogozzi
    Moderator
    Master

    Hai ragione, ho indicato il giorno corrente.

    Le estensioni di quanto devono essere? Se metto il 10% sul DAX, ad esempio, sono ben 1200 Pips!

    05/02/2019 at 6:50 PM #97570 quote
    Marcotrading
    Participant
    Junior

    Le estensioni dovrebbero essere un 10% superiore tra il range max e minimo trovato dall’indicatore. Come un fibonacci, ma con la differenza che le estensioni vanno calcolate sul range max/minimo del giorno prima dalle ore 8 alle 22

    05/02/2019 at 7:19 PM #97576 quote
    robertogozzi
    Moderator
    Master

    Le estensioni avevi detto sui min/max dalle 8 alle 14, ad ogni modo puoi cambiare tu le date (basta che tu sostituisca 140000 con 220000):

    DEFPARAM CalculateOnLastBars = 1000
DEFPARAM DrawOnLastBarOnly   = true
IF OpenTime >= 080000 AND OpenTime <= 220000 THEN
   IF OpenTime = 080000 THEN
      MinimoPrec  = Minimo
      MassimoPrec = Massimo
      Sopra10Prec = Sopra10
      Sotto10Prec = Sotto10
      Minimo  = low
      Massimo = high
      Inizio  = BarIndex
   ENDIF
   Massimo = max(Massimo, high)
   Minimo  = min(Minimo, low)
ENDIF
IF OpenTime >= 080000 AND OpenTime <= 140000 THEN
   Estensione = (Massimo - Minimo) * 0.1              //10%
   Sopra10    = Massimo  + Estensione
   Sotto10    = Minimo   - Estensione
ENDIF
DRAWSEGMENT(Inizio,MassimoPrec,BarIndex,MassimoPrec) coloured(0,201,87,255)
DRAWSEGMENT(Inizio,MinimoPrec ,BarIndex,MinimoPrec)  coloured(0,201,87,255)
DRAWSEGMENT(Inizio,Sopra10Prec,BarIndex,Sopra10Prec) coloured(218,165,32,255)
DRAWSEGMENT(Inizio,Sotto10Prec,BarIndex,Sotto10Prec) coloured(218,165,32,255)
RETURN
    05/04/2019 at 11:00 AM #97655 quote
    Marcotrading
    Participant
    Junior

    Salve Roberto, funziona benissimo.

    Ti chiedo un ultima cosa. per inserire questo indicatore in una strategia del tipo:

    Calcolati i max e minimi di ieri dalle ore 08 alle ore 22, con le relative estensioni, vorrei una strategia che ogni giorno alle ore 08:00 inserisca due ordini pendenti.

    un ordine sell stop in corrispondenza del valore “sopra10” con stop 20 punti e target 20 punti.

    un ordine buy limit in corrispondenza del valore “sotto10” con stop 20 punti e target 20 punti.

    Ovviamnate se nell’arco della giornata non si verificano le condizioni di acquisto o vendita, il ts dopo le ore 22 toglie gli ordini pendenti.

    Grazie mille

    05/04/2019 at 11:28 AM #97665 quote
    robertogozzi
    Moderator
    Master

    Per parlare di una strategia ti prego di aprire un altro argomento sul supporto ProOrder, magari inserendo anche un link a questo perché altri possano capire di cosa si sta parlando.

    Grazie.

    05/04/2019 at 11:44 AM #97666 quote
    Marcotrading
    Participant
    Junior

    Perfetto, lo faro subito Roberto, ti ringrazio.

    Un ultima cosa, vorrei inserire sulle linee tracciate il valore del prezzo, è possibile?

    05/04/2019 at 12:16 PM #97672 quote
    robertogozzi
    Moderator
    Master

    Ecco con il prezzo alla destra delle linee:

    DEFPARAM CalculateOnLastBars = 1000
DEFPARAM DrawOnLastBarOnly   = true
IF OpenTime >= 080000 AND OpenTime <= 220000 THEN
   IF OpenTime = 080000 THEN
      MinimoPrec  = Minimo
      MassimoPrec = Massimo
      Sopra10Prec = Sopra10
      Sotto10Prec = Sotto10
      Minimo  = low
      Massimo = high
      Inizio  = BarIndex
   ENDIF
   Massimo = max(Massimo, high)
   Minimo  = min(Minimo, low)
ENDIF
IF OpenTime >= 080000 AND OpenTime <= 140000 THEN
   Estensione = (Massimo - Minimo) * 0.1              //10%
   Sopra10    = Massimo  + Estensione
   Sotto10    = Minimo   - Estensione
ENDIF
DRAWSEGMENT(Inizio,MassimoPrec,BarIndex,MassimoPrec)                                 coloured(0,201,87,255)
DRAWTEXT("                 #MassimoPrec#", barindex,MassimoPrec, SansSerif,Bold,10)  coloured(0,201,87,255)
DRAWSEGMENT(Inizio,MinimoPrec ,BarIndex,MinimoPrec)                                  coloured(0,201,87,255)
DRAWTEXT("                 #MinimoPrec#" , barindex, MinimoPrec, SansSerif,Bold,10)  coloured(0,201,87,255)
DRAWSEGMENT(Inizio,Sopra10Prec,BarIndex,Sopra10Prec) coloured(218,165,32,255)
DRAWTEXT("                  #Sopra10Prec#", barindex, Sopra10Prec, SansSerif,Bold,10)coloured(218,165,32,255)
DRAWSEGMENT(Inizio,Sotto10Prec,BarIndex,Sotto10Prec) coloured(218,165,32,255)
DRAWTEXT("                  #Sotto10Prec#", barindex, Sotto10Prec, SansSerif,Bold,10)coloured(218,165,32,255)
RETURN
    05/04/2019 at 4:09 PM #97682 quote
    Marcotrading
    Participant
    Junior

    Roberto, un’altra info. Come posso modificare lo spessore delle linee tracciate? oppure come posso rendere una linea tratteggiata?

    05/04/2019 at 7:14 PM #97695 quote
    robertogozzi
    Moderator
    Master
    Non si può, solo i dati restituiti con RETURN possono essere personalizzati. Togli, o commenta, tutte le righe dove c’ è DRAW e sostituisci l’ultima riga con: 
    RETURN MassimoPrec,MinimoPrec,Sopra10Prec,Sotto10Prec

    Poi personalizzale con le proprietà dell’indicatore.

    05/14/2019 at 12:07 PM #98460 quote
    Marcotrading
    Participant
    Junior
    Salve, funziona tutto alla grande, grazie mille Roberto 🙂
    05/14/2019 at 12:18 PM #98462 quote
    Marcotrading
    Participant
    Junior
    Roberto, mentre se mi voglio formare lo stesso indicatore, ma che mi tracci massimi e minimi sempre calcolati dalle ore 08 alle ore 22 di due giorni fa, quindi non del giorno precedente, cosa devo modificare all’interno? Grazie ancora per la tua disponibilità
  • Author
    Posts
Viewing 15 posts - 1 through 15 (of 28 total)
1 2
  • You must be logged in to reply to this topic.

Max min con estensioni


ProBuilder: Indicatori & Strumenti Personalizzati

New Reply
Author
author-avatar
Marcotrading @marcotrading Participant
Summary

This topic contains 27 replies,
has 2 voices, and was last updated by robertogozzi
3 years, 6 months ago.

Topic Details
Forum: ProBuilder: Indicatori & Strumenti Personalizzati
Language: Italian
Started: 05/02/2019
Status: Active
Attachments: 7 files
Logo Logo
Loading...
Do you like cookies? 🍪 We use cookies to ensure you get the best experience on our website. (Learn more)
©2026 ProRealCode - Trading & Coding with ProRealTime™