Qui di seguito una domanda inviata a ProRealTime :

INGRESSO LONG:
Candela Bullish engulfing o di Breakout rialzista ingresso long 1 punto/pip sopra il massimo della candela
PARABILICSAR deve incrociare al rialzo e diventare di colore verde
RSI a [7] periodi deve essere  > 50)
fine condizione long

INGRESSO SHORT:
Candela Bearish engulfing o Breakout ribassista ingresso short 1 punti/pips sotto il minimo della candela
PARABILICSAR deve incrociare al ribasso e diventare di colore rosso
RSI a [7] periodi deve essere  < 50)
fine condizione short

Uscita posizione long:
Quando il parabolic sar incrocia al ribasso e diventa di colore rosso
fine uscite long

Uscita posizione short:
Quando il parabolic sar incrocia al rialzo e diventa di colore verde,
fine uscite short

// Stop e target: Inserisci qui i tuoi stop di protezione
Stop loss 1 punto/pip sotto il minimo della candela bullish engulfing o breakout nella posizione long
Stop loss 1 punto/pip sopra massimo della candela bearish engulfing o breakout nella candela short

E un esempio di risposta :

bullc1=Low=Lowest[5](Low)
bullc2=Close > Close[1]
Bullish=bullc1 and bullc2

Bearc1=High=Highest[5](High)
Bearc2=Close < Close[1]
Bearish=Bearc1 and Bearc2

bhc1=high=highest[10](high)
bhc2=(high-low)=highest[5](high-low)
bhc3=Volume>average[5](volume)
bhc4=Close > (high-((high-low)/3))
breakouthausse= bhc1 and bhc2 and bhc3 and bhc4

bbc1=low=lowest[10](low)
bbc2=(high-low)=highest[5](high-low)
bbc3=Volume>average[5](volume)
bbc4=Close < (low+((high-low)/3))
breakoutbaisse=bbc1 and bbc2 and bbc3 and bbc4


Parabolic=SAR[0.02,0.02,0.2]
myRSI=RSI[7](close)

cachat=(breakouthausse or Bullish) and Parabolic crosses under close and myRSI > 50
if not longonmarket and cachat then
buy 1 share at high+1*pointsize stop
longstop= low-1*pointsize
sell at longstop stop
endif

cvente=(bearish or breakoutbaisse) and Parabolic crosses over close and myRSI < 50
if not shortonmarket and  cvente then
sellshort 1 share at low-1*pointsize stop
shortstop=high+1*pointsize
exitshort at shortstop stop
endif

if longonmarket  then
sell at longstop stop
if parabolic crosses over close then
sell at market
endif
endif

if shortonmarket then
exitshort at shortstop stop
if parabolic crosses under close then
exitshort at market
endif
endif