Prova questo:

// Definizione dei parametri del codice
DEFPARAM CumulateOrders = false // Posizioni cumulate attivate
// Il sistema cancellerà tutti gli ordini in attesa e chiuderà tutte le posizioni a 0:00. Dopo l’orario "Flat Before" non saranno piazzati nuovi ordini o posizioni.
DEFPARAM FLATBEFORE = 230100
// Cancellare tutti gli ordini in attesa e chiudere tutte le posizioni all’orario "Flat After"
DEFPARAM FLATAFTER = 230000
//
TIMEFRAME(default)
// Impedisce al sistema di tradare in giorni specifici della settimana
daysForbiddenEntry = OpenDayOfWeek = 6 OR OpenDayOfWeek = 0
//
ONCE risk  = 50                                //max. capitale da rischiare
ONCE lotti = 1                                 //1 lotto per difetto
MyATR = AverageTrueRange[7](close)*10          // 10 volte atr
//
IF MyATR >= 2 AND MyATR <= 5 THEN
   Lotti = 1
ELSIF MyATR >= 6 AND MyATR <= 9 THEN
   Lotti = 1.5
ENDIF
//
Pips  = Risk / PipValue                        //Ricalcola
SET STOP   pLOSS Pips
SET TARGET pPROFIT Pips * 3
//
// Condizioni per entrare su posizioni long
indicator1 = Average[3](Stochastic[5,3](close))
c1 = (indicator1 CROSSES OVER 20)
//
TIMEFRAME(1 hour,default)
indicator2 = ExponentialAverage[9](close)
indicator3 = ExponentialAverage[21](close)
c2 = (indicator2[1] > indicator3[1])
//
TIMEFRAME(default)
IF (c1 AND c2) AND not daysForbiddenEntry THEN
   BUY Lotti SHARES AT MARKET
ENDIF
// Condizioni per entrare su posizioni short
indicator4 = Average[3](Stochastic[5,3](close))
c3 = (indicator4 CROSSES UNDER 80)
//
TIMEFRAME(1 hour,default)
indicator5 = ExponentialAverage[9](close)
indicator6 = ExponentialAverage[21](close)
c4 = (indicator5[1] < indicator6[1])
//
TIMEFRAME(default)
IF (c3 AND c4) AND not daysForbiddenEntry THEN
   SELLSHORT Lotti SHARES AT MARKET
ENDIF
TIMEFRAME (5minute,upDateOnClose)
//************************************************************************
//trailing stop function
trailingstart = 20  //trailing will start @trailinstart points profit
trailingstep  = 5   //trailing step to move the "stoploss"
//reset the stoploss value
IF NOT ONMARKET THEN
   newSL=0
ENDIF
//manage long positions
IF LONGONMARKET THEN
   //first move (breakeven)
   IF newSL=0 AND close-tradeprice(1)>=trailingstart*pipsize THEN
      newSL = tradeprice(1)+trailingstep*pipsize
   ENDIF
   //next moves
   IF newSL>0 AND close-newSL>=trailingstep*pipsize THEN
      newSL = newSL+trailingstep*pipsize
   ENDIF
ENDIF
//manage short positions
IF SHORTONMARKET THEN
   //first move (breakeven)
   IF newSL=0 AND tradeprice(1)-close>=trailingstart*pipsize THEN
      newSL = tradeprice(1)-trailingstep*pipsize
   ENDIF
   //next moves
   IF newSL>0 AND newSL-close>=trailingstep*pipsize THEN
      newSL = newSL-trailingstep*pipsize
   ENDIF
ENDIF
//stop order to exit the positions
IF newSL>0 THEN
   SELL AT newSL STOP
   EXITSHORT AT newSL STOP
ENDIF

Per favore non duplicare i post!

Tu l’hai addiruttura triplicato inserendone uno nel forum sbagliato!

Può solo frammentare le informazioni in quanto qualcuno può risponderti ad un post, qualcun altro ad altri post, col risultato di rendere più difficile trovare le informazioni.

Hai postato qui Venerdì sera, adesso è Lunedì mattina e c’è stato un fine settimana nel mezzo in cui non sempre c’è qualcuno disponibile. Le risposte vengono date da trader appassionati e volontari, quando hanno dei momenti liberi. A volte ne hanno di più, altre di meno.

Ti prego di avere pazienza e di rispettare le regole basilari ben evidenziate in giallo quoi sotto.

Grazie 🙂

