I am clearing the decks of loads of Systems … off PRT and onto my PC.

I came across attached … good results so I thought I’d add to this Topic!  I did not optimise at all, just backtested today!

Paul you put so much hard work … I hope this Topic might be revived.

I will put on Forward Test on Monday and report back … and if I forget to report back, please remind me at some stage anybody!? 🙂

what do you mean by ATR = 5
I put the screen copy for more understanding

I have a “trailing challenge” for anyone up to it. I would guess that @Paul and @nonetheless might like this.

Attached is the Kama Sma strategy originally posted by robertogozzi. It includes his sophisticated trail. However the gain/loss ratio is about the same (2.6-2.7) with and without the trail. The win-rate is better with trail. But the interesting part is the MFE/MAE ratio at 3.7 (!) meaning there is way more candy to steal. I have tried a lot of trails and breakevens from this forum but can’t find a good one boosting the G/L above 3. Any suggestions on a suitable trail? A side note is that the equity curve will never be straight so don’t get hung up on that.

DEFPARAM CumulateOrders = false
DEFPARAM PreLoadBars    = 2000

//code re-invest
Capital = 1000 // initial capital
Equity = Capital + StrategyProfit
Position = Max(1, Equity * (1/Capital))
Position = Round(Position*100)
Position = Position/100
//********************

ONCE TP            = 4.5
ONCE SL            = 0.3

//code quit strategy
maxequity = max(equity,maxequity)
DrawdownNeededToQuit = 40   // percent drawdown from max equity to stop strategy
if equity < maxequity * (1 - (DrawdownNeededToQuit/100)) then
quit
endif
//*****************

////////////////////////////////////////////////////////////////////////
TIMEFRAME (default)
//ONCE nLots         = 1
ONCE LongTrading   = 1                                //1=allowed   0=banned
ONCE ShortTrading  = 1                                //1=allowed   0=banned

TIMEFRAME (1 hour, updateonclose)                                             //h1
IF Not OnMarket THEN
BarCount = 0
ELSE
BarCount = BarCount + 1
ENDIF
//------------------------------------------------------------------------------------
//                         Kama & Sma Strategy
//
//https://www.forexstrategiesresources.com/trend-following-forex-strategies/111-kama-strategy/
//
Period     = 2                                              //2        (standard 10)
FastPeriod = 2                                              //standard
SlowPeriod = 30                                             //standard
//
Fastest  = 2 / (FastPeriod + 1)
Slowest  = 2 / (SlowPeriod + 1)
if barindex >= (Period + 1) then
Num   = abs(close-close[Period])
Den   = summation[Period](abs(close-close[1]))
ER    = Num / Den
Alpha = SQUARE(ER *(Fastest - Slowest )+ Slowest)
Kama  = (Alpha * Close) + ((1 -Alpha)* Kama[1])
else
Kama  = close
endif
//------------------------------------------------------------------------------------
Sma        = average[22,0](close)                           //22
//------------------------------------------------------------------------------------
a1 = Kama CROSSES OVER  Sma
// --- SHORT
b1 = Kama CROSSES UNDER Sma
////////////////////////////////////////////////////////////////////////
TIMEFRAME (default)                                                           //1 min
ONCE TradeON = 1
IF IntraDayBarIndex = 0 THEN
TradeON = 1
ENDIF
TradeBar = BarCount
IF Not OnMarket AND TradeBar <> TradeBar[1] THEN
TradeON = 1
ENDIF
//************************************************************************
//                           LONG  trades
//************************************************************************
IF a1 AND TradeON AND LongTrading and TradeOK THEN
BUY 1 CONTRACT AT MARKET
TradeON = 0
ENDIF
//************************************************************************
//                           SHORT trades
//************************************************************************
IF b1 AND TradeON AND ShortTrading and TradeOK THEN
SELLSHORT 1 CONTRACT AT MARKET
TradeON = 0
ENDIF
//
SET TARGET %PROFIT TP
SET STOP   %LOSS   SL
//////////////////////////////////////////////////////////////////////////////////////////////////////////
//                                Trailing Stop
//------------------------------------------------------------------------------------
IF Not OnMarket THEN
TrailStart    = 50          //50     Start trailing profits from this point
BasePerCent   = 0.07 //0.07       //10.0%  Profit to keep
StepSize      = 6           //6      Pips chunks to increase Percentage
PerCentInc    = 0.1       //10.0%  PerCent increment after each StepSize chunk
RoundTO       = -0.5        //-0.5   rounds to Lower integer,  +0.4 rounds to Higher integer
PriceDistance = 7 * pipsize//8.9    minimun distance from current price
y1            = 0
y2            = 0
ProfitPerCent = BasePerCent
ELSIF LongOnMarket AND close > (TradePrice + (y1 * pipsize)) THEN //LONG
x1 = (close - tradeprice) / pipsize                            //convert price to pips
IF x1 >= TrailStart THEN                                       //go ahead only if N+ pips
Diff1         = abs(TrailStart - x1)
Chunks1       = max(0,round((Diff1 / StepSize) + RoundTO))
ProfitPerCent = BasePerCent + (BasePerCent * (Chunks1 * PerCentInc))
ProfitPerCent = max(ProfitPerCent[1],min(100,ProfitPerCent))
y1 = max(x1 * ProfitPerCent, y1)                            //y = % of max profit
ENDIF
ELSIF ShortOnMarket AND close < (TradePrice - (y2 * pipsize)) THEN//SHORT
x2 = (tradeprice - close) / pipsize                            //convert price to pips
IF x2 >= TrailStart THEN                                       //go ahead only if N+ pips
Diff2         = abs(TrailStart - x2)
Chunks2       = max(0,round((Diff2 / StepSize) + RoundTO))
ProfitPerCent = BasePerCent + (BasePerCent * (Chunks2 * PerCentInc))
ProfitPerCent = max(ProfitPerCent[1],min(100,ProfitPerCent))
y2 = max(x2 * ProfitPerCent, y2)                           //y = % of max profit
ENDIF
ENDIF
IF y1 THEN                                        //Place pending STOP order when y>0
SellPrice = Tradeprice + (y1 * pipsize)        //convert pips to price
IF abs(close - SellPrice) > PriceDistance THEN
IF close >= SellPrice THEN
SELL AT SellPrice STOP
ELSE
SELL AT SellPrice LIMIT
ENDIF
ELSE
SELL AT Market
ENDIF
ENDIF
IF y2 THEN                                        //Place pending STOP order when y>0
ExitPrice = Tradeprice - (y2 * pipsize)        //convert pips to price
IF abs(close - ExitPrice) > PriceDistance THEN
IF close <= ExitPrice THEN
EXITSHORT AT ExitPrice STOP
ELSE
EXITSHORT AT ExitPrice LIMIT
ENDIF
ELSE
EXITSHORT AT Market
ENDIF
ENDIF

