Bonjour, dans son livre ‘Mastering the trade’ John Carter parle d’un indicateur nommé ‘$Tick’ qui donne l’évolution du nombre de ticks par 5 minutes. J’ai trouvé un indicateur semblable sur Tradingview qui se nomme ‘Tick Indicator’ de Mr_Meeseexs du 28/03/2020 Je n’ai malheureusement pas accès au code. Le graphique sur tradingview donne une allure identique au graphique de John Carter. Pouvez vous réaliser ou existe t’il déjà un indicateur semblable sur Prorealtime
Merci
Sur un graphique classique, on peut utiliser le code ci-dessous, cela indique la quantité de fois où le prix change dans la barre courante, en + ou en –
once $lastclose[0]=close
if not isset($ticks[barindex]) then
$ticks[barindex] = 0
endif
if islastbarupdate then
if close>$lastclose[0] then
$ticks[barindex]=$ticks[barindex]+1
else
$ticks[barindex]=$ticks[barindex]-1
endif
$lastclose[0]=close
endif
return $ticks[barindex] //coloured(0,255,255) style(histogram)
Sur un graphique en ticks, on peut utiliser le code suivant, qui tracera une barre verticale à chaque fois qu’on a atteint la limite de temps en minutes, ici définit par la variable “timeperiod”
//
timeperiod = 5 //time period in minutes
// ---------------
once $time[0]=opentimestamp
once $lastclose[0]=close
once $ticks[0]=0
if islastbarupdate then
diff=timestamp-$time[0]
if diff/60>=timeperiod then
$time[0]=opentimestamp
$ticks[0]=0
drawvline(barindex)
endif
if close>$lastclose[0] then
$ticks[0]=$ticks[0]+1
else
$ticks[0]=$ticks[0]-1
endif
$lastclose[0]=close
endif
return $ticks[0]
On peut pas récupérer la quantité de ticks dans l’historique, sauf si on utilise bien sûr une graphique en 1-tick, mais cela nécessite un autre code, à voir selon tes besoins.
Un grand merci , je teste rapidement celà
Bonjour,
Je me permets de relancer le sujet car je tente de créer un indicateur tout simple qui affiche, sur chaque bougie, les ticks positifs et négatifs. J’ai donc essayé d’adopter le code ci-dessus proposé par Nicolas et d’y ajouter des compteurs de ticks positifs et négatifs mais je ne comprends pas : on dirait que le compte ne se fait pas correctement et je n’arrive pas à comprendre pourquoi. Auriez-vous, s’il vous plaît, une idée à me soumettre ?
Voici le code que j’utilise actuellement mais qui ne fonctionne pas :
once $lastclose[0]=close
if not isset($ticks[barindex]) then
$ticks[barindex] = 0
positivetick=0
negativetick=0
endif
if islastbarupdate then
if close>$lastclose[0] then
$ticks[barindex]=$ticks[barindex]+1
positivetick=positivetick+1
else
$ticks[barindex]=$ticks[barindex]-1
negativetick=negativetick+1
endif
$lastclose[0]=close
endif
return positivetick as "positivetick", negativetick as "negativetick"
Bien cordialement.
C’est normal puisqu’à chaque tick reçu (à chaque mouvement du prix durant le même chandelier) tes variables classiques positivetick et negativetick sont réinitialisés à 0. Il faut donc utiliser des variables en tableau (qui elles, ne se reset pas à chaque mouvement du prix durant le même chandelier).
Ci-dessous une rapide correction à tester:
once $lastclose[0]=close
if not isset($ticks[barindex]) then
$ticks[barindex] = 0
$positivetick[barindex]=0
$negativetick[barindex]=0
endif
if islastbarupdate then
if close>$lastclose[0] then
$ticks[barindex]=$ticks[barindex]+1
$positivetick[barindex]=$positivetick[barindex]+1
else
$ticks[barindex]=$ticks[barindex]-1
$negativetick[barindex]=$negativetick[barindex]+1
endif
$lastclose[0]=close
endif
return 0,$positivetick[barindex] as "positivetick" coloured("green"), $negativetick[barindex] as "negativetick" coloured("crimson")
Mille mercis Nicolas ! Ça marche très bien !
Seul bémol, on n’arrive pas à obtenir le “passé” : l’indicateur se construit au fur et à mesure de notre présence sur le graphique mais impossible d’avoir les valeurs précédentes. Y aurait-il un moyen ?
Non, on ne peut pas extraire quand et comment le prix a bougé à l’intérieur d’une bougie qui a déjà clôturé.
Si tu veux un historique, ouvre le graphique 1-tick 😉
Je comprends. Merci Nicolas !