Intanto noto che hai un orario diverso, un’ora in meno rispetto a quella italiana, forse usi quella inglese.

Bene, dovremmo esserci, ho trovato degli errori logici nel calcolo, che è più semplice di quanto pensassi prima.

Vedrai che ci sono molte operazioni che finiscono con 150 di guadagno, mentre quelle in perdita sono di 50, tranne alcune perché hanno chiuso l’operazione in occasione di gap contrari, quindi hanno chiuso al primo prezzo disponibile, anche se distante molti pip!

// Definizione dei parametri del codice
DEFPARAM CumulateOrders = false // Posizioni cumulate attivate
// Il sistema cancellerà tutti gli ordini in attesa e chiuderà tutte le posizioni a 0:00. Dopo l’orario "Flat Before" non saranno piazzati nuovi ordini o posizioni.
//DEFPARAM FLATBEFORE = 230100
// Cancellare tutti gli ordini in attesa e chiudere tutte le posizioni all’orario "Flat After"
//DEFPARAM FLATAFTER = 230000
//
TIMEFRAME(default)
// Impedisce al sistema di tradare in giorni specifici della settimana
daysForbiddenEntry = OpenDayOfWeek = 6 OR OpenDayOfWeek = 0
//
//////////////////////////////////////////////////////////////////////////////////
ONCE risk     = 50                                 //max. capitale da rischiare
ONCE PipNum   = risk / pipvalue                    //Numero di Pips in base al rischio
ONCE lotti    = 1                                  //1 lotto per difetto
//ONCE MinLotti = 0.5                                //Numero minimo di lotti
MyATR         = (AverageTrueRange[7](close) / pipsize) * 2
Pips          = max(0,min(PipNum,MyATR))
Lotti         = PipNum / Pips
//////////////////////////////////////////////////////////////////////////////////
//
// Condizioni per entrare su posizioni long
indicator1 = Average[3](Stochastic[5,3](close))
c1 = (indicator1 CROSSES OVER 20)
//
TIMEFRAME(1 hour,default)
indicator2 = ExponentialAverage[9](close)
indicator3 = ExponentialAverage[21](close)
c2 = (indicator2[1] > indicator3[1])
//
TIMEFRAME(default)
IF (c1 AND c2) AND not daysForbiddenEntry AND Not OnMarket THEN
BUY Lotti SHARES AT MARKET
SET STOP   pLOSS   Pips
SET TARGET pPROFIT Pips * 3
ENDIF
// Condizioni per entrare su posizioni short
indicator4 = Average[3](Stochastic[5,3](close))
c3 = (indicator4 CROSSES UNDER 80)
//
TIMEFRAME(1 hour,default)
indicator5 = ExponentialAverage[9](close)
indicator6 = ExponentialAverage[21](close)
c4 = (indicator5[1] < indicator6[1])
//
TIMEFRAME(default)
IF (c3 AND c4) AND not daysForbiddenEntry AND Not OnMarket THEN
SELLSHORT Lotti SHARES AT MARKET
SET STOP   pLOSS   Pips
SET TARGET pPROFIT Pips * 3
ENDIF
TIMEFRAME (5minute,upDateOnClose)
//************************************************************************
//trailing stop function
trailingstart = 20  //trailing will start @trailinstart points profit
trailingstep  = 5   //trailing step to move the "stoploss"
//reset the stoploss value
IF NOT ONMARKET THEN
newSL=0
ENDIF
//manage long positions
IF LONGONMARKET THEN
//first move (breakeven)
IF newSL=0 AND close-tradeprice(1)>=trailingstart*pipsize THEN
newSL = tradeprice(1)+trailingstep*pipsize
ENDIF
//next moves
IF newSL>0 AND close-newSL>=trailingstep*pipsize THEN
newSL = newSL+trailingstep*pipsize
ENDIF
ENDIF
//manage short positions
IF SHORTONMARKET THEN
//first move (breakeven)
IF newSL=0 AND tradeprice(1)-close>=trailingstart*pipsize THEN
newSL = tradeprice(1)-trailingstep*pipsize
ENDIF
//next moves
IF newSL>0 AND newSL-close>=trailingstep*pipsize THEN
newSL = newSL-trailingstep*pipsize
ENDIF
ENDIF
//stop order to exit the positions
IF newSL>0 THEN
SELL AT newSL STOP
EXITSHORT AT newSL STOP
ENDIF
//
//graph MyATR
//graph Lotti
//graph Pips
//graph NewSL