// trailing atr stop
once trailingstoptype1 = 1 // trailing stop - 0 off, 1 on

if trailingstoptype1 then
//========================
once tsatrdistlong  = 5 // ts atr distance
once tsatrdistshort = 5 // ts atr distance

once tsincrements = 0.05 // set to 0 to ignore tsincrements
once tsminatrdist = 2

once tsatrperiod    = 14 // ts atr parameter
once tsminstop      = 10 // ts minimum stop distance

once ts1sensitivity = 1  // [0]close;[1]high/low;[2]low;high
//========================
if barindex=tradeindex then
trailingstoplong = tsatrdistlong
trailingstopshort = tsatrdistshort
else
if longonmarket then
if tsnewsl>0 then
if trailingstoplong>tsminatrdist then
if tsnewsl>tsnewsl[1] then
trailingstoplong=trailingstoplong
else
trailingstoplong=trailingstoplong-tsincrements
endif
else
trailingstoplong=tsminatrdist
endif
endif
endif
if shortonmarket then
if tsnewsl>0 then
if trailingstopshort>tsminatrdist then
if tsnewsl<tsnewsl[1] then
trailingstopshort=trailingstopshort
else
trailingstopshort=trailingstopshort-tsincrements
endif
else
trailingstopshort=tsminatrdist
endif
endif
endif
endif
tsatr=averagetruerange[tsatrperiod]((close/10)*pipsize)/1000
//tsatr=averagetruerange[tsatrperiod]((close/1)*pipsize) // (forex)
tgl=round(tsatr*trailingstoplong)
tgs=round(tsatr*trailingstopshort)
if not onmarket or ((longonmarket and shortonmarket[1]) or (longonmarket[1] and shortonmarket)) then
tsmaxprice=0
tsminprice=close
tsnewsl=0
endif
if ts1sensitivity=1 then
ts1sensitivitylong=high
ts1sensitivityshort=low
elsif ts1sensitivity=2 then
ts1sensitivitylong=low
ts1sensitivityshort=high
else
ts1sensitivitylong=close
ts1sensitivityshort=close
endif
if longonmarket then
tsmaxprice=max(tsmaxprice,ts1sensitivitylong)
if tsmaxprice-tradeprice(1)>=tgl*pointsize then
if tsmaxprice-tradeprice(1)>=tsminstop then
tsnewsl=tsmaxprice-tgl*pointsize
else
tsnewsl=tsmaxprice-tsminstop*pointsize
endif
endif
endif
if shortonmarket then
tsminprice=min(tsminprice,ts1sensitivityshort)
if tradeprice(1)-tsminprice>=tgs*pointsize then
if tradeprice(1)-tsminprice>=tsminstop then
tsnewsl=tsminprice+tgs*pointsize
else
tsnewsl=tsminprice+tsminstop*pointsize
endif
endif
endif
if barindex-tradeindex>1 then
if longonmarket then
if tsnewsl>0 then
sell at tsnewsl stop
endif
if tsnewsl>0 then
if close crosses under tsnewsl then
sell at market
endif
endif
endif
if shortonmarket then
if tsnewsl>0 then
exitshort at tsnewsl stop
endif
if tsnewsl>0 then
if close crosses over tsnewsl then
exitshort at market
endif
endif
endif
endif
endif

// trailing stop percentage
once trailingstoptype2 = 1

if trailingstoptype2 then
//====================
once trailingpercentlong  = 0.333 // %
once trailingpercentshort = 0.333 // %
once accelerator     = 1 // 1 = default; always > 0 (i.e. 0.5-3)
once ts2sensitivity  = 1 // [0]close;[1]high/low;[2]low;high
//====================
once steppercentlong  = (trailingpercentlong/10)*accelerator
once steppercentshort = (trailingpercentshort/10)*accelerator
if onmarket then
trailingstartlong = tradeprice(1)*(trailingpercentlong/100)
trailingstartshort = tradeprice(1)*(trailingpercentshort/100)

