Questo è lo screener senza la forza relativa:

//--------------------------------------------------------
TIMEFRAME(Weekly)
//
// Canale di DONCHIAN
p         = 20
Upper     = HIGHEST[p](HIGH[1])
//Lower   = LOWEST[p](LOW[1])
Distanza  = 3 * pipsize
cDonchiaN = close >= (Upper - Distanza)
//
cWeekly   = cDonchian
//--------------------------------------------------------
TIMEFRAME(Daily)
//
Rialzo    = close > open
//
M20       = average[20,0](close)
cM20      = M20 > M20[1]
M50       = average[50,0](close)
cM50      = M50 > M50[1]
M200      = average[200,0](close)
cM200     = M200 > M200[1]
//
Roc20     = ROC[20](close)
cRoc20    = Roc20 > 0
Roc50     = ROC[20](close)
cRoc50    = Roc50 > 0
Roc200    = ROC[20](close)
cRoc200   = Roc200 > 0
//
DMI18     = DIplus[18](close)
cDmi18    = DMI18 > DMI18[1]
//
Rsi14     = Rsi[14](close)
cRsi14    = Rsi14 >= 65
//
cVolume   = Volume > Volume[1]
//
cDaily    = Rialzo AND cM20 AND cM50 AND cM200 AND cRoc20 AND cRoc50 AND cRoc200 AND cDmi18 AND cRsi14 AND cVolume
//
//--------------------------------------------------------
TIMEFRAME(default)
//
Risultato = cDaily AND cWeekly
//
SCREENER[Risultato]

questo è uno screener con la Forza Relativa (va applicato sul gruppo NASDAQ):

TIMEFRAME(daily)
CloseVal = Close
//
EQUITYFRAME("Azioni - US (NASDAQ","AMZN")
CloseInd = Close
EQUITYFRAME(default)
Ratio = (CloseVal / CloseInd) *100
//
TIMEFRAME(default)
RelativeStrength = (Ratio - Ratio[1]) *100
MyAvg = average[20,0](RelativeStrength)       //Media Semplice a 20 periodi
Cond = 0
IF RelativeStrength CROSSES OVER MyAvg AND (close > 150) THEN
   cond = 1
ELSIF RelativeStrength CROSSES UNDER MyAvg AND (close > 150) THEN
   cond = 2
ENDIF
SCREENER [Cond](Cond AS "1=↑,2=↓")//(RelativeStrength AS "RelativeStrength"

quando lo fai partire ti si aprirà una finestra dove ti chiede di selezionare il titolo da confrontare, perchè con codice AMZN ce ne sono diversi (se fosse univoco non lo chiederebbe). Se provi ad applicarlo ad u gruppo/categoria diverso da NASDAQ vedrai la segnalazione d’errore.

raffa58 wrote:

Grazie per gli screnner. Al fine di comprendere il contenuto e provare a scrivere qualche linea di codice, posso fare qualche domanda ?
si, ci mancherebbe, il forum serve principalmente  a questo!
Quali sono le istruzioni che indicano allo screener di selezionare solo i titoli che hanno la seconda candela in rialzo dal primo break out. ?
in realtà non c’è, ho messo la seconda senza pensare alla prima, occorre modificare la riga 39 in:

cDaily    = Rialzo AND Rialzo[1] AND cM20 AND cM50 AND cM200 AND cRoc20 AND cRoc50 AND cRoc200 AND cDmi18 AND cRsi14 AND cVolume

Il significato di questa istruzione invece cosa indica ? “Distanza = 3 * pipsize”
serve per individuare quando il prezzo è vicino (sopra o sotto) alla banda, io ho messo 3 pips, ma sei tu a stabilire quanti siano quelli utili per considerare il prezzo “vicino“, possono essere 3 oppure 0.2
la lista delle azioni candidate al rialzo, prodotta dal primo scanner, hanno una colonna denominata “criterio” Alcune di esse hanno lo stesso numero di criterio come mai ?, qual’è il suo significato (allego l’esempio)
il criterio è un valore su cui vuoi fare l’ordinamento e va scritto tra parentesi tonde DOPO quelle quadre che rappresentano la selezione. Io non l’ho messo, forse mette il prezzo di chiusura, non saprei. Nel secondo screener c’è ed è la condizione stessa, ma può essere anche diverso.
per le azioni sul nasdaq, è possibile selezionare nello screnner le società di bassa e media capitalizzazione ?
non saprei come ottenere il valore della capitalizzazione, IG non lo fornisce, si può fare VOLUME*CLOSE, ma questo è il valore complessivo del capitale movimentato in quella specifica candela, non la capitalizzazione

Per gli allarmi, lo screener E’ un allarme e suona (se non disattivato in qualche impostazione) quando trova nuovi strumenti. NON è possibile aggiungerci gli allarmi della piattaforma, quelli creati con l’icona della campanella, che si possono usare solo con i grafici.

Non hai allegato niente. Cerca di spiegare cosa intenti per “momento giusto”.