Eccolo, per il trailing stop (qui settato a 5 pips di partenza e 5 pips di incremento successivo) ho usato il codice di Nicolas (https://www.prorealcode.com/blog/trading/complete-trailing-stop-code-function/):

DEFPARAM CumulateOrders = false
DEFPARAM FLATBefore     = 090000                         //09:00
DEFPARAM FLATAfter      = 210000                         //21:00
DEFPARAM PreLoadBars    = 2000

ONCE nLots              = 1
ONCE MaxPrice           = 999999
ONCE MinPrice           = 0
ONCE FirstHour          = 090000

IF time = FirstHour THEN
MaxPrice = highest[12](high)                          //Il massimo/minimo delle ultime 12 barre
MinPrice = lowest[12](low)                            //   (ogni ora = 12 barre da 5 minuti)
ENDIF
//************************************************************************
//     trailing stop function
trailingstart = 5    //5    trailing will start @trailinstart points profit
trailingstep  = 5    //5    trailing step to move the "stoploss"
//
//reset the stoploss value
IF NOT ONMARKET THEN
newSL=0
ENDIF
//manage long positions
IF LONGONMARKET THEN
//first move (breakeven)
IF newSL=0 AND close-tradeprice(1)>=trailingstart*pipsize THEN
newSL = tradeprice(1)+trailingstep*pipsize
ENDIF
//next moves
IF newSL>0 AND close-newSL>=trailingstep*pipsize THEN
newSL = newSL+trailingstep*pipsize
ENDIF
ENDIF
//manage short positions
IF SHORTONMARKET THEN
//first move (breakeven)
IF newSL=0 AND tradeprice(1)-close>=trailingstart*pipsize THEN
newSL = tradeprice(1)-trailingstep*pipsize
ENDIF
//next moves
IF newSL>0 AND newSL-close>=trailingstep*pipsize THEN
newSL = newSL-trailingstep*pipsize
ENDIF
ENDIF
//stop order to exit the positions
IF newSL>0 THEN
SELL AT newSL STOP
EXITSHORT AT newSL STOP
ENDIF
//************************************************************************
//                           LONG
a1 = close > MaxPrice
IF a1 THEN
Buy nLots CONTRACT AT MARKET
MaxPrice = 999999
MinPrice = 0
ENDIF

//                           SHORT
b1 = close < MinPrice
IF b1 THEN
Sellshort nLots CONTRACT AT MARKET
MaxPrice = 999999
MinPrice = 0
ENDIF

Ho aggiunto delle righe per fare in modo che entri solo una volta al giorno. Basta che tu commenti (mettendo le due barre oblique all’inizio della riga) le righe 56-57 e 64-65 e il TS potrà entrare anche più volte.

Roberto