trailingsteplong = tradeprice(1)*(steppercentlong/100)
trailingstepshort = tradeprice(1)*(steppercentshort/100)
endif
if not onmarket or ((longonmarket and shortonmarket[1]) or (longonmarket[1] and shortonmarket)) then
newsl=0
endif
if ts2sensitivity=1 then
ts2sensitivitylong=high
ts2sensitivityshort=low
elsif ts2sensitivity=2 then
ts2sensitivitylong=low
ts2sensitivityshort=high
else
ts2sensitivitylong=close
ts2sensitivityshort=close
endif
if longonmarket then
if newsl=0 and ts2sensitivitylong-tradeprice(1)>=trailingstartlong then
newsl = tradeprice(1)+trailingsteplong
endif
if newsl>0 and ts2sensitivitylong-newsl>trailingsteplong then
newsl = newsl+trailingsteplong
endif
endif
if shortonmarket then
if newsl=0 and tradeprice(1)-ts2sensitivityshort>=trailingstartshort then
newsl = tradeprice(1)-trailingstepshort
endif
if newsl>0 and newsl-ts2sensitivityshort>trailingstepshort then
newsl = newsl-trailingstepshort
endif
endif
if barindex-tradeindex>1 then
if longonmarket then
if newsl>0 then
sell at newsl stop
endif
if newsl>0 then
if close crosses under newsl then
sell at market
endif
endif
endif
if shortonmarket then
if newsl>0 then
exitshort at newsl stop
endif
if newsl>0 then
if close crosses over newsl then
exitshort at market
endif
endif
endif
endif
endif

Hi everyone,

I’ve spent hours reading through all this and I’m still finding it tricky to understand to be honest. Why does it seem so difficult to add a breakeven line of code? I’m very new to all this so do give me some patience haha.

I am just practicing and getting the hang of coding bits so to keep it simple I have just created a code to buy when the RSI gets to 30 and have set a trailing stop too but what I want to do is simply add something like “breakeven level 10 pips above entry, exit the market if triggered ”

Is this possible? All I see on here is 100 lines of code for something that seems so simple!

Any help would be greatly appreciated, thanks guys

The above code is 1/4 of 100 lines!

Is it still too much much?

There you go with just 4 lines:

If (positionprice * PositionPerf / PipSize) >= 30 * PipSize then
   Sell at tradeprice + 10*pipsize STOP
   Exitshort at tradeprice - 10*pipsize STOP
Endif

That’s pretty short!
Add this to your code and you will soon report that it will not always exit at the expected entry price + 10 pips.

That’s because pending orders expire each bar, so when your profit is 30+ pips they will be placed, but if they are not triggered and the next bar your profit is, say, 29 pips, they will not be placed again and you may suffer an unexpected big loss! How can this be dealt with? By adding a few lines to RECORD that your trigger level has been reached, so the stop orders are to be placed again, next bar, even if by that time your profit is lower than that level:

Once NewSL = 0
If (positionprice * PositionPerf / PipSize) >= 30 * PipSize then
   If LongOnMarket then
      NewSL = tradeprice + 10*pipsize
   ElsIf ShortOnMarket then
      NewSL = tradeprice - 10*pipsize
Endif
If NewSL > 0 then
   Sell at NeWSL STOP
   Exitshort at NewSL STOP
Endif

as you can see, a few more lines have been added, but they are still not so many!

Well… there’s still a problem. Next trade NewSL will still retain the previous exit price and it may exit at an incorrect price,

We need to add a few more lines to prevent this from happening:

Once NewSL = 0
If not OnMarket then
   NewSL = 0
Endif
If (positionprice * PositionPerf / PipSize) >= 30 * PipSize then
   If LongOnMarket then
      NewSL = tradeprice + 10*pipsize
   ElsIf ShortOnMarket then
      NewSL = tradeprice - 10*pipsize
Endif
If NewSL > 0 then
   Sell at NeWSL STOP
   Exitshort at NewSL STOP
Endif

it’s no more just a few lines (and I did not add comments to make code easier to read),  it it can’t be done with less than that!

100+ lines can easily be reached to add more sophisticated features.

It’s like starting a car, you don’t need too much engineering, but then you have to add support for speeding up, then slowing down, then braking, then steering, then accommodating people, etc…

Thanks Peter, just found out that this trailing module doesn’t react the same way in MTF. Say you’re executing a 5min Algo on a 1 min chart. If you leave everything under TIMEFRAME(5 minutes), this module doesn’t change. If you insert TIMEFRAME(DEFAULT) just before this module, it works fine.

Khaled

What kind of crossing hull do you use ???