// (GER) No trade after friday 16:00:00 (UTC+2 Europe/Berlin) or on holidays
If dayofweek = 5 AND Time > 160000 then
TradeOK = 0
elsif dayofweek = 0 then
TradeOK = 0
elsif dayofweek = 1 AND Time < 000100 then
TradeOK = 0
elsif year = 2019 and month = 12 and day = 24 then //
TradeOK = 0
elsif year = 2019 and month = 12 and day = 25 then //
TradeOK = 0
elsif year = 2019 and month = 12 and day = 26 then //
TradeOK = 0
elsif year = 2019 and month = 12 and day = 31 then //
TradeOK = 0
elsif year = 2020 and month = 1 and day = 1 then // New Year's Day
TradeOK = 0
elsif year = 2020 and month = 4 and day = 9 then // Easter
TradeOK = 0
elsif year = 2020 and month = 4 and day = 10 then // Easter
TradeOK = 0
elsif year = 2020 and month = 4 and day = 13 then // Easter
TradeOK = 0
elsif year = 2020 and month = 5 and day = 1 then //
TradeOK = 0
elsif year = 2020 and month = 6 and day = 1 then //
TradeOK = 0
elsif year = 2020 and month = 12 and day = 24 then //
TradeOK = 0
elsif year = 2020 and month = 12 and day = 25 then //
TradeOK = 0
elsif year = 2020 and month = 12 and day = 26 then //
TradeOK = 0
elsif year = 2020 and month = 12 and day = 31 then //
TradeOK = 0
else
TradeOK = 1
endif
// Add TradeOK to buy condition
//*************

// (GER) Close positions before weekend or day before holiday at 17:15:00 (UTC+2 Europe/Berlin)
if dayofweek = 5 and time = 171500 THEN
Endbeforeholiday = 1
elsif year = 2019 and month = 12 and day = 23 and time = 171500 then
Endbeforeholiday = 1
elsif year = 2019 and month = 12 and day = 30 and time = 171500 then
Endbeforeholiday = 1
elsif year = 2020 and month = 4 and day = 8 and time = 171500 then
Endbeforeholiday = 1
elsif year = 2020 and month = 4 and day = 30 and time = 171500 then
Endbeforeholiday = 1
elsif year = 2020 and month = 12 and day = 23 and time = 171500 then
Endbeforeholiday = 1
elsif year = 2020 and month = 12 and day = 30 and time = 171500 then
Endbeforeholiday = 1
else
Endbeforeholiday = 0
endif
IF Endbeforeholiday THEN
SELL AT MARKET
EXITSHORT AT MARKET
ENDIF
//*************