E’ questo (https://www.prorealcode.com/prorealtime-indicators/ma-trend-colored/), vero?

E’ molto semplice, basta aggiungere il setup per le candele HA e variare i riferimenti a Close,High,open,Low.

Ho fatto queste modifiche:

• ho aggiunto una variabile flag (UsaHA) che ti permette di applicare l’indicatore su candela normali o HA
• ho aggiunto le variabili alle proprietà, in modo che tu non devva variare il codice ogni volta che vuoi cambiare un valore
• ho aggiunti un controllo sull’intervallo (range) di valori accettati, in modo da non generere errori che fanno uscire l’indicatore dal grafico (tipo -1 nei periodi)

Ti conviene importare il file (a cui ho dato un nome diverso dall’originale), così hai già le variabili dichiarate.

//PRC_TrendColored indicator - 21.11.2018 - Nicolas @ www.prorealcode.com
//Sharing ProRealTime knowledge
//
//
//UseHA   = 1                                   //1=Heikin-Ashi, 0=Candele Giapponesi
//Period1 = 10                                  //10  periodi (media veloce)
//MA1type = 2                                   //2=wma
//Period2 = 50                                  //50  periodi (media lenta)
//MA2type = 2                                   //2=wma
//
UseHA     = max(0,min(1,UseHA))                 //range 0-1
Period1   = max(1,min(999,Period1))             //range 1-999
MA1type   = max(0,min(6,MA1type))               //range 0-6
Period2   = max(Period1 + 1,min(999,Period2))   //range (Period1 + 1)-999
MA2type   = max(0,min(6,MA2type))               //range 0-6
//
// HA setup
once xOpen = open
xClose     = (open + close + high + low) / 4
if barindex > 0 then
   xOpen   = (xOpen + xClose[1]) / 2
endif
xLow       = min(low,min(xClose,xOpen))
xHigh      = max(high,max(xClose,xOpen))
// end HA setup
IF UseHA = 1 THEN
   MyClose = xClose
   MyOpen  = xOpen
   MyHigh  = xHigh
   MyLow   = xLow
ELSE
   MyClose = Close
   MyOpen  = Open
   MyHigh  = High
   MyLow   = Low
ENDIF
//
avg1 = average[Period1,MA1type](MyClose)
avg2 = average[Period2,MA2type](MyClose)
if avg1>avg2 then
   r=0
   g=255
   b=0
   if avg1<avg1[1] then
      r=0
      g=128
      b=0
   endif
elsif avg1<avg2 then
   r=255
   g=0
   b=0
   if avg1>avg1[1] then
      r=255
      g=99
      b=71
   endif
endif
//
drawcandle(MyOpen,MyHigh,MyLow,MyClose) coloured(r,g,b)
return

Ma-Trend-Colored-Heikin-Ashi.itf x-4.jpg