Ok, I will code them with the definitions I found browsing the web (commented out variables are unused, but I included them for any future additions):

//Bullish      = close > open
Bearish        = close < open
Body           = abs(close - open)
UpperShadow    = high - max(open,close)
LowerShadow    = min(open,close) - low
//TotalShadow  = range - Body
Total          = 0
//--------------------------------------------------------------------------------------------------------------------
// Hammer
//
Ha1            = LowerShadow >= (Body * 3)     //Lower Shadow 3 times longer than the body
Ha2            = close >= (high-(range * 0.25))//must close in the upper 25% of its range
Ha3            = low = lowest[20](low)         //its Low must be the lowest one of the last 20 candles (1=disabled)
Hammer         = Ha1 AND Ha2 AND Ha3
IF Hammer THEN
   Total = Total + 1
ENDIF
//--------------------------------------------------------------------------------------------------------------------
// Shooting Star
//
Ss1            = UpperShadow >= (Body * 3)     //Upper Shadow 3 times longer than the body
Ss2            = LowerShadow <= Body           //Lower Shadow must be max as large as the body
Ss3            = close <= (low+(range * 0.25)) //must close in the lower 25% of its range
Ss4            = high = highest[20](high)      //its High must be the highest one of the last 20 candles (1=disabled)
ShootingStar   = Ss1 AND Ss2 AND Ss3 AND Ss4
IF ShootingStar THEN
   Total = Total + 2
ENDIF
//--------------------------------------------------------------------------------------------------------------------
// Inverted Hammer
//
Ih1            = Bearish[1]                    //the first candle (the one to the left of the 2-candle pattern) is Bearish
Ih2            = LowerShadow <= Body           //Lower Shadow must be max as large as the body
Ih3            = UpperShadow >= (Body * 2.5)   //Upper Shadow 2.5 times longer than the body
Ih4            = open <= close[1]              //the open must be <= to the previous candle's close
InVertedHammer = Ih1 AND Ih2 AND Ih3 AND Ih4
IF InVertedHammer THEN
   Total = Total + 4
ENDIF
//--------------------------------------------------------------------------------------------------------------------
// Hanging Man
//
Hm1            = UpperShadow <= Body           //Upper Shadow must be max as large as the body
Hm2            = LowerShadow >= (Body * 2)     //Lower Shadow 2 times longer than the body
Hm3            = close >= (high - (range / 3)) //must close in the upper third of its range
HangingMan     = Hm1 AND Hm2 AND Hm3
IF HangingMan THEN
   Total = Total + 8
ENDIF
//--------------------------------------------------------------------------------------------------------------------
//
SCREENER[Total](Total AS "Total")

The result can be 1, 2, 4, 8 or any combinations of them (9 means that the current candlestick can be a Hanging Man or a Hammer, its position on the chart may help you tell one from the other).

There must be something wrong, it does´t work. Thanks anyway