Eccolo:

// Stop e target: Inserisci qui i tuoi stop di protezione e profit target
//————————————————————————-
// Main code : PacMan v2
//————————————————————————-
// PAC MAN v2 - PIP HUNTER
// EUR / USD (M15)
// By BALMORA74 19.05.2018 - Vonasi modifications 20-5-18

DEFPARAM CumulateOrders = false
DEFPARAM Preloadbars = 4000

l = 64
p = 25

MoneyManagement = 0 //0, 1or 2
RiskManagement = 0 //0 or 1
Capital = 10000
MinBetSize = 1
RiskLevel = 20

Equity = Capital + StrategyProfit

IF MoneyManagement = 1 THEN
PositionSize = Max(MinBetSize, Equity * (MinBetSize/Capital))
ENDIF

IF MoneyManagement = 2 THEN
PositionSize = Max(LastSize, Equity * (MinBetSize/Capital))
LastSize = PositionSize
ENDIF

IF MoneyManagement <> 1 and MoneyManagement <> 2 THEN
PositionSize = MinBetSize
ENDIF

IF RiskManagement THEN
IF Equity > Capital THEN
RiskMultiple = ((Equity/Capital) / RiskLevel)
PositionSize = PositionSize * (1 + RiskMultiple)
ENDIF
ENDIF

PositionSize = Round(PositionSize*100)
PositionSize = PositionSize/100

// SHORT
Cv2 = RSI[14](close) <= 28
Cv3 = 0
For i = 11 to 14 Do
IF average[8](STD[i](close)) >= STD[i](close[3]) THEN
Cv3 = 1
ENDIF
NEXT

OKSHORT = cv2 and Cv3

IF OKSHORT then
Sellshort PositionSize CONTRACT at market
SET STOP pLOSS l//64
SET TARGET PPROFIT p// 25
ENDIF

//EXIT ZOMBIE TRADE
IF shortOnMarket AND BARINDEX-TRADEINDEX(1)>= 100 and close > TradePrice THEN
EXITSHORT AT MARKET
ENDIF

// LONG
Cv4 = RSI[14](close) >= 72
Cv5 = 0
For i = 11 to 14 Do
IF average[8](STD[i](close)) < STD[i](close[3]) THEN
Cv5 = 1
ENDIF
NEXT

OKLONG = cv4 and Cv5

IF OKLONG then
Buy PositionSize CONTRACT at market
SET STOP pLOSS l//64
SET TARGET PPROFIT p// 25
ENDIF

//EXIT LONG TRADE
IF LongOnMarket AND BARINDEX-TRADEINDEX(1)>= 100 and close < TradePrice THEN
SELL AT MARKET
ENDIF