Grazie, Roberto, per la tua disponibilità.

Allora, il pattern sul quale sto ragionando da un po’ di tempo è il seguente. E’ un pattern a due barre basato su una prima partenza in una direzione, che poi si rivela falsa in quanto il mercato va nella direzione inversa. Vediamolo nelle due versioni.

Versione Short

La versione short, che ho denominato IFU (Inside Fake Up), è così formata. La prima candela è una barra inside e la seconda è una barra il cui massimo è superiore al massimo della inside e la cui chiusura è inferiore al minimo della barra inside. Questo è il setup. Il trigger, ovvero il segnale di vendita, è dato dalla rottura del minimo della seconda barra.

Questo potrebbe essere il codice che individua il pattern.

// IFU:Inside Fake Up

InsideBar=Low[1]>Low[2] and High[1]<High[2]

SecondBarDown=High>High[1] and Close<Low[1]

Versione Long

La versione long, che ho denominato IFD (Inside Fake Down), è così formata. La prima candela è una barra inside e la seconda è una barra il cui minimo è inferiore al minimo della barra inside e la cui chiusura è superiore al massimo della barra inside. Questo è il setup. Il trigger, ovvero il segnale di acquisto, è dato dalla rottura del massimo della seconda barra.

E questo potrebbe essere il codice che va a cercare questo pattern.

// IFD:Inside Fake Down

InsideBar=Low[1]>Low[2] and High[1]<High[2]

SecondBarUp=Low<Low[1] and Close>High[1]

Un grafico, che si riferisce alla giornata del 21/12/2020 del Dax con time frame a 3 minuti, potrebbe aiutare.

In genere, quando studio un nuovo pattern, la prima cosa che faccio è quella di scrivermi l’indicatore che lo individua.

In questo caso ho scritto il seguente codice.

// IFU:Inside Fake Up; IFD:Inside Fake Down

InsideBar=Low[1]>Low[2] and High[1]<High[2]

SecondBarDown=High>High[1] and Close<Low[1]

SecondBarUp=Low<Low[1] and Close>High[1]

atr=AverageTrueRange[14](close)

//IFU
if InsideBar and SecondBarDown then
drawarrowdown (barindex, High+0.5*atr) coloured(255,0,0) //rosso
endif

//IFD
if InsideBar and SecondBarUp then
drawarrowup (barindex, Low-0.5*atr) coloured(0,255,0) //rosso
endif

return

E qui pongo una prima domanda. E’, tale codice, corretto e coerente al pattern descritto? Oppure manca qualcosa o vi è qualcosa di errato? Inoltre, poteva essere scritto in modo più efficiente?

IFU_IFD.png

Allora provo io.

Defparam CumulateOrders = False // Posizioni cumulate disattivate

percProfitto=0.6
percRischio=7

InsideBar=Low[1]>Low[2] and High[1]<High[2]
SecondBarDown=High>High[1] and Close<Low[1]
SecondBarUp=Low<Low[1] and Close>High[1]

if STRATEGYPROFIT<> STRATEGYPROFIT[1] then
Setup=0
Endif

if InsideBar and SecondBarDown then
EntryShort=Low-1*pipsize
Rischio=Range*percRischio+2*pipsize
Profitto=percProfitto*Rischio
Setup=1
endif

if Setup and not(OnMarket) then
SELLSHORT at EntryShort stop
endif

SET STOP PLOSS Rischio
SET TARGET PPROFIT Profitto

Questo è il codice relativo alla sola versione short del pattern.  Le righe di codice 10,11 e 12 si sono rese necessarie per evitare una seconda entrata non segnalata dalla presenza del pattern ma dal fatto che la variabile setup non viene portata a zero se l’entrata e l’uscita avvengono nella stessa barra.

Le variabili da ottimizzare sono percProfitto e percRischio. Con i valori indicati nel codice alle righe 3 e 4 si ottiene, applicato al Germany 30 su un grafico a 3 minuti, una percentuale di profitto del 72% circa con 10 punti circa di guadagno medio per trade. Naturalmente questo è solo un esempio di valore didattico.

fig1.png

C’è poi la questione dei filtri, molto spesso basati sul tempo. Si potrebbe, in questo caso, accogliere solo quei pattern che si verificano nel corso della sessione di borsa aperta che, nel caso del Dax, significa dalle 9:00 alle 17:30. Vediamo il codice.

