Hey fellows,

It’s been quite a while since the last update here. I have been working on an alternate entry and exit version of the strategy which is better suited for the low volatility and slow markets we have been seeing for the most part of the last few months. This version is aiming at getting 25-100 pips per trade so we still need to catch a decent move but often we will get out quickly with a very small loss, since the entry signal is Heiken Ashi changing color we need to run it on a higher TF than the other verions of the system, I have focused on M15 mainly but it can be run on M5 or H1 as well. The entry filter is directional movement (25) and ADX (25), these values are discretionary depending on the TF.

However I only run it when I can keep an eye on  the markets the market can travel many pips the wrong way in 15 mins, hence I also recommend turning off cumulative orders or set a low amount of maximum entries to 3 or 5.

In order for it to work you will need the below HA Change indicator (a modified version of the one Kasper provided);

//Heikin-Ashi
xClose = (Open+High+Low+Close)/4
if(barindex>2) then
xOpen = (xOpen[1] + xClose[1])/2
endif
changeToGreencandle = xClose>xOpen AND xClose[1]<xOpen[1]
ChangeToRedcandle = xClose<xOpen AND xClose[1]>xOpen[1]
Greencandle=xclose>xopen
redcandle=xclose<xopen
If changeToGreencandle then
Indicator1=1
elsif greencandle then
indicator1=0.5
elsif Changetoredcandle then
indicator1=-1
elsif redcandle then
indicator1=-0.5
Else
Indicator1=0
Endif

Return indicator1

Long;

/// Definition of code parameters
defparam preloadbars =10000
DEFPARAM CumulateOrders = true // Cumulating positions deactivated
AAA= ADX [25]
DIM= DI[25]
HAC= call "HA Change"

once RRreached = 0
accountbalance = 10000 //account balance in money at strategy start
riskpercent = 1 //whole account risk in percent%
amount = 1 //lot amount to open each trade
rr = 1 //risk reward ratio (set to 0 disable this function)
sd = 0.25 //standard deviation of MA floating profit


//dynamic step grid
minSTEP = 5 //minimal step of the grid
maxSTEP = 30 //maximal step of the grid
ATRcurrentPeriod = 150 //recent volatility 'instant' period
ATRhistoPeriod = 3000 //historical volatility period

ATR = averagetruerange[ATRcurrentPeriod]
histoATR= highest[ATRhistoPeriod](ATR)

resultMAX = MAX(minSTEP*pipsize,histoATR - ATR)
resultMIN = MIN(resultMAX,maxSTEP*pipsize)

gridstep = (resultMIN)

// Conditions to enter long positions
c1 = (AAA > 10)
c2 = (DIM > 0)
c3 = (HAC = 1)


//first trade whatever condition, for one cycle only add "AND STRATEGYPROFIT=0" on line 39.
if NOT ONMARKET AND (c1)=1 AND (c2)=1 AND (c3)=1 AND close>close[1] then
BUY amount LOT AT MARKET
endif

// case BUY - add orders on the same trend
if longonmarket and close-tradeprice(1)>=gridstep then
BUY amount LOT AT MARKET
endif
//money management
liveaccountbalance = accountbalance+strategyprofit
moneyrisk = (liveaccountbalance*(riskpercent/100))
if onmarket then
onepointvaluebasket = pointvalue*countofposition
mindistancetoclose =(moneyrisk/onepointvaluebasket)*pipsize
endif

//floating profit
floatingprofit = (((close-positionprice)*pointvalue)*countofposition)/pipsize

//actual trade gains
MAfloatingprofit = average[20](floatingprofit)
BBfloatingprofit = MAfloatingprofit - std[20](MAfloatingprofit)*sd

//floating profit risk reward check
if rr>0 and floatingprofit>moneyrisk*rr then
RRreached=1
endif

//stoploss trigger when risk reward ratio is not met already
c4 = (HAC = -1)
if onmarket and (c4)=1 then
SELL AT MARKET
endif

if onmarket and RRreached=0 then
SELL AT positionprice-mindistancetoclose STOP
endif

//stoploss trigger when risk reward ratio has been reached
if onmarket and RRreached=1 then
if floatingprofit crosses under BBfloatingprofit then
SELL AT MARKET
endif
endif

