Per favore non aggiungere nuovi argomenti ad altri già esistenti.

Per ciascun nuovo argomento, anche se molto simile, occorre aprirne uno nuovo con un titolo appropriato. Grazie 🙂

Adesso l’ho creato io.

Se riesci a postare il codice formattato sarebbe meglio. Anche un link alla pagina web dove l’hai trovato sarebbe molto utile.

Ecco qui:

//-------------------------------------------//
//PRC_Autocorr Price Forecasting
//version = 0
//01.04.2025
//Iván González @ www.prorealcode.com
//Sharing ProRealTime knowledge
//-------------------------------------------//
// Inputs
//-------------------------------------------//
length = 20         // Lag period used for autocorrelation
window = 200        // Number of bars used in the correlation window
threshold = 0.5     // Threshold value to detect the presence of a cycle
src = close         // Source data for returns calculation

//-------------------------------------------//
// Manual Pearson Correlation Calculation
//-------------------------------------------//

// Initialize sum variables for correlation formula
sumX = 0
sumY = 0
sumXY = 0
sumX2 = 0
sumY2 = 0

// Loop through the window and compute necessary sums
FOR i = 0 TO window - 1 DO
   x = close[i]               // Current value
   y = close[i + length]      // Lagged value
   
   sumX  = sumX  + x          // ∑x
   sumY  = sumY  + y          // ∑y
   sumXY = sumXY + x * y      // ∑xy
   sumX2 = sumX2 + x * x      // ∑x²
   sumY2 = sumY2 + y * y      // ∑y²
NEXT

// Apply the Pearson correlation formula
numerador   = window * sumXY - (sumX * sumY)
denominador = SQRT((window * sumX2 - sumX * sumX) * (window * sumY2 - sumY * sumY))

// Handle division by zero
IF denominador <> 0 THEN
   autocorr = numerador / denominador
ELSE
   autocorr = 0
ENDIF

//-------------------------------------------//
// Cycle Detection & Linear Regression
//-------------------------------------------//
cycleDetected = autocorr > threshold   // Detect if autocorrelation is strong enough

// Compute percentage returns
returns = (src - src[1]) / src[1] * 100

// Apply linear regression on returns
linreg = LinearRegression[length](returns)

// Store regression value only if a cycle is detected
IF cycleDetected THEN
   storeCyclevalue = linreg
ENDIF

//-------------------------------------------//
// Future Price Forecast
//-------------------------------------------//
futurePriceEstimate = close * (1 + storeCyclevalue / 100)     // Forecast future price
hipoteticalGain = futurePriceEstimate - close                 // Calculate expected gain/loss

//-------------------------------------------//
// Color Assignment Based on Forecast Direction
//-------------------------------------------//
IF futurePriceEstimate > close THEN
   r = 105
   g = 247
   b = 62     // Green color for bullish forecast
ELSE
   r = 255
   g = 0
   b = 0      // Red color for bearish forecast
ENDIF

//-------------------------------------------//
// Display Forecast Info on Last Bar Only
//-------------------------------------------//
IF islastbarupdate THEN
   prediction = ROUND(hipoteticalGain, 3)         // Rounded gain value
   futurePrice = ROUND(futurePriceEstimate, 3)    // Rounded estimated price
   
   // Draw background box (positioned top right)
   drawrectangle(-10, -60, -200, -140) ANCHOR(topright, xshift, yshift)
   
   // Text labels showing the forecasted values
   drawtext("Last Bar Prediction", -100, -80) ANCHOR(topright, xshift, yshift)
   drawtext("Hipotetical Gain: #prediction#", -100, -100) ANCHOR(topright, xshift, yshift)
   drawtext("Future Price: #futurePrice#", -100, -120) ANCHOR(topright, xshift, yshift)
ENDIF

//-------------------------------------------//
// Output Forecast Line on Chart
//-------------------------------------------//
RETURN futurePriceEstimate COLOURED(r, g, b) STYLE(line, 2)

I valori restituiti sono simili a quelli restituiti dall'indicatore Tradingview…