Eccolo:

DEFPARAM CumulateOrders = FALSE
once xOpen = open
xClose     = (open + close + high + low) / 4
if barindex > 0 then
xOpen  = (xOpen + xClose[1]) / 2
endif
xLow       = min(low,min(xClose,xOpen))
xHigh      = max(high,max(xClose,xOpen))
xUpperWick = xHigh - max(xOpen,xClose)
xLowerWick = min(xClose,xOpen) - xLow
UpperShaved= (xUpperWick = 0)
LowerShaved= (xLowerWick = 0)
MySAR      = SAR[0.02,0.02,0.2]
CrossOver  = xClose CROSSES OVER  MySAR
CrossUnder = xClose CROSSES UNDER MySAR
// condizioni LONG
Lcond      = LowerShaved AND CrossOver  AND Not OnMarket
// condizioni SHORT
Scond      = UpperShaved AND CrossUnder AND Not OnMarket
//
IF LongOnMarket THEN
   MyDiff = abs(min(xOpen,xClose) - MySAR) / 2    //trailing stop LONG
   MyStop = max(MySAR + MyDiff,MyStop)
   SELL AT MyStop STOP
ELSIF ShortOnMarket THEN
   MyDiff = abs(max(xOpen,xClose) - MySAR) / 2    //trailing stop SHORT
   MyStop = min(MySAR - MyDiff,MyStop)
   EXITSHORT AT MyStop STOP
ENDIF
// entrata LONG
IF Lcond THEN
   BUY 1 Contract at Market
   MyDiff = abs(min(xOpen,xClose) - MySAR) / 2
   SET TARGET PROFIT MyDiff * 7
   MyStop = MySAR + MyDiff
   SELL AT MyStop STOP
ENDIF
// entrata SHORT
IF Scond THEN
   SELLSHORT 1 Contract at Market
   MyDiff = abs(max(xOpen,xClose) - MySAR) / 2
   SET TARGET PROFIT MyDiff * 7
   MyStop = MySAR - MyDiff
   EXITSHORT AT MyStop STOP
ENDIF

Te lo allegherà sicuramente Roberto.

In ogni caso puoi provare a  fare da solo in questo modo: nell’immagine con la formula sopra riportata, in alto a destra vedi due piccole icone. Se premi in quella più a sinistra ti si seleziona il testo della strategia. Copi il testo, vai in: indicatori –> backtesting –> nuovo –> la incolli e gli dai il nome che vuoi. Poi basta che selezioni la strategia rinominata e vai in “esporta” per avere il file .itf