Hi quo, although I’m not by any means an expert (neither in fact an user except for some screeners) on this PRT platform , as a programming exercice and to leave Nicolas rest a bit,  I’ve just coded a solution based approx. on your description of the strategy.

Maybe it’s not yet 100% depured and it’s taken me some time too. It’s not as straightforward as your idea so don’t despair if you don’t get it all at first glance.

Feel free to prove it , tamper with it and comment if you want or need (I’m Spanish… just in case…). For your information, I’ve used a correction in the high not the low of the following bar to define the precedent high as a new historic maximum.

This is my go, my excuses to the native English speakers for the odd wrong preposition!

// TS name: Historic_Maximum_BO
// Description: Buy at historic maximum breakouts.
// Sell at relative minimums (or lows) between consecutive historic
// maximums.
// A new historic maximum is defined by a correction in the
// high value (high < high[1]) from a current maximum
// Instruments: Stocks/ETFs
// Time frame: Daily / Weekly
// Features: Only long system. No money management in this version
// Version: 01
//
// Comments: System should give a few operations with a low ratio wins/losses.
// Profitability greatly depending on entering and riding at least
// one big bullish movement.
// minTradeBars should be > 0 (20 for instance for daily TF) to avoid the
// effects of very close consecutive minimums with little inter-maximums
// corrections (exitPrice too close to current prices).
// Ditto for SL and the possible big corrections from very far-off
// historic maximums (exitPrice too far from current prices).
// *********************************************************************************

DEFPARAM PRELOADBARS = 10000

// customizable or optional parameters
once startDate = 20110101 // Example date in YYYYMMDD format for backtesting.
// Today's date for production
once size = 2000 // Example fixed capital to trade
once enterFilter = 0 // Optional. % above maximum to enter position
once exitFilter = 0 // Optional. % under minimum to exit position
once TP = 0 // Optional. Take profit in %
once SL = 0 // Recommended. Stop loss in %
once minTradedBars = 0 // Recommended. Minimal trade span before selling

// variables declaration
once historicMax = 0 // historic maximum
once currentMax = 0 // current maximum candidate to historic maximum
once barHistoricMax = 0 // historic maximum barIndex
once barCurrentMax = 0 // current maximum barIndex
once exitPrice = 0 // exit price
once buyPrice = 0 // buy price
once barOffset = 0 // aux counter used to set exitPrice
once countBars = 0 // idem for measuring trade duration
once waitForBuyPrice = 0 // semaphore to lock updating of historic maximum

// find out historic maximum until startDate
if date < startDate then
if high > historicMax then
historicMax = high
barHistoricMax = barIndex
endif
endif

IF DATE >= STARTDATE THEN
if not onmarket then
// open position at historic maximum plus filter
buyPrice = historicMax * (1 + enterFilter/100)
buy size cash at buyPrice stop // set buy stop order

// if price doesn't reach buyPrice because of the filter
// not to update historic maximum until position is entered
if high > historicMax and high < buyPrice then
waitForBuyPrice = 1 // updating not permitted
endif

// set new historic maximum after exit
if not waitForBuyPrice then
if high > historicMax then
historicMax = high
barHistoricMax = barIndex
endif
endif

// if position is exited precisely in the correction bar
// that updates new historic maximum
if currentMax > historicMax then
historicMax = currentMax
barHistoricMax = barCurrentMax
endif

countBars = 0 // reset countBars
endif

// if entered position, set new historic maximum and first exitPrice
if onmarket and barIndex = TRADEINDEX(1) then
exitPrice = lowest[barIndex - barHistoricMax + 1](low) * (1 - exitFilter/100)
historicMax = high
barHistoricMax = TRADEINDEX(1)
waitForBuyPrice = 0 // updating permitted
endif

// set sell stop order
if onmarket then
if countBars >= minTradedBars then
sell at exitPrice stop
endif
endif

// manage updating of new historic maximum and new exitPrice
if onmarket then
countBars = countBars + 1
// keep track of candidates to new historic maximum
if high > currentMax then
currentMax = high
barCurrentMax = barIndex
elsif high = currentMax then
// keep track of bars with same high = current maximum
barOffset = barOffset + 1
elsif high < currentMax and currentMax <> historicMax then
// if correction from current maximum then update
exitPrice = lowest[barIndex - barHistoricMax + 1 + barOffset](low) * (1 - exitFilter/100)
historicMax = currentMax // update historic maximum
barHistoricMax = barCurrentMax // update historic maximum barIndex
endif
endif
ENDIF

SET TARGET %PROFIT TP
SET STOP %LOSS SL

Hi Quo.

Did you consider using the MFE trailingstop code?

just add it to the end of yours.

Cheers Kasper

//======================TralingSTOP MFE=======================
//trailing stop
trailingstop = 20//x1

//resetting variables when no trades are on market
if not onmarket then
MAXPRICE = 0
MINPRICE = close
priceexit = 0
endif

//case SHORT order
if shortonmarket then
MINPRICE = MIN(MINPRICE,close) //saving the MFE of the current trade
if tradeprice(1)-MINPRICE>=trailingstop*pointsize then //if the MFE is higher than the trailingstop then
priceexit = MINPRICE+trailingstop*pointsize //set the exit price at the MFE + trailing stop price level
endif
endif

//case LONG order
if longonmarket then
MAXPRICE = MAX(MAXPRICE,close) //saving the MFE of the current trade
if MAXPRICE-tradeprice(1)>=trailingstop*pointsize then //if the MFE is higher than the trailingstop then
priceexit = MAXPRICE-trailingstop*pointsize //set the exit price at the MFE - trailing stop price level
endif
endif

//exit on trailing stop price levels
if onmarket and priceexit>0 then
EXITSHORT AT priceexit STOP
SELL AT priceexit STOP
endif

//================================================================

Hi, back in town.

Bloody hell, you keep trying the system on monthly bars and I keep debugging it only in daily timeframes, where it seemed to be working well. But you’re so right, it doesn’t.

My time is limited now as I’have just begun painstakingly (a matter of try and error) to make changes to my own manual strategies after two losing months in a row but I’ll try and find where the problem is as soon as possible.

Cheers and saludos