Tracage de segments au dela des chandeliers courants

Viewing 12 posts - 1 through 12 (of 12 total)
  • Author
    Posts
  • 10/04/2020 at 8:09 AM #146309 quote
    BoutDePain
    Participant
    Average

    Bonjour,

    Je me suis fait un indicateur pour visuellement retrouver facilement les twist de la SSA et SSB pour Ichimoku et les objectifs qui s’y rapportent. Il marche comme je veux a part un des détail que j’ai voulu ajouter récemment. Voici le code de cetr indicateur :

    Tenkansen = (highest[9](high)+lowest[9](low))/2
Kijunsen = (highest[26](high)+lowest[26](low))/2
SSpanA = (tenkansen+kijunsen)/2
SSpanB = (highest[52](high)+lowest[52](low))/2

// CROISEMENT SSA et SSB
TWIST=(SSpanA[1] < SSpanB[1] and SSpanA > SSpanB) or (SSpanA[1] > SSpanB[1] and SSpanA < SSpanB)

if twist then
if SSpanB < close then
objectif = SSpanB - (close - SSpanB)
drawarrowdown(barindex,objectif) coloured(255,0,0)
drawsegment(barindex,objectif,barindex+26,objectif) coloured(255,0,0)
else
objectif = SSpanB + (SSpanB - close)
drawarrowup(barindex,objectif) coloured(0,255,0)
drawsegment(barindex,objectif,barindex+26,objectif) coloured(0,255,0)
endif
endif

return highest[52](high) coloured(245,182,66) AS "Ichimoku Highest",lowest[52](Low) coloured(245,182,66) AS "Ichimoku Lowest"

    Donc voici mon problème : lorsqu’un twist se produit j’indique un cours d’achat dans le sens opposé a la SSB+26 périodes. Mais j’ai voulu ajouter un segment qui partirait en ligne horizontale du jour ou le twist se produit au jour + 26 périodes (pour voir a quel twist on se réfère). Ce segment est bien tracé sauf dans les cas ou la date + 26 période est inférieure a la date courante. Je cherche un moyen de tracer ces segments même s’ils dépassent la date courante et sont dans le futur (un peu comme le fait Ichimoku avec le nuage dans le futur).

    Pour information j’utilise la version 10.3 de Prorealtime.

    10/04/2020 at 8:47 AM #146316 quote
    JC_Bywan
    Moderator
    Master

    Bonjour, la possibilité de tracer dans le futur par rapport à la barre courante est effective à partir de la version 11. Quand ton broker migrera de la 10.3 vers 11 tu pourras le faire via des instructions du type “barindex+…” ou “datetobarindex(…)”.

    BoutDePain thanked this post
    10/04/2020 at 10:51 AM #146326 quote
    BoutDePain
    Participant
    Average

    Merci je viens effectivement de tester en version 11 et cela fonctionne. Tant pis je ne pourrais pas en profiter avec mon broker.

    11/01/2020 at 10:30 AM #149126 quote
    BoutDePain
    Participant
    Average

    Bonjour,

    Je cherche de l’aide car je suis un peu a cours d’idée : je cherche pour mon indicateur ichimoku de range a indiquer cette foi sles bornes de mon range par un rectangle, mais malheureusement je n’arrive pas a mettre de couleur au sein du rectangle.

    Voici mon code :

    Tenkansen1 = (highest[9](high)+lowest[9](low))/2
Kijunsen1 = (highest[26](high)+lowest[26](low))/2
SSpanA = (tenkansen1+kijunsen1)/2
SSpanB = (highest[52](high)+lowest[52](low))/2

// CROISEMENT SSA et SSB
TWIST=(SSpanA[1] < SSpanB[1] and SSpanA > SSpanB) or (SSpanA[1] > SSpanB[1] and SSpanA < SSpanB)

if inRange = 1 and (BorneSup < close or BorneInf > close) then
inRange=0
endif

if twist then
if SSpanB < close and SSpanB > SSpanA then
objectif = SSpanB - (close - SSpanB)
drawarrowdown(barindex,objectif) coloured(255,0,0)
drawsegment(barindex,objectif,barindex+26,objectif) coloured(255,0,0)
elsif SSpanB > close and SSpanB < SSpanA then
objectif = SSpanB + (SSpanB - close)
drawarrowup(barindex,objectif) coloured(0,255,0)
drawsegment(barindex,objectif,barindex+26,objectif) coloured(0,255,0)
endif
if inRange <> 1 then
inRange=1
rangeStart=barindex
BorneSup=highest[52](high)
BorneInf=lowest[52](low)
endif
endif


if PlusHautAvecMeche <> highest[52](high) and inRange <> 1 then
PlusHautAvecMeche=highest[52](high)
lastChangeHigh=barindex
endif
if PlusBasAvecMeche <> lowest[52](low) and inRange <> 1 then
PlusBasAvecMeche=lowest[52](low)
lastChangeLow=barindex
endif
if lastChangeLow > lastChangeHigh then
lastChange=lastChangeHigh
else
lastChange=lastChangeLow
endif

x=highest[52](close)
y=highest[52](open)
if (x>y) then
PlusHautSansMeche=x
else
PlusHautSansMeche=y
endif
x=lowest[52](close)
y=lowest[52](open)
if (x>y) then
PlusBasSansMeche=y
else
PlusBasSansMeche=x
endif

