Hi all,

Here my first approximation… I feel very optimistic about this approach although there is a lot work to do (that’s why there is not algorithm to detects double bottom/tops yet )

Please see the picture attached, the triangle is draw by the algorithm here:

//LOCALS MINIMUMS AND MAXIMUMS

Kdouble=0.1 //Factor for defining what is double top or bottom

//Leo Moving Average, formula: LMA= WMA+(WMA-SMA)
LMA=2*weightedaverage[period](close)-average[period](close)

//Smoothed curve of Leo Moving Average
IF BARINDEX > period THEN
smoothLMA=weightedaverage[period](LMA)
ELSE
smoothLMA=undefined
ENDIF

// << Storage of minimums and maximums >>
once mintemp=low
once posmintemp=1
once maxtemp=high
once posmaxtemp=1

IF BARINDEX>1 THEN
// the value 0.75 is to ensure that the donchian channel is faster than the curves analysis (this value to be checked)
IF low < lowest[round(0.75*period)](low[1]) THEN
mintemp=low //minimum temporal
posmintemp=BARINDEX //postition of minimum temporal
ENDIF
IF high > highest[round(0.75*period)](high[1]) then
maxtemp=high //maximum temporal
posmaxtemp=BARINDEX //position maximum temporal
ENDIF
ENDIF

//  << Detecting and locating a local minimums >>
//  Where the LMA is crossing the smoothed LMA, there is a maximum or minimum nearby
//  If there is a new local min/max, the preivus one is stored in de varible B... (before)
once LEVMIN=low
once POSLEVMIN=1
once LEVMAX=high
once POSLEVMAX=1

IF LMA crosses over smoothLMA THEN
BLEVMIN=LEVMIN        //previus local minimum is saved
BPOSLEVMIN=POSLEVMIN
LEVMIN=mintemp
POSLEVMIN=posmintemp
support=LEVMIN
DRAWARROWUP(POSLEVMIN,LEVMIN) coloured(0,0,0,30)
ENDIF

// --> Detecting and locating a local maximum
IF LMA crosses under smoothLMA THEN
BLEVMAX=LEVMAX       //previus local maximum is saved
BPOSLEVMAX=POSLEVMAX
LEVMAX=maxtemp
POSLEVMAX=posmaxtemp
resistance=LEVMAX
DRAWARROWDOWN(POSLEVMAX,LEVMAX) coloured(0,0,0,30)
ENDIF

support=min(low,support)
resistance=max(high,resistance)


// << DETECTING DOUBLE TOP OR BOTTOMS  >>

once WidthDoubleTop = high-low
once WidthDoubleBottom = high-low

//--> Double bottoms
IF LMA crosses over smoothLMA THEN
WidthDoubleBottom = LEVMAX-(BLEVMIN+LEVMIN)/2 // local max minus average of the las two local min
IF abs(BLEVMIN-LEVMIN) < Kdouble*WidthDoubleBottom THEN
DRAWTRIANGLE(POSLEVMIN,LEVMIN,POSLEVMAX,LEVMAX,BPOSLEVMIN,BLEVMIN) COLOURED(0,255,0,200)
ENDIF
ENDIF
//--> Double tops
IF LMA crosses under smoothLMA THEN
WidthDoubleTop=(BLEVMAX+LEVMAX)/2 -LEVMIN
IF abs(BLEVMAX-LEVMAX) < Kdouble*WidthDoubleTop THEN
DRAWTRIANGLE(POSLEVMIN,LEVMIN,POSLEVMAX,LEVMAX,BPOSLEVMAX,BLEVMAX) COLOURED(255,0,0,200)
ENDIF
ENDIF

RETURN LMA AS "LMA", support as "support", resistance as "resistance", smoothLMA as "smooth LMA" //, lowest[round(0.75*period)](low[1]), highest[round(0.75*period)](high[1])