I converted it to MTF (1-minute default TF):

// HammerNegated OIL 10min mtf
//
// https://www.prorealcode.com/prorealtime-trading-strategies/oil-10min-hammernegated-pattern-strategy/
// https://www.prorealcode.com/topic/francescos-hammernegated-strategy/
//
defparam cumulateorders = false
timeframe(10 minute,updateonclose)
ONCE p            = 36                         //36             4
ONCE t            = 0                          //0              0
av1               = average[2,t](close)        //2              2
av2               = average[2,t](close)        //2              15
av3               = average[50,t](close)       //50             30
ONCE x            = 0.53                       //0.53           0.50
bull              = close> av1 and close >av2 and close > av3
bear              = close <av1 and close <av2 and close < av3
ONCE n            = 150                        //150            95
ONCE m            = 30                         //30             85
hammerup          = min(open[1],close[1]) > high[1]-(high[1]-low[1]) / 3//and timeok
hammerupnegated   = max(open,close) < min(open[1],close[1]) and abs(open-close) / (high-low) > x
cs                = hammerup and hammerupnegated and bear
hammerdown        = max(open[1],close[1]) < low[1]+(high[1]-low[1]) / 3 //and timeok
hammerdownnegated = min(open,close) > max(open[1],close[1]) and abs(open-close) / (high-low) > x
cl                = hammerdown and hammerdownnegated and bull
timeframe(default)
if cs AND Not OnMarket then
   sellshort 1 contract at market
   set target pprofit n*averagetruerange[p]
   set stop   ploss   m*averagetruerange[p]
endif
if cl AND Not OnMarket then
   buy 1 contract at market
   set target pprofit n*averagetruerange[p]
   set stop   ploss   m*averagetruerange[p]
endif
//TRAILING STOP
ONCE TGL = 27     //27      30
ONCE TGS = 27     //27      18
if not onmarket then
   MAXPRICE     = 0
   MINPRICE     = close
   PREZZOUSCITA = 0
ENDIF
if longonmarket then
   MAXPRICE = MAX(MAXPRICE,close)
   if MAXPRICE-tradeprice(1)>=TGL*pointsize then
      PREZZOUSCITA = MAXPRICE-TGL*pointsize
   ENDIF
ENDIF
if shortonmarket then
   MINPRICE = MIN(MINPRICE,close)
   if tradeprice(1)-MINPRICE>=TGS*pointsize then
      PREZZOUSCITA = MINPRICE+TGS*pointsize
   ENDIF
ENDIF
if onmarket and PREZZOUSCITA>0 then
   EXITSHORT AT PREZZOUSCITA STOP
   SELL      AT PREZZOUSCITA STOP
ENDIF

1. it’s not a typo, it’s the optimization tool that said it was the same (I kept all the three not to alter the original logic)
2. I kept the same code as the original version, but you can try different settings
3. Yes, I optimized all variables due to the fact that I was using a MTF approach, which is different from using a single TF
4. Yes, I attach both 100k and 200k performance on the original code, but with a 15-minute TF as you asked (oddly enough there’s no difference in performance and dates on CL, while there are on DAX or Eur/Usd). I never use 200k tests!
5. No, I just kept the original code, just changing values or replacing some constants with variables. I also reintroduced the last two lines, but placed them elsewhere to avoid SL & TP be altered every candle when onmarket