Defparam CumulateOrders = False // Posizioni cumulate disattivate

percProfitto=0.6
percRischio=7

SetupTime=time>=090000 and time<=173000

InsideBar=Low[1]>Low[2] and High[1]<High[2]
SecondBarDown=High>High[1] and Close<Low[1]
SecondBarUp=Low<Low[1] and Close>High[1]

if STRATEGYPROFIT<> STRATEGYPROFIT[1] then
Setup=0
Endif

if InsideBar and SecondBarDown and SetupTime then
EntryShort=Low-1*pipsize
Rischio=Range*percRischio+2*pipsize
Profitto=percProfitto*Rischio
Setup=-1
endif

if InsideBar and SecondBarUp and SetupTime then
EntryLong=High+1*pipsize
Rischio=Range*percRischio+2*pipsize
Profitto=percProfitto*Rischio
Setup=1
endif

if Setup=-1 and not(OnMarket) then
SELLSHORT at EntryShort stop
endif

if Setup=1 and not(OnMarket) then
Buy at EntryLong stop
endif

SET STOP PLOSS Rischio
SET TARGET PPROFIT Profitto

Sembra interessante: il guadagno medio per trade è cresciuto in modo percentualmente importante.

Naturalmente, come per tutti i filtri, si osserverà una più o meno importante riduzione del numero delle operazioni e, quindi, una riduzione dell’attendibilità dei risultati statistici del backtest. In questo caso, come si può notare dalla figura, il numero delle trades si è ridotto a circa un terzo di quello precedente all’inserzione del filtro.

fig3.png

Due errori, trovati! In realtà era uno solo, l’altro era semplicemente legato al prezzo di entrata che essendo di tipo stop, lo faceva in apertura quale primo prezzo disponibile. E quel prezzo non mi tornava.

Comunque, sperando che ci sia qualcuno interessato, scrivo qui di cosa si trattava. Potrebbe tornare utile a chi, come me e tanti altri qui dentro, cerca di capire e sviscerare il linguaggio.

Allora, riferendomi al codice pubblicato al post #156304, le righe 8,9 e 10 individuano le barre che costituiscono il pattern long e quello short. Le righe da 16 a 21 verificano la sussistenza delle condizioni di presenza del pattern short e intervallo orario operativo e, in caso affermativo, calcolano il prezzo di entrata, il rischio dove posizionare lo stoploss ed il target price. Viene inoltre posta a -1 la variabile Setup.

Le righe da 23 a 28 verificano la sussistenza delle condizioni di presenza del pattern long e intervallo orario operativo e, in caso affermativo, calcolano il prezzo di entrata, il rischio dove posizionare lo stoploss ed il target price. Viene inoltre posta a +1 la variabile Setup.

Ora, nel caso non si sia a mercato e sia pari a -1 la variabile Setup, le righe 30,31 e 32 dispongono l’ordine di vendita al prezzo di entrata prima calcolato in modalità stop. In modo analogo, le righe 34, 35 e 36 nel caso di disposizione di ordine di acquisto.

Ora, vediamo cosa succede.

Il 3/12/2020 alle 12:48 c’è un ingresso short a 13255,6. Valore corretto in quanto il prezzo di entrata è calcolato un punto sotto al minimo della seconda barra del pattern che, in questo caso, vale 13.256,8. Il profitto, calcolato come da riga 19 del codice, vale 26,40. Quindi, l’uscita in gain dovrebbe avvenire a 13.230,4. In effetti, come mostra la seconda figura, avviene a 13.209. Perché?

Perché dopo l’ingresso, si sono presentati altri due pattern short, vedi terza figura, che hanno modificato il valore del profitto.

Allora il codice deve essere corretto. E come? Evitando che, quando il sistema è già a mercato, si rientri nella routine che ricalcola profitto, prezzo di entrata, ecc.

if InsideBar and SecondBarDown and SetupTime and Setup=0 then

EntryShort=Low-1*pipsize

Rischio=Range*percRischio+2*pipsize

Profitto=percProfitto*Rischio

Setup=-1

Endif

In questo modo il sistema entra in questa parte di codice solo se Setup=0.

IFU_IFD_1.png IFU_IFD_2.png IFU_IFD_3.png

L’ottimizzazione, su 50 k, sempre con time frame a 7 minuti, produce i risultati mostrati in figura. Sembrano abbastanza stabili.

IFU_IFD_6.png