Ciao, per valore assoluto s’intende l’eliminazione del segno negativo ad un risultato.

Se close è inferiore a open, close-open darà un risultato negativo, es:

close=5, open=7 close-open =5-7=-2.

In questo caso se vuoi il valore assoluto fai :

abs(close-open) =2

Per il range (high-low) non c’è bisogno di utilizzare abs perchè sarà sempre un risultato positivo, infatti high è sempre maggiore di low.

per la PIN rialzista (Hammer):

C1 = close[1]<open[1] // candela precedente ribassista

C2=open[0]>low[0]+(range*0.70) // apertura corrente nei 2/3 superiori del range

C3= close[0]>low[0]+(range*0.70)// chiusura corrente nei 2/3 superiori del range

C4= range[0]>abs(open-close)*3 // range > body di almeno 3 volte

per la PIN ribassista (shooting star):

C1 = close[1]>open[1] // candela precedente rialzista

C2=open[0]<high[0]-(range*0.70) // apertura corrente nei  2/3 inferiore del range

C3= close[0]<high[0]-(range*0.70) // chiusura corrente nei  2/3 inferiore del range

C4= range[0]>abs(open-close)*4  // range > body di almeno 3 volte

Puoi vedere altri codici di candele qui:

Candlestick patterns recognition

Max

Ottimo lavoro maximus78.

Per fare riferimento alla candela precedente usa [1] tra parentesi.

Se l’attuale è una Pin BAR, per verificare che la precedente sia ribassista scrivi

IF open[1] > close[1] THEN  //ribassista
IF close[1] > open[1] THEN  //rialzista

Ecco il codice completo long e short:

defparam cumulateorders=false

//per la PIN rialzista (hammer):
C1 = close[1]<open[1] // candela precedente ribassista
C2=open[0]>low[0]+(range*0.70) // apertura corrente nei 2/3 superiori del range
C3= close[0]>low[0]+(range*0.70)// chiusura corrente nei 2/3 superiori del range
C4= range[0]>abs(open-close)*3 // range > body di almeno 3 volte

condlong=c1 and c2 and c3 and c4
entrylong=high[0]+(1*pointsize)
stoplosslong=range[0]+(2*pointsize)
tplong=stoplosslong*2

// long trade
if not onmarket and condlong then
buy 1 shares at entrylong stop
set stop loss stoplosslong
set target profit tplong
endif

//per la PIN ribassista (shooting star):
C5 = close[1]>open[1] // candela precedente rialzista
C6=open[0]<high[0]-(range*0.70) // apertura corrente nei  2/3 inferiore del range
C7= close[0]<high[0]-(range*0.70) // chiusura corrente nei  2/3 inferiore del range
C8= range[0]>abs(open-close)*3  // range > body di almeno 3 volte

condshort=c5 and c6 and c7 and c8
entryshort=low[0]-(1*pointsize)
stoplossshort=range[0]+(2*pointsize)
tpshort=stoplossshort*2

if not onmarket and condshort then
sellshort 1 shares at entryshort stop
set stop loss stoplossshort
set target profit tpshort
endif

graph entrylong as "entrylong"
graph entrylong-stoplosslong as "stoploss long"
graph entrylong+tplong as " take profit long"

graph entryshort as "entryshort"
graph entryshort+stoplossshort as "stoploss short"
graph entryshort-tpshort as " take profit short"

Io utilizzo sempre il comando graph finale per le variabili di acquisto e vendita.

In questo modo verifico se i trades entrano ed escono ai giusti livelli di prezzo.

In questo caso, i livelli di prezzo sono quelli sulla candela precedente all’entrata in posizione.

Max

Esatto Fabio, devi lavorare sui filtri….per esempio…

range[0]>averagetruerange[20](close)*1.5 oppure *2

oppure se vuoi che la Pin rialzista sia in trend in un long trade:

close>average[N, type](close)

o controtrend reversal sempre in un long trade..

close<average[N, type](close)

Puoi utilizzare anche 2 medie mobili per determinare la situazione del mercato,oppure

oscillatori di ipercomprato e ipervenduto come RSI, stocastico o williams %R…

ecc…..

Max

No, prova anche quelli, ovviamente settando un adeguato spread.

Uno spread di 2 pips per esempio su EUR/USD su timeframe di 1 ora ha ovviamente un impatto molto diverso rispetto al timeframe a 1 minuto.

Le pin candles si formano frequentemente su tutti i timeframes.

Max

Certo che è possibile.

Devi impostare una variabile che “blocca” il verificarsi di una condizione.

Ti faccio un esempio con 2 condizioni distinte.

C1 il prezzo fa un nuovo minimo a 10 periodi.

C2 avviene un incrocio di 2 medie mobili entro 10 candele dal verificarsi di C1.

Mylongindex è la variabile che setto quando si verifica C1 e viene richiamata nelle condizioni di acquisto settando il periodo limite di 10 candele.

Vedrai nel grafico “graph” che le entrate in posizione sono sempre inferiori a 10 candele tra C1 e C2.

Max

defparam cumulateorders=false
c1=low[0]<lowest[10](low)[1]
c2=average[5](close) crosses over average[10](close)

if c1 then
mylongindex=barindex
endif

if (barindex-mylongindex)<10 and not onmarket then
if c2 then
buy 1 shares at market
set stop ploss 50
set target pprofit 100
endif
endif

graph (barindex-mylongindex)