buongiorno a tutti
avrei bisogno di un’indicazione su come inserire in automatico lo SL in un’operazione di break.
In un time frame giornaliero entro (se ne esistono le condizioni) alla rottura del massimo della barra precedente. Avrei bisogno delle indicazioni per settare (solo al momento dell’ingresso se vengo eseguito) uno stop loss a n Pips sotto al prezzo di apertura della barra medesima
ringrazio anticipatamente, Joe
Eccolo (entra 5 pips sotto l’apertura):
IF MieCondizioniLong THEN
BUY 1 Contract at Market
SET STOP PRICE (Open - 10*PipSize)
ENDIF
grazie, sempre prontissimo!
ancora una domanda
se voglio gestire lo stop con un multiplo dell’ATR?
Ecco un esempio:
superTrendValue = SuperTrend[5.4,36]
myAtr = AverageTrueRange[14](close)
IF NOT ONMARKET AND close CROSSES OVER superTrendValue THEN
BUY 1 CONTRACT AT MARKET
set target profit myAtr * 2
set stop loss myAtr
ELSIF NOT ONMARKET AND close CROSSES UNDER superTrendValue THEN
SELLSHORT 1 CONTRACT AT MARKET
set target profit myAtr * 2
set stop loss myAtr
ENDIF
E’ possibile inserire un secondo stop loss o comunque un sistema che mi permetta di uscire dal trade nel caso il primo stop loss risulti troppo elevato? Mi spiego, nella strategia lo stop loss basato sull’entrata si rivela corretto ma in alcuni casi dove la candela giornaliera ha performato molto nel caso di perdita subisco una botta fuori dal comune. Come posso arginarla?
Si, certo. Come vorresti limitare lo Stop Loss?
In questo modo…ho lo stop loss che normalmente lavora qualche tick sotto il prezzo di apertura della barra dopo che il sistema in reverse è entrato alla rottura della barra precedente. Se il sistema entra su una barra molto lunga e ritraccia immediatamente fino allo stop, in qualche caso posso subire delle perdite molto pesanti. Guardando l’analisi MAE ci sono pochi trade che fanno questo ma quando succede sono pesanti. Avrei bisogno di uno stop che, a prescindere dallo stop normale basato sull’apertura chiudesse la posizione nel momento in cui il DD superi una certa cifra
Ecco il codice, dove ho indicato un Capitale iniziale di 100000 ed un DD massimo di 10000. Ovviamente tu metterai i dati che soddisfano le tue necessità:
// calcolo del DrawDown
//
ONCE Capital = 100000
ONCE MinPoint = Capital
ONCE MaxPoint = 0
ONCE MaxDD = 0
//------------------------------------------
// EQUITY
Equity = Capital + StrategyProfit
TempProfit = PositionPerf * PositionPrice / PipSize * PipValue // / abs(CountOfPosition)
TempEquity = Equity + TempProfit
//------------------------------------------
// DrawDown
MaxPoint = max(MaxPoint,TempEquity)
DD = MaxPoint - TempEquity
MaxDD = max(MaxDD,DD)
DDperc = MaxDD * 100 / Capital
//
//------------------------------------------
// inioio della strategia
ONCE DDlimit = 10000 //limite del DrawDown, dopodiché si chiudono le operazioni
superTrendValue = SuperTrend[5.4,36]
myAtr = AverageTrueRange[14](close)
IF NOT ONMARKET AND close CROSSES OVER superTrendValue THEN
BUY 1 CONTRACT AT MARKET
set target profit myAtr * 2
set stop loss myAtr
ELSIF NOT ONMARKET AND close CROSSES UNDER superTrendValue THEN
SELLSHORT 1 CONTRACT AT MARKET
set target profit myAtr * 2
set stop loss myAtr
ENDIF
IF (MaxDD >= DDlimit) THEN
SELL AT MARKET
EXITSHORT AT MARKET
MaxDD = 0
MaxPoint = 0
ENDIF
//graph MaxDD
me lo studio, grazie ancora
