COMPRESSIONE D PREZZO E ATR

Viewing 2 posts - 1 through 2 (of 2 total)

Author

Posts

09/08/2021 at 8:12 AM #176999 quote

Participant

Senior

Buon giorno Roberto chiedevo due screener diversi con i seguenti parametri per grafici giornalieri:

il range di prezzo dal minimo (low) al massimo degli ultimi 8-10 giorni (numero che si deve poter cambiare a piacimento) non deve essere più del 10% (% da cambiare a piacimento)del massimo raggiunto nel periodo;

l ATR a 14 periodi deve essere il minimo degli ultimi 10 giorni.

oppure

il range di prezzo dal minimo (low) al massimo (high) degli ultimi 8-10 giorni (numero che si deve poter cambiare a piacimento) non deve essere più del 10% (% da cambiare a piacimento) del massimo di prezzo raggiunto nel periodo;

il BB% (bollinger Bands % deve essere al minimo degli ultimi 10 gg (da poter cambiare);

il Money Flow deve essere al minimo degli ultimi 10gg (da poter cambiare).

Spero di essermi spiegato, grazie mille.

09/08/2021 at 8:48 AM #177001 quote

robertogozzi

Moderator

Legend

Primo:

P   = 10                             //Numero di periodi
Atr = AverageTrueRange[14](close)    //Average True Range
HH  = highest[P](high)               //Massimo degli ultimi 10 periodi
LL  = lowest[P](low)                 //Minimo  degli ultimi 10 periodi
Rng = HH - LL                        //intervallo (range) degli ultimi 10 periodi
c1  = (Atr = lowest[P](Atr))         //ATR sul minimo
c2  = (Rng <= (HH * 0.1))            //range non oltre il 10%
Cond= c1 AND c2
SCREENER[Cond](Atr AS "Atr")

Secondo:

P       = 10                             //Numero di periodi
// range
HH      = highest[P](high)               //Massimo degli ultimi 10 periodi
LL      = lowest[P](low)                 //Minimo  degli ultimi 10 periodi
Rng     = HH - LL                        //intervallo (range) degli ultimi 10 periodi
//BB %
N       = 20
dev     = 2.0
BollInf = Average[N,0](close) - (dev * std[N](close))
BollSup = Average[N,0](close) + (dev * std[N](close))
pB      = ((close - BollInf) / (BollSup - BollInf)) * 100   //BB %
//
Mfi     = MoneyFlowIndex[14]             //MFI
//
c1      = (pB = lowest[P](pB))           //BB% minimo degli ultimi P periodi
c2      = (Rng <= (HH * 0.1))            //range non oltre il 10%
c3      = (Mfi = lowest[P](Mfi))         //BB% minimo degli ultimi P periodi
Cond= c1 AND c2 AND c3
SCREENER[Cond](pB AS "BB%")