Ciao. Lascia che ti faccia un esempio. Ora devi solo modificare le condizioni di input e output per quelle che desideri.

// HARSI  by JS le 02.10.2023 modifié  02.10.2023
//variabili:
rsip = 7
smoothing = 1
halength = 14

rsihelp = RSI[rsip]((high+close+low+open)/4)
closersi2 = rsi[halength](close)

if barindex > 0 then
openrsi2 = rsi[halength](close[1])
else
openrsi2 = rsi[halength](close)
endif

rsihighraw2 = rsi[halength](high)
rslowraw2 = rsi[halength](low)
rsihigh2 = max(rsihighraw2, rslowraw2)
rsilow2 = min(rsihighraw2, rslowraw2)

haclose = (closersi2 + openrsi2 + rsihigh2 + rsilow2) / 4

if barindex > halength + 2 then
haopen = ((haopen[1] * smoothing) + haclose[1]) / (smoothing + 1)
else
haopen = (closersi2 + openrsi2) / 2
endif

hahigh = max(rsihigh2, max(haopen, haclose))
halow = min(rsilow2, min(haopen, haclose))

if barindex > rsip then
rsismoothed = (rsismoothed[1] + rsihelp) / 2
else
rsismoothed = rsihelp
endif

//----- Strategia di trading -----//

// Condizioni di entrata/uscita lunghe
yourConditionsOpenLong=rsismoothed crosses over 30
yourConditionsCloseLong=rsismoothed crosses over 70

if not longonmarket and yourConditionsOpenLong then
BUY 1 CONTRACT AT MARKET
endif

if longonmarket and yourConditionsCloseLong then
SELL AT MARKET
endif

// Condizioni di entrata/uscita corte
yourConditionsOpenShort=rsismoothed crosses under 70
yourConditionsCloseShort=rsismoothed crosses under 30
if not shortonmarket and yourConditionsOpenShort then
SELLSHORT 1 CONTRACT AT MARKET
endif

if shortonmarket and yourConditionsCloseShort then
EXITSHORT AT MARKET
endif