if inRange = 1 then
if rangeStart=barindex then
DRAWRECTANGLE(lastChange,BorneSup,barindex,BorneInf) coloured(0,0,200,100)
else
DRAWRECTANGLE(barindex-1,BorneSup,barindex,BorneInf) coloured(0,0,200,100)
endif
endif

return highest[52](high) coloured(245,182,66) AS "Ichimoku Highest",lowest[52](Low) coloured(245,182,66) AS "Ichimoku Lowest",PlusHautSansMeche coloured(245,182,66) as "Plus Haut Sans Meche", PlusBasSansMeche coloured(245,182,66) as "Plus Bas Sans Meche"
    11/01/2020 at 11:10 AM #149128 quote
    JC_Bywan
    Moderator
    Master

    Bonjour,

    comme pour le tracé au-delà de la barre courante, on est dans les améliorations de la v11 par rapport à la v10.3. En effet en v10.3 on ne peut colorer que le bord du rectangle avec le mot clé “coloured”, on ne choisit pas la couleur intérieure. Pour pouvoir colorer l’intérieur d’un rectangle avec “coloured”, il faut la v11 (et le contour peut lui-même être coloré différemment de l’intérieur avec le nouveau mot clé de la v11 “bordercolor”).

    11/01/2020 at 11:53 AM #149132 quote
    BoutDePain
    Participant
    Average

    Merci en fait je suis passé en version 11 récemment et c’est bien sur la V11 que mon problème se situe, je vais cependant essayer avec bordercolor pour voir si j’ai des résultats différents.

    11/01/2020 at 12:00 PM #149140 quote
    JC_Bywan
    Moderator
    Master

    Ok, si tu as eu la v11 depuis l’autre fois, alors il te faut effectivement utiliser les 2 mots clés à la fois pour que coloured s’applique à l’intérieur, exemple:

    DRAWRECTANGLE(lastChange,BorneSup,barindex,BorneInf) coloured(0,0,200,100) bordercolor(255,0,0)
    11/01/2020 at 12:00 PM #149141 quote
    BoutDePain
    Participant
    Average

    Cela a marché merci bien c’est un peu surprenant que coloured ne colore que les bords par défaut si on n’indique pas bordercolor. En tout cas tout fonctionne maintenant.

    11/01/2020 at 12:12 PM #149143 quote
    JC_Bywan
    Moderator
    Master

    Oui c’était ma première réaction aussi quand j’ai pu mettre la main sur les nouveaux mots clés de la v11 à l’époque, je crois qu’ils ont fait ça pour des raisons de compatibilité d’indicateurs personnels de la v10.3 se mettant à tourner en v11 de sorte qu’ils continuent à faire les mêmes rectangles qu’avant sans que les utilisateurs aient besoin de modifier leur code. Perso j’aurais tout simplement ajouté le nouveau mot clé “insidecolor” pour l’intérieur au lieu de “bordercolor” pour les bords, de sorte que “coloured” aurait gardé un seul comportement simple pour les bords quelle que soit la version, mais bon maintenant que c’est fait mon avis ne va rien y changer…

    01/21/2021 at 10:52 PM #158873 quote
    Protagonist
    Participant
    New

    Bonjour à tous

    ,

    Je vois souvent l’instruction inRange.

    Je n’arrive pas à trouve sa signification.

    Pouvez-vous m’expliquer SVP…

    Merci et bons trades

    01/22/2021 at 9:15 AM #158888 quote
    JC_Bywan
    Moderator
    Master

    Bonjour Protagonist, ce n’est pas une instruction, c’est un nom de variable choisi, ou copié tel quel à partir d’un code d’autrui (d’où son éventuelle récurrence fréquente d’un code à l’autre), par l’auteur du code. Donc pas d’instruction particulière associée…

    Ici c’est juste un flag qui bascule de 0 à 1 selon les conditions décidées par l’auteur du code.

    En cas de doute sur si un mot est une instruction ou pas, le format dans l’éditeur de code (reproduit dans les messages du site grâce au bouton “insert PRT code”) donne des couleurs qui aident à différencier, en bleu ou vert un mot réservé du langage, et en noir une variable de l’auteur.

    06/13/2021 at 8:33 PM #171691 quote
    Protagonist
    Participant
    New

    Merci Noobywan pour tes explications!

  • Author
    Posts
Viewing 12 posts - 1 through 12 (of 12 total)
  • You must be logged in to reply to this topic.

Tracage de segments au dela des chandeliers courants


ProBuilder : Indicateurs & Outils Personnalisés

New Reply
Author
author-avatar
BoutDePain @boutdepain Participant
Summary

This topic contains 11 replies,
has 3 voices, and was last updated by Protagonist
4 years, 9 months ago.

Topic Details
Forum: ProBuilder : Indicateurs & Outils Personnalisés
Language: French
Started: 10/04/2020
Status: Active
Attachments: No files
Logo Logo
Loading...
Do you like cookies? 🍪 We use cookies to ensure you get the best experience on our website. (Learn more)
©2026 ProRealCode - Trading & Coding with ProRealTime™