//resetting the risk reward reached variable
if not onmarket then
RRreached = 0
endif

Short

/// Definition of code parameters
defparam preloadbars =10000
DEFPARAM CumulateOrders = true // Cumulating positions deactivated
AAA= ADX [25]
DIM= DI[25]
HAC= call "HA Change"

once RRreached = 0
accountbalance = 100000 //account balance in money at strategy start
riskpercent = 1 //whole account risk in percent%
amount = 1 //lot amount to open each trade
rr = 1 //risk reward ratio (set to 0 disable this function)
//sd = 0.25 //standard deviation of MA floating profit


//dynamic step grid
minSTEP = 5 //minimal step of the grid
maxSTEP = 30 //maximal step of the grid
ATRcurrentPeriod = 150 //recent volatility 'instant' period
ATRhistoPeriod = 3000 //historical volatility period

ATR = averagetruerange[ATRcurrentPeriod]
histoATR= highest[ATRhistoPeriod](ATR)

resultMAX = MAX(minSTEP*pipsize,histoATR - ATR)
resultMIN = MIN(resultMAX,maxSTEP*pipsize)

gridstep = (resultMIN)

// Conditions to enter short positions
c11 = (AAA > 10)
c12 = (DIM < 0)
c13 = (HAC = -1)

//first trade whatever condition, for only one cycle add "AND STRATEGYPROFIT=0" on line 39.
if NOT ONMARKET AND (c11)=1 AND (c12)=1 AND (c13)=1 AND close<close[1] then
SELLSHORT amount LOT AT MARKET
endif

// case SELL - add orders on the same trend
if shortonmarket and tradeprice(1)-close>=gridstep then
SELLSHORT amount LOT AT MARKET
endif

//money management
liveaccountbalance = accountbalance+strategyprofit
moneyrisk = (liveaccountbalance*(riskpercent/100))
if onmarket then
onepointvaluebasket = pointvalue*countofposition
mindistancetoclose =(moneyrisk/onepointvaluebasket)*pipsize
endif

//floating profit
floatingprofit = (((close-positionprice)*pointvalue)*countofposition)/pipsize

//actual trade gains
MAfloatingprofit = average[200](floatingprofit)
BBfloatingprofit = MAfloatingprofit - std[200](MAfloatingprofit)//*sd

//floating profit risk reward check
if rr>0 and floatingprofit>moneyrisk*rr then
RRreached=1
endif

c14 = (HAC > 0)
if c14 then
EXITSHORT AT MARKET
endif

//stoploss trigger when risk reward ratio is not met already
if onmarket and RRreached=0 then
EXITSHORT AT positionprice-mindistancetoclose STOP
endif

//stoploss trigger when risk reward ratio has been reached
if onmarket and RRreached=1 then
if floatingprofit crosses under BBfloatingprofit then
EXITSHORT AT MARKET
endif
endif

//resetting the risk reward reached variable
if not onmarket then
RRreached = 0
endif

I hope you will enjoy it and find room for improvements 🙂

Kasper, have you tried the latest code with HA entry and exit? It seems very promising when limiting the number of entries and running it on M15 or H1 but I’m looking for a way to filter out the sideways movement but it’s tricky to find a good one, I have been experimenting with Keltner and Donchian but no major progress yet. I’m hoping you may have some suggestions 🙂

Well it is coded as an automated strategy but just as with the other versions of my strategies we need to pick and choose the period to start it when we have the right setup and stop it when we are happy with our profits or the setup has disappeared. If we expect an up move on DAX on Monday we start the strategy on Monday morning and keep an eye on it and the price action during the day.

Indeed MTF support would make a huge difference with more precise entries and a stoploss ready to kick in right away when a retrace occurs rather than at the close of each 15m candle, do think there is a chance that we can change the code in the HA Change to reflect a higher TF, for instance running it on 5m with the changes of 15m? I know I have asked the question before but perhaps we have found new answers since last time it was asked.

I will look inte Ale’s code more and give it a shot too, it has a lot of potential for the ranging markets we have been seeing lately.

Thanks for your feedback Kasper 🙂